[日期时间] 批处理计算日期函数调用

随风

利用 will sort 的纯批处理计算日期，作了个函数，
方便在写代码时对日期的计算。可省略大量的代码。
将以下代码保存为 jsrq.cmd 文件 复制到C:\WINDOWS\system32文件夹下即可。
前提是你的C:\WINDOWS\system32文件夹里和当前文件夹里没有jsrq.cmd这个文件。
在批处理中输入 call jsrq.cmd // 查看帮助。
如 ：
@echo off
call jsrq //
pause
::

@echo off
:: 批处理计算日期
:: 作者: will sort  原帖出自 cn-dos联盟
:: 整理 code by  随风 @bbs.bathome.net
:: 经略微改动后,(计算部分没改)以函数形式调用,方便在批处理中计算日期.
if "%1"=="//" goto :bz
if not "%1"==":" (
for /f "delims=" %%a in ('%0 : %1 %2') do set %2=%%a
goto :eof
)
shift
setlocal ENABLEEXTENSIONS
call ate2Day %date:~0,10% sdays
set /a sdays-=%1
call ay2Date %sdays% difdate
echo %difdate%
goto :EOF
ate2Day
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
  set yy=%%a & set mm=%%b & set dd=%%c 
)
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF 
ay2Date
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF 
:bz
color 1f
echo\&echo  jsrq.cmd 计算日期，使用帮助
echo\&echo  将 jsrq.cmd 文件 复制到C:\WINDOWS\system32文件夹下即可。
echo\&echo  输入 call jsrq.cmd // 查看帮助。
echo\&echo  格式: call jsrq.cmd 参数1 参数2
echo\&echo  参数1 为要计算的天数
echo\&echo  参数2 为变量名
echo\
echo\&echo  如: call jsrq.cmd 5 num
echo\&echo  意识就是 设变量 num 等于 当前日期减 5 天的日期，
echo\&echo  如果输入的是 －5 就是当前日期加 5 天的日期
echo\&echo\&echo\&echo\&echo  按任意键退出。。。
pause>nul
cls
color 07
goto :eof
复制代码

youxi01

@echo off
call :DateDiff 2007-11-11 -2 var
echo %var%

pause>nul

:DateDiff DateStart DateDiff Result

Rem '///////////////日期计算函数///////////////////////
Rem '算法源自德国**,代码由willsort提供,youxi01改装；
Rem '===============使用方法===========================
Rem '1、要调用本段函数，先将标签下:DateDiff所有内容拷贝
Rem '到对应批处理的pause段下。
Rem '2、参数解析：DateStart是起始时间；DateDiff为时间差；
Rem 'Result用来接受传回结果。
Rem '3、如：Call :DateDiff 2007-10-21 2 Res，Res中的结果
Rem '就为：2007-10-23
Rem '==================================================
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=-" %%a in ("%~1") do set yy=%%a & set mm=%%b & set dd=%%c

set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,i=153*m+2
set /a i=i/5+dd+y*365+y/4-y/100+y/400-2472633+%2

set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
set mm=0%mm%&set dd=0%dd%

endlocal &set %3=%yy%-%mm:~-2%-%dd:~-2%&goto :eof

somebody

算法源自德国~~哈哈，这都被你知道，willsort 真会找.......找到德国去了，以为他原创的吖

more

call后的标签没有冒号
标签也没有冒号
望随风大人改正...

Batcher

有冒号不行么？报错信息是什么？

more

要加上冒号才可以用,直接复制1楼的代码用不了...