77七

@echo off
set root_dir=c:\

set folderlist="Intel" "PerfLogs" "Program Files" "Program Files (x86)" "Windows" "Users" "8888" "Boot" "Config.Msi" "Documents and Settings" "MSOCache" "ProgramData"
set filelist="kernel*.*" "sealdr*.*" "ABSPE*.*" "bootmgr*.*" "BOOTSECT*.*"
for %%a in (%folderlist%) do (
	set d"%%~a"=1
)

setlocal
pushd "%root_dir%"
for /f "delims=" %%i in ('2^>nul dir /b /a-d %filelist%') do (
	set f"%%i"=1
)
for /f "delims=" %%d in ('dir /b /a') do (
	if exist "%%d\" (
		if not defined d"%%d" (
			echo rd /s /q "%%d"
		)
	) else if not defined f"%%d" (
		echo del /a /f "%%d"
	)
)
popd
endlocal

pause
复制代码

77七

回复 9# ygqiang



如果要求不严谨，突出一个“能用就行“，楼主可试试以下代码 (删除操作需删除echo 及转义符^再执行)。

@echo off
set root_dir=c:
(for /f "delims=" %%a in ('dir /b /a "%root_dir%" ^| findstr /livbg:"%~f0"') do (
        echo rd /s /q "%root_dir%\%%a" ^|^| del /a /f "%root_dir%\%%a"
)) 2>nul
pause
exit
Intel
PerfLogs
Program Files
Program Files (x86)
Windows
Users
8888
Boot
Config.Msi
Documents and Settings
MSOCache
ProgramData
kernel
sealdr
ABSPE
bootmgr
BOOTSECT
复制代码

77七

回复 11# ygqiang


   文件夹和文件横着写成了两行，竖着却只有一列，已经埋下了“祸根”，无法区分文件、文件夹，只有区分它们之后才可进行文件夹的完全匹配、文件的开头匹配，假如匹配末尾（保留*.txt，很常见），代码则完全不适用。
假如仍要写成竖列，比如写两列，以列区分 或者以行区分 或者添加辅助字符去区分，代码进一步复杂，属于多此一举，且真正降低了代码的可读性、可维护性。

77七

回复 14# ygqiang


  ”pagefile.sys“ 这个子文件包括在文件夹的排除列表中了，即变量 !d!，会导致误删，还需要更可靠的方法分辨文件夹和文件。