批处理将字符串中的字母大小写互换

随风

将字符串中的字母大写换成小写，小写换成大写。
如：

set var=abHJ      dfsKHK    aB
复制代码

要求显示
转换前：abHJ      dfsKHK    aB
转换后：ABhj      DFSkhk   Ab
复制代码

suqili56

@echo off
set var=abHJ      dfsKHK    aB
set/p b=AB%var:~2,18%AB
pause

随风

汗，字符窜是随机的，没有规律。

tireless

@echo off
setlocal EnableDelayedExpansion
set /p var=请输入: 
set Lowercase=a b c d e f g h i j k l m n o p q r s t u v w x y z
set Capital=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
cls & echo 转换前: %var%

for %%a in (%var%) do call :replace %%a
echo 转换后: %var%
pause & exit /b

:replace
set "n="
set "word2="
set word=%1
:loop
set /a n+=1
set one=!word:~-%n%,1!
if %one% leq Z if %one% geq a (
  if "!Lowercase:%one%=%one%!" equ "%Lowercase%" (
    call :C %one% & goto next
  ) else (call :L %one% & goto next)
) 
set "word2=%one%%word2%"
:next
if "!word:~%n%!" neq "" goto loop
set var=!var:%word2%=%word2%!
goto :eof

:L
for %%a in (%Lowercase%) do if /i %1==%%a set "word2=%%a%word2%" & goto :eof

:C
for %%a in (%Capital%) do if /i %1==%%a set "word2=%%a%word2%" & goto :eof
复制代码

有点乱。。

[ 本帖最后由 tireless 于 2008-12-8 01:50 编辑 ]

rat

@echo off
set /p var=Please input:
for /f "delims=" %%a in ('^(echo e0:200 "%var%" ff^&more /e +5^<"%~f0"^)^|debug^|findstr "^[^-0]"^|findstr /v "Program Invalid"') do echo.%%a
pause&exit/b

a100
mov ax,0
mov ds,ax
mov bx,200
mov dl,[bx]
cmp dl,41
jb 112
xor dl,20
mov ah,2
int 21
inc bx
mov al,[bx]
cmp al,ff
jnz 108
int 20

g
q
q
复制代码

lhjoanna

@echo off&setlocal enabledelayedexpansion
set /p "string=请输入字符串:"
set "code=a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
set string=!string: =#!
:loop
set "str_nul=!str_nul!!string:~,1! "&set string=!string:~1!
if defined string goto loop
for %%i in (!str_nul!) do (
    set flag=1
    for %%j in (!code!) do (
        if /i "%%i"=="%%j" if not "%%i"=="%%j" set str=!str!%%j&set flag=0
    )
    if !flag! equ 1 set str=!str!%%i
)
set "str=!str:#= !"
echo.&echo 转换后:!str!
pause>nul
复制代码

以上代码对于数字和空格原样输出，之前写过类似代码，见http://www.bathome.net/thread-2550-1-2.html中第二个功能。

[ 本帖最后由 lhjoanna 于 2008-12-8 01:56 编辑 ]

tireless

遇到非字母会有问题：

请输入字符串:bbs.bathome.net
'P' 不是内部或外部命令，也不是可运行的程序
或批处理文件。

转换后BBs.bathome.net

pusofalse

指定的字符串中会有特殊字符吗？

lhjoanna

'P' 不是内部或外部命令，也不是可运行的程序
或批处理文件。
复制代码

这个不是非字母的问题啊，刚检查了下，是因为在给code赋值时 P 到了第二行了，应该是粘贴时不小心多按了回车，现已改过来了。对于特殊字符，不支持 !  ^ 。#符号我当成空格的标记了，如果需要显示可以修改下代码。

youxi01

利用一个特性：变量名不区分大小写，变量值却区分大小写。

@echo off&setlocal enabledelayedexpansion
set str=aA bB cC dD eE fF gG hH iI jJ kK lL mM nN oO pP qQ rR sS tT uU vV wW xX yY zZ
for %%i in (%str%) do set "var=%%i" & set !var:~0,1!=%%i
set "TS="
set /P TS=请输入测试字符(没考虑特殊字符)：
for /l %%i in (0 1 100) do (
        set "T3=!TS:~%%i,1!"
        if "!T3!"=="" goto :Res
        if defined !T3! (
                call set T2=%%!T3!:~0,1%%
                if "!T3!"=="!T2!" call set T2=%%!T3!:~1,1%%) else set "T2= "
        set Res=!Res!!T2!
)
:Res
echo.&echo 转换前：!TS!
echo 转换后：!Res!
pause>nul
 
复制代码

随风

set var=abc  ## adf
这种情况下把#号替换成了空格。

firewolf85

原帖由 rat 于 2008-12-7 22:56 发表
@echo off
set /p var=Please input:
for /f "delims=" %%a in ('^(echo e0:200 "%var%" ff^&more /e +5^

汇编吗？很眼熟的说。

youxi01

原帖由 随风 于 2008-12-8 15:15 发表
set var=abc  ## adf
这种情况下把#号替换成了空格。

呵呵，只处理 字母 和空格，当初设计的时候
没考虑完全啊

rat

原帖由 firewolf85 于 2008-12-8 17:38 发表

汇编吗？很眼熟的说。

是。就会一点点而已：（

skuny

@ECHO OFF&setlocal enabledelayedexpansion
:222
set st=
set /p "strr=请输入字符串:"
echo 转换前!strr!
call :111 a b c d e f g h i j k l m n o p q r s t u v w x y z
echo 转换后:!st!
pause>nul&goto :222
:111
for /l %%a in (0,1,100) do (
  set "stt=!strr:~%%a,1!"
  if not defined stt goto :eof
  set /a aaa=0
    for %%i in (%*) do (
    set /a aaa+=1
    if /i "!stt!"=="%%i" (
         if not "!stt!"=="%%i" set "st=!st!%%i"&set /a aaa=0
         if "!stt!"=="%%i" (
             set "bb=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
             for %%k in (!bb!) do if /i "!stt!"=="%%k" set "st=!st!%%k"&set /a aaa=0
                   )
               )
    if !aaa!==26 set "st=!st!!stt!" 
        )                    
)

[ 本帖最后由 skuny 于 2009-1-15 19:34 编辑 ]