[文本处理] [已解决]批处理从1.csv中取出.txt、.ini、.bat、.vbs的完整路径（含扩展名）

yyz219

从1.csv中取出.txt、.ini、.bat、.vbs的完整路径（含扩展名），保存为1.txt
完美解决了：

@echo off
(for /f "delims=" %%i in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    for /f tokens^=17^ delims^=^" %%j in (%%i) do (
        for /f "delims=-" %%k in ("%%j") do echo,%%k
    )
))>1.txt
复制代码

pause[/code]*****************************************************************
下面是不能正确输出的1.csv
https://pan.baidu.com/s/1D0-KYijTpeT6mD2UXB3r-g

yyz219

如果文件扩展名都是4个字符（包括.），用一个for循环+变量延迟即可：这个可以忽略，主要是自己想练练手。
qixiaobin0715 发表于 2022-9-24 10:05

     乐于助人

qixiaobin0715

如果文件扩展名都是4个字符（包括.），用一个for循环+变量延迟即可：

@echo off
for /f tokens^=17^ delims^=^" %%j in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    if "%%j"=="%%~fj" (
        set "Filen=%%~dpnj"
    ) else (
        set "Filen=%%~nj"
    )
    set "Extn=%%~xj"
    setlocal enabledelayedexpansion
    echo,!Filen!!Extn:~,4!
    endlocal
)
pause
复制代码

这个可以忽略，主要是自己想练练手。

qixiaobin0715

22楼代码化简为：

@echo off
(for /f tokens^=17^ delims^=^" %%j in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    for /f "delims=-" %%k in ("%%j") do echo,%%k
))>1.txt
pause
复制代码

yyz219

回复  yyz219


   
如果想快，建议用第3方式具gawk（  ）
hfxiang 发表于 2022-9-21 10:42

又多了一种方法，谢谢

hfxiang

回复 20# yyz219


   
如果想快，建议用第3方式具gawk（ http://bcn.bathome.net/tool/4.1.3/gawk.exe ）

@(for /f "delims=" %%a in ('gawk -F"," "$10~/\.txt/||/\.ini/||/\.bat/||/\.vbs/{print $10}" 1.csv') do @for /f "delims=-" %%b in (%%a) do @echo %%b)>1.txt 2>nul
复制代码

yyz219

回复  yyz219
那就去掉变量延迟：
qixiaobin0715 发表于 2022-9-21 10:16

    非常成功，非常感谢

yyz219

回复  yyz219
那就去掉变量延迟：
qixiaobin0715 发表于 2022-9-21 10:16

    辛苦了 谢谢

qixiaobin0715

回复 16# yyz219
那就去掉变量延迟：

@echo off
(for /f "delims=" %%i in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    for /f tokens^=17^ delims^=^" %%j in (%%i) do (
        for /f "delims=-" %%k in ("%%j") do echo,%%k
    )
))>1.txt
pause
复制代码

flashercs

0<1/*,:
@echo off
cd /d "%~dp0"
cscript -nologo -e:jscript "%~f0" "1.csv" "1.txt"
pause
exit /b
*/;
if (WScript.Arguments.length < 2) WScript.Quit();
var fso = new ActiveXObject('Scripting.FileSystemObject');
var re = /(?:")([^"]*\.(?:txt|ini|bat|vbs))[^"]*"$/igm;
try {
  var tsread = fso.OpenTextFile(WScript.Arguments(0), 1, false, -2);
  var str = tsread.ReadAll();
  tsread.Close();
  var tswrite = fso.OpenTextFile(WScript.Arguments(1), 2, true, -2);
  var arr;
  while (null != (arr = re.exec(str))) {
    tswrite.WriteLine(arr[1]);
  }
  tswrite.Close();
} catch (e) {

}
复制代码

yyz219

for指令在命令行执行与批处理内执行，其两者之间的参数对应关系为：
在命令行用单百分号（%），如下：在批 ...
hfxiang 发表于 2022-9-21 08:23

    你这些代码比主楼的慢一些，能不能加快一点（或者修改一下主楼的代码，使它支持“！”号）

谢谢

yyz219

for指令在命令行执行与批处理内执行，其两者之间的参数对应关系为：
在命令行用单百分号（%），如下：在批 ...
hfxiang 发表于 2022-9-21 08:23

非常感谢

hfxiang

for指令在命令行执行与批处理内执行，其两者之间的参数对应关系为：
在命令行用单百分号（%），如下：

@(for /f "tokens=10 delims=," %a in (1.csv) do @for /f %b in ('echo %~a^|findstr /i ".txt .ini .bat .vbs"')  do @echo "%~b")>1.txt 2>nul
复制代码

在批处理用双百分号（%%），如下：

@(for /f "tokens=10 delims=," %%a in (1.csv) do @for /f %%b in ('echo %%~a^|findstr /i ".txt .ini .bat .vbs"')  do @echo "%%~b")>1.txt 2>nul
复制代码

yyz219

回复  yyz219


   
直接在CMD窗口下试试如下指令：
hfxiang 发表于 2022-9-20 10:55

    能够正确输出，麻烦修改为批处理

谢谢

yyz219

如果数据像你提供的那么规整的话，这样效率应当更高些：未经测试。
qixiaobin0715 发表于 2022-9-20 16:37

如果文件路径中有 “！”号的时候，被过滤掉了，能不能修改一下

下面是不能正确输出的1.csv
https://pan.baidu.com/s/1D0-KYijTpeT6mD2UXB3r-g