ppll2030

回复 1# delab-1


    如果你只是替换A/B/C/D/E这些固定位置的数值，类似制作多人奖状，邀请函等要变更多人姓名，时间等的操作，可以用word的邮件合并功能。

ppll2030

回复 9# delab-1


    哈。看来是我理解错误了。再来用VBS脚本来试试吧。
1、把你要替换的文本保存为export.txt，要用编码ANSI，否则遇到中文会乱码。
格式如下：
AAAA=1111
BBBB=2222
CCCC=3333
2、把下面代码保存为VBS文件，也是用ANSI编码。
3、以上两个文件跟你的word文件放一块，最后执行vbs文件即可。

Set fso = CreateObject("Scripting.FileSystemObject")
Set path = fso.GetFolder(".")
Set file = fso.OpenTextFile(path & "\export.txt", 1)

Set wordApp = CreateObject("Word.Application")
Set doc = wordApp.Documents.Open(path & "\export.docx")

Do Until file.AtEndOfStream
    line = file.ReadLine()
    If InStr(line, "=") > 0 Then
        oldstr = Split(line, "=")(0)
        newstr = Split(line, "=")(1)
        With doc.Content.Find
        .Text = oldStr
        .Replacement.Text = newStr
        .Execute ,,,,,,,,,,2
        End With
    End If
Loop

file.Close
doc.Save
doc.Close

wordApp.Quit
Set fso = Nothing

MsgBox "替换完成！"
复制代码

ppll2030

回复 18# delab-1


    为什么txt非要用utf-8呢。默认不是ANSI编码的吗
下面是按你要求修改的。

Set fso = CreateObject("Scripting.FileSystemObject")
Set path = fso.GetFolder(".") 

Set objStream = CreateObject("ADODB.Stream")
objStream.Charset = "utf-8"
objStream.Open
objStream.LoadFromFile(path & "\export.txt")
content = objStream.ReadText

Set wordApp = CreateObject("Word.Application")
Set doc = wordApp.Documents.Open(path & "\export.docx") 

line = Split(content, vbCrLf)
For i = 0 To UBound(Line)
    If InStr(line(i), "=") > 0 Then
        oldstr = Split(line(i), "=")(0)
        newstr = Split(line(i), "=")(1)
        With doc.Content.Find
        .Text = oldStr
        .Replacement.Text = newStr
        .Execute ,,,,,,,,,,2
        End With
    End If
next
doc.Save
doc.Close

objStream.Close
wordApp.Quit
Set fso = Nothing

MsgBox "替换完成"
复制代码

ppll2030

回复 21# delab-1


    就用你的"笨方法"，让脚本帮你从文本末尾行开始向上读取好啦。
把代码第 14 行，改为：

For i = UBound(line) to 0 step -1
复制代码