[文件操作] 【已解决】求助批处理删除特殊字符

lj670

mp4文件名中包含有许多特殊字符☀ ✦ ♬ ♭ ♩等等需要删除掉，用删除一般字符的脚本无法删除这些，求助各位大佬，谢谢！🙏🙏
例如：
高清✦ 难以置信的美丽.mp4
高清难☀☀以置信的美丽.mp4
高清难以置信的♬ ♭美丽.mp4

lj670

回复 4# aloha20200628

运行完美，速度非常快，处理4150个视频用时65秒，谢谢🙏🙏

lj670

回复 3# Five66

非常行，运行完美，不用指定，去除所有特殊字符，谢谢🙏🙏🙏

lj670

回复 2# 77七


    运行完美，非常好！谢谢🙏🙏

aloha20200628

回复 1# lj670

@echo off & chcp 936>nul &setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b/a-d *.mp4') do set "a=%%a" &ren "%%a" "!a:?=!"
pause&exit/b
复制代码

Five66

不知行否

@echo off&chcp 936
for %%a in (*.mp4) do (
set old=%%a
for /f "delims=" %%b in ('echo "%%a"') do (
set "new=%%~b"
setlocal enabledelayedexpansion
echo rename "!old!" to "!new:?=!"
rename "!old!" "!new:?=!"
endlocal
)
)
pause&exit/b
复制代码

77七

@echo off
rem 保存为utf-8编码
chcp 65001 >nul
set str="☀" "✦" "♬" "♭" "♩"
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
	set n=%%~ni
	if defined n (
		setlocal enabledelayedexpansion
		set _n=!n!
		for %%a in (%str%) do (
			set _n=!_n:%%~a=!
		)
		ren "!n!%%~xi" "!_n!%%~xi"
		endlocal
	)
)
pause
复制代码