[文件操作] 求助批处理保留指定文件，删除其他文件及文件夹。

fyngd

A目录，B目录，想保留其中的 _info.txt 文件，然后删除此根目录和子目录中的所有文件和文件夹，请高手出招。

Batcher

回复 3# fyngd

@echo off
set "Folder1=\\DS918\roms\gba"
set "Folder2=\\DS918\roms\gbc"
for %%a in ("%Folder1%" "%Folder2%") do (
    echo 正在处理文件夹：%%a
    if exist "%%~a\" (
        pushd "%%~a"
        for /f "delims=" %%i in ('dir /b /ad') do (
            rd /s /q "%%i"
        )
        for /f "delims=" %%i in ('dir /b /a-d ^| findstr /v /x /c:"_info.txt"') do (
            del /f /q "%%i"
        )
        popd
    )
)
复制代码

fyngd

回复 2# Batcher


感谢管理员，怪我没表达清楚让您费心了，我是想能够添加路径，然后保留里面的 _info.txt 文件，删除定义路径下其他所有文件和文件夹。如下，谢谢！

\\DS918\roms\gba
\\DS918\roms\gbc

Batcher

回复 1# fyngd


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

@echo off
cd /d "%~dp0"
for %%a in (A B) do (
    echo 正在处理文件夹：%%a
    if exist "%%a\" (
        pushd "%%a"
        for /f "delims=" %%i in ('dir /b /ad') do (
            rd /s /q "%%i"
        )
        for /f "delims=" %%i in ('dir /b /a-d ^| findstr /v /x /c:"_info.txt"') do (
            del /f /q "%%i"
        )
        popd
    )
)
复制代码