[文本处理] 求助批处理copy合并指定的时间段txt文件到一个txt里

yp2121540

好比现在一个文件夹下包含多个文件 命名格式分别是2019-01-01 XXX.txt  现在我想取 2019-01-01 到2019-01-15号的txt文件内容到 一个新的txt文件，请大神帮忙~ 在线坐等

yp2121540

已经解决 谢谢大家

yp2121540

回复 6# flashercs


   
    这个脚本只适用于.txt文件么  .sql文件不适合么？

yp2121540

回复 7# Batcher


    这个脚本只适用于.txt文件么  .sql文件不适合么？

Batcher

回复 4# yp2121540


    3楼代码无法处理这个情况是吗？请把你的测试用例和测试结果发出来看看，我试试能否重现你的问题。

flashercs

@echo off
set "searchdir=."
set "searchpattern=????-??-?? *.txt"
set "newfile=.\new.txt"
set startdate=2019-01-01
set enddate=2019-01-15

cd . >"%newfile%"
for /f "delims=" %%A in ('where "%searchdir%:%searchpattern%"') do (
  for /f "tokens=1" %%B in ("%%~nxA") do (
    if %%B geq %startdate% (
        if %%B leq %enddate% (
          REM echo %%A
          copy /y /b "%newfile%"+"%%A"
          echo.>>"%newfile%"
        )
      )
  )
)
pause
exit /b
复制代码

yp2121540

回复 3# Batcher


    整合的时候能不是一个长串么   都用回车隔开

yp2121540

回复 3# Batcher


    如果我这标题格式 不只有日期呢？如2019-01-05  XXXXXXX_part.txt   我这是否可以这样模糊搜索 这一类时间段的文件？

Batcher

回复 1# yp2121540

@echo off
setlocal enabledelayedexpansion
REM 设置开始日期
set start=2019-01-01
REM 设置结束日期
set end=2019-01-15
set /a sy=%start:~,4%,sm=1%start:~5,2%%%100,sd=1%start:~8,2%%%100,ey=%end:~,4%,em=1%end:~5,2%%%100,ed=1%end:~8,2%%%100,a=31
for %%a in (1 3 5 7 8 10 12 4 6 9 11) do (
    if %%a equ 4 set /a a-=1
    set /a _%%a=a
)
(for /l %%a in (%sy%,1,%ey%) do (
    set /a "_2=^!(%%a%%4)&^!(^!(%%a%%100))|^!(%%a%%400)+28"
    set /a a=1,b=12
    if "%%a" equ "%sy%" set /a a=sm
    if "%%a" equ "%ey%" set /a b=em
    for /l %%b in (!a!,1,!b!) do (
        set /a c=1,d=_%%b
        if "%%a%%b" equ "%sy%%sm%" set /a c=sd
        if "%%a%%b" equ "%ey%%em%" set /a d=ed
        for /l %%c in (!c!,1,!d!) do (
            for %%d in (%%b %%c) do set ".%%d=0%%d"&set ".%%d=!.%%d:~-2!"
            echo %%a-!.%%b!-!.%%c!
        )
    )
))>"%temp%\DateList.txt"

type nul >"结果.txt"
for /f %%a in ('type "%temp%\DateList.txt"') do (
    if exist "%%a*.txt" (
        type "%%a*.txt" >>"结果.txt"
    )
)
复制代码

yp2121540

有没有人帮忙下 ，谢谢  怎么写 能给批处理代码粘贴下么