[文本处理] 想VBA和PDFtk结合给指定的PDF加标签，中途报错，求方案。

qd2024

开始的时候，我想用VBS +PDFtk来解决
执行VBS时，提示选择PDF文件，
与VBS同级目录下有 标签.txt 一行一个内容，按行数对应该PDF的页数，一行一页，一个标签
但是没有实现

后改VBA  中间有报错 没结果


链接：https://pan.baidu.com/s/1IPWaUsmx1IV-LpkBNUZRoQ?pwd=0jfb
提取码：0jfb
--来自百度网盘超级会员V10的分享

与EXECL文件同级文件平　PDFtk 下有 PDFtk.exe文件
运行VBA时提示选择文件，选择目录开始在当前目录
利用VBA为所选PDF文件添加标签，
A1对应PDF第1页
A2对应PDF第2页
A3对应PDF第3页
A4对应PDF第4页
A5对应PDF第5页
A6对应PDF第6页
……
以此类推


所有需要的临时文件都在 \TEMP 中

ppll2030

VBA不熟。就不搀和了。习惯了用批处理，看看合不合用吧。
注意：
代码一定一定要保存为UTF-8格式的bat文件。
bat文件跟pdftk.exe文件放一块。
书签明细可在脚本后修改。
PDF文件支持拖放，也可打开后手动输入。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi
set /a n=1
rem skip数值以 "以下为书签名单" 所在行为准
(for /f "skip=24 tokens=* delims=" %%a in ('type "%~f0"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
pdftk "%f%" update_info_utf8 bookmark.txt output "%_nf%_bookmark%_xf%"
del /q bookmark.txt
pause&exit

以下为书签名单：
红旗小学1
红旗小学2
红旗小学3
红旗小学4
红旗小学5
红旗小学6
红旗小学7
红旗小学8
红旗小学9
红旗小学10
红旗小学11
红旗小学12
红旗小学13
红旗小学14
红旗小学15
红旗小学16
红旗小学17
红旗小学18
红旗小学19
红旗小学20
红旗小学21
红旗小学22
红旗小学23
红旗小学24
红旗小学25
红旗小学26
红旗小学27
红旗小学28
红旗小学29
红旗小学30
复制代码

qd2024

回复 2# ppll2030


    辛苦了 谢谢

   因为要经常更换标签     能不能在 bat  同级下 放一下 标签.txt  把标签 内容放在这里 感谢

     bat   pdftk.exe  标签.txt

ppll2030

回复 3# qd2024


    把12行的内容改一下就可以了。
自己新建一个标签.txt，一行开始直接放标签明细即可。

(for /f "delims=" %%a in ('type "标签.txt"') do (
复制代码

qd2024

回复 4# ppll2030
链接：https://pan.baidu.com/s/1GduyUNl_tyKOVOb9ONT6FQ?pwd=mek3
提取码：mek3
--来自百度网盘超级会员V10的分享

我尝试了 没有成功  PDFtk  我在同级和目录里都放了  不行

我的PDF文件里有  _    基本都是  0098_XXXXXX    把_删除 也不行

   

辛苦再帮我看看 谢谢

aloha20200628

回复 5# qd2024

本帖的关键是pdftk.exe要求加入 ‘包含中文标签’ 的设置文件须为utf-8编码（无BOM头标），其文件名似乎还须是单字节ascii字符
以下代码存为test.bat，放在 *.pdf，标签.txt，pdftk.exe 等文件同在的目录下运行，先用 "标签.txt" 生成 "BMu8.txt" ，再将其转码为无头标utf-8，最后调用pdftk生成 "*.new.pdf" 即为楼主所要...

<# ::
@echo off &if not exist "*.pdf" (exit/b) else if not exist "标签.txt" exit/b
powershell "iex(${%~f0}|out-string)" &if not exist "BMu8.txt" exit/b
for %%F in (*.pdf) do (set "pF=%%F"&set "_pF=%%~nF.new.pdf")
pdftk.exe "%pF%" update_info_utf8 "BMu8.txt" output "%_pF%"
del "BMu8.txt"&pause&exit/b
#>
$n=1; $s=foreach($l in gc "标签.txt") {
	echo("BookmarkBegin`nBookmarkTitle: "+$l+"`nBookmarkLevel: 1`nBookmarkPageNumber: "+($n++))
}; [io.file]::writeAlllines("BMu8.txt", $s); exit
复制代码

qd2024

回复 6# aloha20200628


    谢谢了。但是我每次处理时试卷不同，PDF文件名不同，这样每次改BAT里的关键字，有点麻烦，
                看看有没有其他方法，我保证 与bat 标签.txt pdttk.exe 同级目录只有一个*.pdf  让代码直接修改这个PDF文件 达成目标

万分感谢。

aloha20200628

回复 7# qd2024

6楼代码已订正，再试试吧
确保运行时，当前目录中存在 ‘唯一’ 的目标文件 *.pdf 及其 "标签.txt" 和 pdftk.exe+libiconv2.dll 文件...
订正后的代码先检查 *.pdf 及其 “标签.txt” 是否存在，缺一者即退出...

ppll2030

回复 5# qd2024


    你把标签.txt也要保存为UTF-8的格式就可以了。

ppll2030

回复 5# qd2024


    再次修改了一下脚本，这样你就不需要把PDF文件跟脚本放一块了。这样应该更方便一些。
注意：
代码一定要保存为UTF-8编码格式的bat文件，跟pdftk放置一块
标签.txt一定一定要保存为UTF-8编码格式的txt文件
标签.txt和PDF放在一起即可，不需要把他俩复制粘到pdftk的同一个文件夹内。
直接拖拽PDF到bat上面即可，也可先打开bat，再拖拽过去，或复制PDF完整路径进来。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~dpni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
rem 标签.txt一定一定要保存为UTF-8编码格式的txt文件
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>!_pf!bookmark.txt
%~dp0pdftk "!f!" update_info_utf8 "!_pf!bookmark.txt" output "!_nf!_bookmark!_xf!"
del /q !_pf!bookmark.txt
echo.&echo.书签添加完毕！&timeout /t 3 &exit
复制代码

qd2024

回复 10# ppll2030

不放在桌面  移动到D盘下 测试成功
有没有可能 直接在我的PDF文件上添加标签   或者用方法做中介 最后只保留与我源文件同名的添加好标签的文件即可

辛苦了 谢谢

ppll2030

回复 11# qd2024


    直接改动源文件比较危险哦。切记做好备份
关于桌面失败，可能是路径带空格的问题，现已修复，你可以再试试。
在代码第20行后面添加了两行，直接改动源文件，默认无备份，需要备份就去掉21行的两个::冒号。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
"%~dp0pdftk" !f! update_info_utf8 "!_pf!bookmark.txt" output "!_pf!!_nf!_bookmark!_xf!"
rem 备份源文件，需要去掉前面两个 :: 冒号
::ren "!f!" "!_nf!_bak!_xf!"
move /y "!_nf!_bookmark!_xf!" !f! >nul
del /q "!_pf!bookmark.txt"
echo.&echo.书签添加完毕！&timeout /t 3&exit
复制代码

77七

批处理调用pdftk.exe给pdf文件逐页添加书签

@echo off
rem "批处理调用pdftk给无书签的pdf文件按照 书签文本每一行对应pdf每一页 添加书签（如果某页不需要书签，则书签文本对应行留空）"
rem "批处理和书签文本全部保存为utf-8编码，pdftk添加到环境变量，书签文本格式txt，与pdf文件同名"
chcp 65001 >nul
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
	if exist "%%~ni.txt" (
		pdftk "%%i" dump_data_utf8 output |find "BookmarkTitle:" 1>nul
		if errorlevel 1 (
			(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%~ni.txt"') do (
				if "%%b" neq "" (
					echo BookmarkBegin
					echo BookmarkTitle: %%b
					echo BookmarkLevel: 1
					echo BookmarkPageNumber: %%a
				)
			))>report.txt
			pdftk "%%i" update_info_utf8 report.txt output "%%~ni_new.pdf"
		)
	) else (
		echo 未找到文本 [%%~ni.txt]
	)
)
del report.txt 2>nul
pause
复制代码

qd2024

回复 12# ppll2030


    感谢 D盘测试成功  完美      桌面还是闪过，可以忽略  不是一定要放在桌面的

再次感谢

qd2024

回复 13# 77七


    辛苦了  感谢