[游戏娱乐] 批处理之家论坛网站宣传小动画

batman

@echo off&setlocal enabledelayedexpansion
title made by batman 2008-08-02
:begin
echo.&echo.&echo.&echo.&set "n=0"&set "m=0"
for /f "skip=26 delims=" %%a in (%~fs0) do (
    for %%i in (0 5 10) do if !n! equ %%i set /a a=!random!%%10
    set "str=%%a"&set /a n+=1
    for %%m in (6 11) do if !n! equ %%m echo.&echo.
    if !n! neq 11 call :sp "%%a"&echo.
)
call :sp "no" 80
set "var=%str%"
:lp
set /p b=%var:~,1%<nul&set "var=%var:~1%"
for /l %%i in (1,1,100) do echo>nul
if defined var goto lp
:loop 
call :sp "no" 80
call :sp "%str%"
set /a m+=1&if !m! lss 10 goto loop
del /q ●* *-*>nul 2>nul
ping /n 3 127.1>nul&cls&goto begin 
:sp
if %1 neq "no" set /p= <nul>%1&findstr /a:0%a% .* %1*
for /l %%i in (1,1,%2) do set /p= <nul
del /q ●* *-*>nul 2>nul&goto :eof
               ●●●●    ●●●●  ●●●●●
              ●      ● ●      ●     ●
             ●●●●● ●●●●●     ●
            ●      ● ●      ●     ●
           ●●●●● ●      ●     ●
                    ●      ●  ●●●●   ●●●●   ●●●●●
                   ●      ● ●      ● ●  ●   ● ●
                  ●●●●● ●      ● ●  ●   ● ●●●●
                 ●      ● ●      ● ●  ●   ● ●
                ●      ●  ●●●●  ●  ●   ● ●●●●●
         www.bathome.net ----- It's the best professional batwebsite。
复制代码

慕夜蓝化

>_<！！！！
强！ ，我只为了改变批处理中一行颜色的字体，来到了这里，没想到那么的厉害。
大家！赞赞赞！

hack1994

●●●●  ●●●●    ●●    ●●●●  ●●●●  ●●●●  ●●●●  ●●●●  ●  ●●●●
     ●   ●         ● ●    ●    ●  ●    ●  ●    ●  ●    ●       ●   ●  ●
    ●    ●●●●  ●  ●    ●    ●  ●    ●  ●●●●  ●●●●      ●    ●  ●●●●
   ●     ●    ●  ●●●●  ●    ●  ●    ●  ●    ●  ●    ●     ●     ●        ●
  ●      ●    ●      ●    ●    ●  ●    ●  ●    ●  ●    ●    ●      ●        ●
●       ●●●●      ●    ●●●●  ●●●●  ●●●●  ●●●●   ●       ●  ●●●●

wc726842270

“findstr /a:1f .* *a.txt”后面的通配符是干什么的啊

cuipengfei

三楼的那个代码是怎么编的？看不懂！

lifenjoiner

呵呵，谢了，原理我明白。

[ 本帖最后由 lifenjoiner 于 2010-10-1 21:52 编辑 ]

bbwanwt123

我保存成bat格式

为什么运行部出来啊

Batcher

不可以
你应该向他请教一下为啥那样写^_^

lifenjoiner

原帖有误，现已纠正。

[ 本帖最后由 lifenjoiner 于 2010-10-1 21:40 编辑 ]

ljl

都是高手啊，我怎么就不能编出来了

batman

原帖由 jellyhk 于 2008-10-6 19:21 发表
本人初学！
问下 斑竹是怎么做到bat和home的颜色不一？
我怎么没看见color??请教！

颜色是在这个标签内实现变化的：

:sp
if %1 neq "no" set /p= <nul>%1&findstr /a:1%a% .* %1*
for /l %%i in (1,1,%2) do set /p= <nul
del /q %1*>nul 2>nul&goto :eof
复制代码

在cmd中键入findstr /?，你会看到这样一行： [/A:attr   指定有十六进位数字的颜色属性。
请见 "color /?"]，但这样的帮助信息会让你看得云里雾里，我就结合上面的代码来稍做下
说明：当findstr 后面跟/a:的开关时将会以紧跟在":"号后的两个颜色编码（前面一个是背景
，后面的一个是字符颜色）来输出查找内容（注意这个内容是彩色的文件名加":"号，后面
紧跟文件本身内容），我们先来段代码以帮助理解：
有文本a.txt内容如下

bathome is the best webbbs
复制代码

在cmd中键入findstr /a:1f .* *a.txt（注意后面的*是通配符是必加的）
你会发现会输出如下内容：

现在如文本内容为空，是不是仅会输出彩色的文件名了加":"号了，那么我们怎么去掉这个":"
号呢，我们就来认识一下神奇的退格符""了，退格符顾名思义就是退一格，而这个退一格
是将光标退一格，那么当标退格后再次输入的内容将会覆盖前面的内容，于是我们只要在a.txt
中输入" "（退格符+空格+退格符）是不是就将这个":"去掉了，而当sp标签的第一句命令：
if %1 neq "no" set /p= <nul>%1&findstr /a:1%a% .* %1*中的%a%和%1两个参数发生变化
屏幕输出内容和输出颜色就会相应进行变化，只是这样会每次生成一个以%1命名的文件，所以
标签中最后来个句：del /q %1*>nul 2>nul&goto :eof输出后再将生成的临时文件删除。

[ 本帖最后由 batman 于 2008-10-6 21:06 编辑 ]

jellyhk

本人初学！
问下 斑竹是怎么做到bat和home的颜色不一？
我怎么没看见color??请教！

523066680

还是喜欢第一楼的效果 --黑影

tjtchly

很高深呀，学习学习。

batman

最终定稿：

@echo off&setlocal enabledelayedexpansion
color 1f&title made by batman 2008-08-02
:begin
echo.&echo.&echo.&echo.
for /f "skip=44 delims=" %%a in (%~fs0) do (
    set "str=%%a"&set /a n+=1
    if !n! lss 11 (
       if !n! leq 5 (
          set "a=c"
          ) else (
          set "a=a"
       )
       if !n! equ 6 echo.
       call :sp "%%a"&echo.
       ) else (
       if !n! equ 11 echo.&echo.
       set "var=!str!"&call :step
       if !n! equ 15 echo.
       if !n! geq 15 call :lp
    )
)
pause>nul&goto :eof
:lp 
call :sp "no" 80
if %n% equ 15 (
   set "a=f"
   ) else (
   set "a=e"
)
call :sp "%str%"
set /a m+=1
if %m% lss 5 goto lp
if %n% equ 15 ping /n 2 127.1>nul&echo.&echo.
set "m=-5"&goto :eof
:step
set /p b=%var:~,1%<nul&set "var=%var:~1%"
for /l %%i in (1,1,200) do echo>nul
if defined var goto step 
ping /n 2 127.1>nul
call :sp "no" 80&goto :eof
:sp
if %1 neq "no" set /p= <nul>%1&findstr /a:1%a% .* %1*
for /l %%i in (1,1,%2) do set /p= <nul
del /q %1*>nul 2>nul&goto :eof
               ●●●●    ●●●●  ●●●●●
              ●      ● ●      ●     ●
             ●●●●● ●●●●●     ●
            ●      ● ●      ●     ●
           ●●●●● ●      ●     ●
                    ●      ●  ●●●●   ●●●●   ●●●●●
                   ●      ● ●      ● ●  ●   ● ●
                  ●●●●● ●      ● ●  ●   ● ●●●●
                 ●      ● ●      ● ●  ●   ● ●
                ●      ●  ●●●●  ●  ●   ● ●●●●●
                            我们，在Windows窗前
                      为了追逐的梦，叩响CMD深邃的大门
                     多少回挑灯夜战，又多少次彻夜难眠
                   身心虽已疲倦，然心中却有个坚定的信念：
                     精益求精缔造完美，不言最好只求更高
         www.bathome.net ----- It's the best professional batwebsite
复制代码

[ 本帖最后由 batman 于 2008-8-3 23:11 编辑 ]