[文本处理] 文本批量替换字符的批处理求助

haichuan5121

各位大神好：
有一批文本内容格式如下；RCP格式可以记事本打开；判断文件名是否包含04T字符，不包含04T的文件将C0_E0后面的1,0,0或2,0,0替换为3,0,1
SMD-Product,C:\AV03-2322-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\AV03-2322-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,1,0,0,C:\AV03-2322-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,2,0,0,S3 or S4,,
,,,,,,,,,,,,

qixiaobin0715

回复 21# haichuan5121
根据24楼代码进行完善，满足21楼2个附加条件：
1.非法输入提示重新输入；
2.只有一组C0-E0不执行操作；

@echo off
setlocal enabledelayedexpansion
:a
set /p n=Please Input a number: 
set x1=C0_E0,1,0,0
set x2=C0_E0,2,0,0
set x3=C0_E0,3,0,1
set a=1
for /l %%i in (1,1,3) do (
    for /l %%j in (1,1,3) do (
        set m=%%i%%j
        if !n! equ !m! (
            set a=
            set a1=!x%%i!
            set a2=!x%%j!
        )
    )
)
if defined a (
    echo,Input error!
    goto :a
)
set Groups="C0_E0,1,0,0" "C0_E0,2,0,0" "C0_E0,3,0,1"
set Sub=`
for /f "delims=" %%i in ('findstr /imr "C0_E0,.*C0_E0," *.RCP^|findstr /iv "04T"') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        for %%k in (%Groups%) do set "str=!str:%%~k=%Sub%!"
        for /f "tokens=1,2* delims=%Sub%" %%a in ("!str!") do (
            if not "%%c"=="" (
                echo,%%a!a1!%%b!a2!%%c
            ) else (
                echo,%%j
            )
        )
    ))>"New-%%i"
)
pause
复制代码

haichuan5121

回复 31# WHY


    新文本更改后缀会不能识别，改成前缀比较好，替换源文件用这个 fso.OpenTextFile(f & ".RCP", 2, True).Write s为甚报错 没有指定Input a Number:22
C:\Users\1111\Desktop\PI\PTN测试新.bat(36, 9) Microsoft JScript 运行时错
误: 'True' 未定义

请按任意键继续. . .

qixiaobin0715

回复 32# WHY
实际上代码中延迟变量开关位置设置有问题，不应当放在循环内，把setlocal enabledelayedexpansion移到@echo off下一行，就不会出现报错的问题。谢谢提醒！

WHY

回复 30# qixiaobin0715

可以在 goto :a 的上一行插入 endlocal

WHY

本来不想再在这个帖子浪费时间，想想还是贴出来，其他人有可能会参考一下下。

@if(0)==(0) echo off
for %%i in (11 12 13 21 22 23 31 32 33) do set _%%i=1
:Loop
set /p "Input=Input a Number:"
setlocal enabledelayedexpansion
if not defined _!Input! (
    endlocal
    echo;Input Error
    goto :Loop
) else (
    endlocal
    dir /b /a-d *.rcp | findstr /i /v "04T" | cscript -nologo -e:jscript "%~f0" "%Input%"
)
pause & exit
@end

var arg = WSH.Arguments(0);
var arr = ['C0_E0,1,0,0', 'C0_E0,2,0,0', 'C0_E0,3,0,1'];
var reg = new RegExp('C0_E0,[123],0,[01]', 'ig');
var fso = new ActiveXObject('Scripting.FileSystemObject');

var replacement = function(s0) {
    var i = arg.substr(n, 1);
    n += 1;
    return n<=2 ? arr[i-1] : s0;  //replace only 2 times
}

while (!WSH.StdIn.AtEndOfStream) {
    var n = 0;
    var f = WSH.StdIn.ReadLine();
    var objFile = fso.OpenTextFile(f, 1);
    var s = objFile.ReadAll();
    objFile.Close();
    if (s.split(reg).length > 2) {
        s = s.replace(reg, replacement);
        fso.OpenTextFile(f + '.Log', 2, 1).Write(s);
    }
}
复制代码

qixiaobin0715

回复 29# WHY

是要在第2、3行加上一行endlocal，是吗？

WHY

回复 28# qixiaobin0715


    如果提示输入错误次数超过32次，可能会报语法错误。因为变量延迟递归层数限制在32以内。
当然这是从批处理语法上说的，实际中没人会一直输入错误。

qixiaobin0715

回复 24# qixiaobin0715
又仔细检查了24楼代码，是有点问题，影响不大，只是在文本文件中压根不存在"C0_E0,1,0,0" "C0_E0,2,0,0" "C0_E0,3,0,1"这3个字符串时，会生成与源文件内容相同的新文件而不会被后面的del命令删除。分别将代码第34、38行修改如下：

if not "%%c"=="" set a=1
if not defined a del "New-%%i"
复制代码

qixiaobin0715

回复 26# haichuan5121
不要纠结我写的这个了，没仔细检查，可能是哪个地方有问题，楼上有能用的就好。

haichuan5121

回复 24# qixiaobin0715


    文本验证文本没有更新也没生成新的文本，源文件也没有变化没看出来问题在哪儿

WHY

<# :
@echo off
PowerShell ". ([ScriptBlock]::Create((gc -Literal '%~f0') -join \"`r`n\")) '%~dp0'"
pause & exit
#>

While (($myInput = Read-Host 'Input a Number') -notMatch '^[123][123]$') {
    echo 'Input Error!';
}

$HashTab = @{'1'='C0_E0,1,0,0,'; '2'='C0_E0,2,0,0,'; '3'='C0_E0,3,0,1,'}
$reg     =[regex]'(?i)C0_E0,[123],0,[01],';
$replace = {
    $key = $myInput.SubString($global:n, 1);
    $global:n += 1;
    $HashTab[$key];
}

forEach ($file In (dir -Literal $args[0] -Filter *.rcp)) {
    If ($file -is [IO.FileInfo] -and $file.BaseName -notMatch '04T') {
        $global:n = 0;
        $s = (gc -Literal $file.FullName -ReadCount 0) -join "`r`n";
        If ($reg.Matches($s).Count -gt 1) {
            $s = $reg.Replace($s, $replace, 2);   #Replace Only 2 Times
            sc -Literal $file.FullName -Value $s;
        }
    }
}
复制代码

qixiaobin0715

1.非法输入提示重新输入，返回开始输入界面；
2.判断不符合条件不操作，其一是比较繁琐，其二可能效率会受到影响；不如先操作后判断，不符合条件时删除生成的文件；

@echo off
:a
set /p n=Please Input No. :
setlocal enabledelayedexpansion
set x1=C0_E0,1,0,0
set x2=C0_E0,2,0,0
set x3=C0_E0,3,0,1
set a=1
for /l %%i in (1,1,3) do (
    for /l %%j in (1,1,3) do (
        set m=%%i%%j
        if !n! equ !m! (
            set a=
            set a1=!x%%i!
            set a2=!x%%j!
        )
    )
)
if defined a (
echo,Please Input again
goto :a
)
set Groups="C0_E0,1,0,0" "C0_E0,2,0,0" "C0_E0,3,0,1"
set Sub=`
for /f "delims=" %%i in ('dir /b /a-d *.RCP^|findstr /v "04T"') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        for %%k in (%Groups%) do set "str=!str:%%~k=%Sub%!"
        if "!str!"=="%%j" (
            echo,%%j
        ) else (
            for /f "tokens=1,2* delims=%Sub%" %%a in ("!str!") do (
                echo,%%a!a1!%%b!a2!%%c
                if "%%c"=="" set a=1
            )
        )
    ))>"New-%%i"
if defined a del "New-%%i"
)
pause
复制代码

77七

回复 19# qixiaobin0715


   大佬说得对，有时候没必要考虑这个感叹号，但是我想，一是楼主提供的文本只是部分；二是主要想多写写，折腾...

aloha20200628

回复 20# aloha20200628

给一个调用 powershell 低版本也能可靠运行的代码...
命令行的参数组合用法如同20楼说明

@echo off &setlocal &if "%~2"=="" exit/b
if "%~1"=="3" (set "v1=_C0_E0,3,0,1,") else (set "v1=_C0_E0,%~1,0,0,")
if "%~2"=="3" (set "v2=_C0_E0,3,0,1,") else (set "v2=_C0_E0,%~2,0,0,")
powershell "dir *.rcp -exclude '*04T*'|%%{ $s=(gc -raw $_.name); $p=($s -replace '_C0_E0,\d,0,\d,', '◆').split('◆'); $s=$p[0]+'%v1%'+$p[1]+'%v2%'+$p[2]; sc ($_.basename+'.new.rcp') $s.trim() }"
endlocal&pause&exit/b
复制代码