aloha20200628

回复 25# qd2024

看楼主用数学题轮训各位热心解答者，也跟一帖。
代码说明：
一。获取dir简报结果至少须用 "delims=" 禁止系统分隔符（,; =），须用 /s 获取全路径文件名
二。用双引号包裹命令表达式，减少打理转义符的麻烦
三。ffprobe筛选时长的参数表达式虽然很多，但其输出效率之差可忽略，选择最轻量化代码即可
四。本帖要求时长误差是分钟级，故可免去调用外部浮点运算功能

以下代码可存为test.bat，将一级目录拖给它即可，完成一级目录及其子目录的更名》源目录名【时长】。

@echo off
if "%~1"=="" (exit/b) else (setlocal enabledelayedexpansion)
set fpb="C:\ffmpeg\bin\ffprobe.exe"
for /f "delims=" %%D in (' dir /b/s/ad "%~1" ') do (
	for /f "delims=" %%F in (' dir /b/s/a-d "%%~D\*.mp4" ') do (
		for /f "tokens=1-4 delims=:. " %%1 in (' "%fpb% "%%~F" 2>&1 | findstr /ic:"Duration:" " ') do (
			set/a "m+=%%2*60+%%3,s+=%%4">nul 2>nul
		)
	)
	set/a "ms=s/60,sm=s%%60,m+=ms">nul 2>nul
	if !sm! neq 0 (set/a m+=1)
	ren "%%~D" "%%~nxD【!m!】" & set/a "mm+=m,m=s=0"
)
ren "%~1" "%~nx1【!mm!】"
endlocal&exit/bCOPY

aloha20200628

给一个不调用ffprobe.exe的bat+jscript混编版本，直接调用windows系统内置的fso功能获取媒体文件属性（如时长），与用ffprobe.exe/mediainfo.exe等外部方法对比可明显提速（尤其是大目录操作），因批处理脚本调用后者是逐个文件处理，而前者能一次性批量处理。
以下代码可存为test.bat，将一级目录拖给它即可，完成一级目录及其子目录的更名》源目录名【时长】。

@set @v=1 /*
@echo off
if "%~1"=="" (exit/b) else (setlocal enabledelayedexpansion)
(for /f "delims=" %%D in (' dir /b/s/ad "%~1" ') do (
	for /f %%v in (' " dir/b/s/a-d "%%~D\*.mp4"|cscript /e:jscript "%~f0" " ') do (set "m=%%v")
	set/a "mm+=!m!" & ren "%%~D" "%%~nxD【!m!】"
)
ren "%~1" "%~nx1【!mm!】" & endlocal & exit/b) 2>nul
*/
m = s = ms = sm = 0, ws = WSH.stdin, sa = WSH.createobject('shell.application');
while (!ws.atendofstream) {
	F = ws.readline(); i = F.lastIndexOf('\\'), pF = F.substr(0,i+1), nF = F.substr(i+1);
	ns = sa.namespace(pF), pn = ns.parsename(nF); d = ns.getdetailsof(pn,27).split(':');
	m += ~~d[0]*60 + ~~d[1]; s += ~~d[2];
}
WSH.echo(m+=Math.ceil(s/60));COPY

aloha20200628

回复 31# newswan

类同资源管理器各种媒体文件文件属性列表中的时长。可修改29楼代码中的*.mp4（扩展名），验证结果...

aloha20200628

回复 34# qd2024

27楼或29楼代码中的第5行》修改 *.mp4 为 *.mp? 即可包括 mp4/mp3 音视频文件
如果子目录中全是常见类型的音视频文件（mp4/mkv/avi/wmv/vob/ts/mpg/mp3/flac/wav/...），可修改为 *.* 通配符涵盖所有文件。