【已解决】【100元红包】判断本地文件夹是否为空，将NAS文件剪切到本地文件夹里

linfeng_321

NAS文件（文件名有版本号区分：V14、V15...）：
A120001-V15.zip
A120002-V14.zip
A120003-V15.zip
...

本地文件夹：
.\aaa\bbb-V15
.\aaa\bbb-V14
...

操作步骤：
1、判断本地文件夹是否为空，将NAS文件名（判断版本号：V14，V15...）剪切到本地对应编号文件夹里，再执行123.bat。
2、设置延迟时间120秒，再重复一次“第1步”操作，一直循环下去。

注：每次只能剪切一个文件（按时间升序剪切）。
如果本地文件夹里包含隐藏文件“thumb.db或.DS_Store文件”时，也判断文件夹为空。顺便删除这些文件。

NAS信息和延迟时间，放在批处理顶部变量区域，便于我修改。

zaqmlp

@echo off&cd /d "%~dp0"&mode con lines=5000&rem bat存为编码ANSI

set "nas_folder=\\nas_ip\zipfolder"
set sleep=120
set "run_bat=.\123.bat"

:loop
set "local_folder="
for %%a in (
    ".\aaa\bbb-V15\ccc"
    ".\aaa\bbb-V14\ccc"
) do (
    set "count="
    if exist "%%~a" (
        for /f "delims=" %%b in ('dir /a-dh/b "%%~a\" 2^>nul') do del /a /f /q "%%~a\%%~nxb"
        for /f "delims=" %%b in ('dir /a-d-h/b "%%~a\" 2^>nul') do set /a count+=1
        if not defined count (
            set "local_folder=%%~a"
            goto :movefile
        )
    ) else (echo;"%%~a" path error or not existed)
    
)
if not defined local_folder (
    echo;can not find any empty local folders
    goto :break
)

:movefile
echo;local_folder="%local_folder%"

set "ver="
for /f "delims=" %%a in ("%local_folder%") do set "fd=%%~dpa"
for /f "delims=" %%a in ("%fd:~,-1%") do (
    for /f "tokens=1* delims=-" %%b in ("%%~nxa") do set "ver=%%c"
)
if not defined ver (
    echo;can not get version number
    goto :break
)
echo;ver="%ver%"

echo;"%nas_folder%\*-%ver%.zip" is finding……
for /f "delims=" %%a in ('dir /a-d/b/od/tw "%nas_folder%\*-%ver%.zip"') do (
    echo;"%nas_folder%\%%~nxa" --^> "%local_folder%\"
    move "%nas_folder%\%%~nxa" "%local_folder%\"
    if exist "%run_bat%" (start "" "%run_bat%") else (echo;"%run_bat%" not found)
    goto :break
)

:break
timeout /t %sleep% /nobreak
goto loop
复制代码

linfeng_321

回复 2# zaqmlp


    大佬你好，帮我修改下
本地文件夹(修改为)：
.\aaa\bbb-V15\ccc
.\aaa\bbb-V14\ccc

zaqmlp

回复 3# linfeng_321


    已修改

linfeng_321

回复 4# zaqmlp


    已支付，谢谢大佬