qzwqzw

用批处理的办法基本无解

这个问题源于Explorer的拖放扩展程序shell32.dll
注册表路径位于HKEY_CLASSES_ROOT\CLSID\{86C86720-42A0-1069-A2E8-08002B30309D}
因为它没有将“&"视为转义符号
所以不会用引号对将其扩起取消转义

所以对于这个问题无非以下几个方案：
1、修改拖放扩展程序shell32.dll，让它可以处理"&"的情况；
2、新建拖放扩展程序，专门处理cmd之类程序的路径过滤；
3、在处理前告知用户使用"&"的情况可能出错，交由用户处理发生的异常；

qzwqzw

说下，和shell32.dll没关系，明显是cmd的事情。。。
slore 发表于 2011-3-25 17:32

呵呵
这可真是公说公有理婆说婆有理了
cmd怪shell32不把&用引号包裹住再交过来
shell32怪cmd自己不把赤裸的&管教好
一嘴烂账没法说清

不过又回头多想了一下
这个问题仍有探索的余地
余地就在%cmdcmdline%
那里包裹了更多的信息
想办法处理了一下
因为以前很少关注转义字符的处理
费了许多功夫才大致完成
最终的结果是给定的12个特殊文件处理了11个
唯一剩下的一个(abc)&(xyz).cmd
没什么好办法
因为它直接导致批处理无法启动

:: 测试多个怪僻文件名直接拖拽到批处理文件上，批处理是否正确处理这些文件名
@echo off
rem pause
if not [%1]==[] goto :start
echo 正在生成测试文件
echo.>abc.cmd
echo.>"abc xyz.cmd"
echo.>"abc^xyz.cmd"
echo.>"abc&xyz.cmd"
echo.>"abc & xyz.cmd"
echo.>"(abc)(xyz).cmd"
echo.>"(abc) (xyz).cmd"
rem echo.>"(abc)&(xyz).cmd"
echo.>"(abc) & (xyz).cmd"
echo.>"abc;xyz.cmd"
echo.>"abc,xyz.cmd"
echo.>"abc=xyz.cmd"
echo @echo 溢出漏洞存在！^&pause>xyz.cmd
echo 测试文件生成.
goto :eof

:start
echo starting...
set _line="%cmdcmdline:"=＂%"
set _line=%_line:^=＾%
set _line=%_line:&=＆%
set _line=%_line:(=（%
set _line=%_line:)=）%
set _line=%_line:,=，%
set _line=%_line:;=；%
set _line=%_line: =□%
rem set _line
rem pause
setlocal EnableDelayedExpansion
for %%f in (%_line:~1,-1%) do set _line2=!_line2!＝%%f
endlocal & set _line=%_line2:□= %
set _line=%_line:＂="%
set _line=%_line:~9,-1%
rem set _line
rem pause
setlocal EnableDelayedExpansion
for %%f in (%_line%) do (
	set _file="%%~f"
	set _file=!_file:＾=^^!
	set _file=!_file:＆=^&!
	set _file=!_file:（=^(!
	set _file=!_file:）=^)!
	set _file=!_file:，=,!
	set _file=!_file:；=;!
	set _file=!_file:＝==!
	if exist !_file! (echo ---!_file!---) else 	(echo ___"%%~f"____)
)
endlocal
echo 结束
pause
复制代码

另外
转义字符的处理过程中
又遇到了等号的替换问题
顺便提供了一种新思路

@echo off & setlocal EnableDelayedExpansion
set _exp=var＝value
set _exp
set _exp=%_exp:＝==%
set _exp
echo 全角等号可以直接替换
pause
set _exp=var=value
set _exp
for %%f in ("=") do (
	call set _exp=!_exp:%%~f=-!
)
set _exp
echo 半角等号不能直接替换
pause
set _exp=var=value
set _exp
set _exp=%_exp: =□%
set _exp=%_exp:;=；%
for %%e in (%_exp%) do set _exp2=!_exp2!＝%%e
set _exp=%_exp2:□= %
set _exp=%_exp:；=;%
set _exp=%_exp:~1%
set _exp
echo 转折的办法：把非等号的for分隔符替换掉，再用for遍历被等号分隔的所有串，并且用等号的替换字符连接这些串，最后将其它分隔符恢复，不支持处理连续的等号
pause
复制代码

qzwqzw

qzw居然把我那个例子拿出来了
zqz0012005 发表于 2011-4-29 19:39

恕我无知
竟然不知道那段文字引用了你哪个例子

关于等号替换
我认为稳妥的办法还是逐个字符检测
特殊字符可以另行处理

@echo off
set _exp=if "%%a%%"=="%%b%%" echo 2^^3=8^>out.txt
set _exp
set "_exp=%_exp:"=＂%"
:loop
if "%_exp:~0,1%"=="=" (
	set "_exp2=%_exp2%＝"
) else (
	set "_exp2=%_exp2%%_exp:~0,1%"
)
set "_exp=%_exp:~1%"
if not "%_exp%"=="" goto :loop
set "_exp=%_exp2:＂="%"
set _exp2=
set _exp
echo 老实的办法：逐个字符判断是否等号，是则替换，不是则直接连接
pause
复制代码