批处理之家 - Powered by Discuz! Board

标题: [其他] [已解决]批处理怎样把标准错误信息向变量中存储？ [打印本页]

作者: ming_fox 时间: 2010-5-20 11:12 标题: [已解决]批处理怎样把标准错误信息向变量中存储？

大家好，哪位高手能给一个简单的批处理文件，能满足下面的要求：
执行【del】命令，如果出错了的话当然会有出错信息，这时要把出错信息
重定向到【error.log】文件中去。
同时我想把标准错误流（“2”）中的错误信息存到一个变量里面去，因为下面会用到
它进行一些判断。

请问类似这样的功能能实现么，如果能的话，方便的话给一个简单的小例子，谢谢~~

[ 本帖最后由 ming_fox 于 2010-5-21 15:57 编辑 ]

作者: ming_fox 时间: 2010-5-20 11:45

有高人路过么，还是这个思路有问题，不能实现呢？

作者: ming_fox 时间: 2010-5-20 11:56

执行的命令不一定是【del】，任何一个能出错误信息的命令都是可以的。
期待中……

作者: caruko 时间: 2010-5-20 12:25

IF ERRORLEVEL number command

ERRORLEVEL 是程序执行情况的返回值,执行成功,值为0,失败则看情况有不同的值..

作者: caruko 时间: 2010-5-20 12:29

比如
ping 127.1
echo %ERRORLEVEL%

如果成功,返回值为0,一般的失败则为1
中途clrt+c,则返回值为-1073741510
丢包,也有不同的返回值,具体自己测试

作者: ming_fox 时间: 2010-5-20 12:33

原帖由 caruko 于 2010-5-20 12:25 发表
IF ERRORLEVEL number command

ERRORLEVEL 是程序执行情况的返回值,执行成功,值为0,失败则看情况有不同的值..

谢谢回复俄！
errorlevel这个变量我知道，但是问题是del这个命令貌似有bug，成功不成功都会返回0，所以
我就想通过获得标准错误流中的信息进行判断！所以想把标准错误的值输入到变量里面。

作者: Spring 时间: 2010-5-20 13:18

任意一个命令？什么叫做出错？怎么判断出错？
比如下面三个命令：

@echo off
::一个不存在的文件
set file=不存在的文件.txt
for %%a in (del,type,attrib) do call :Play %%a
pause
goto

:Play
echo.
echo 执行命令:  %1 %file%
echo.
echo 标准输出:
%1 %file% 1>con 2>nul
echo 错误代码:  %ERRORLEVEL%
echo ---------------
echo 标准错误:
%1 %file% 1>nul 2>con
echo 错误代码:  %ERRORLEVEL%
echo =============================================
复制代码

作者: ming_fox 时间: 2010-5-20 13:24

感谢Spring的回复

不好意思，我说的有问题，纠正一下。。

其他的命令用errorlevel可以判定是否正常执行。

但是【del】命令不行。因为即便是出错了errorlevel也是0。

说白了我就是想判定del是成功了还是失败了。

所以我想用判断错误输出（“2”）里面的信息有还是没有来判断是不是
del命令是不是成功了。“2”里有值说明出错，没有，说明没出错。

这只是我个人的想法而已，如果有别的能判别del成功与否的方法请不吝赐教，
谢谢~

作者: hanyeguxing 时间: 2010-5-20 13:59

@echo off
del 12.txt 2>$&&set/p err=<$&&if defined err call echo.错误:%%err%%&&del /q $
复制代码

[ 本帖最后由 hanyeguxing 于 2010-5-20 14:02 编辑 ]

作者: Spring 时间: 2010-5-20 14:18

我给出的三个例子的意思是这样的：
type命令（以及大多数）找不到文件错误代码不是 0 并且在通道 2 里面输出信息，
del 找不到文件错误代码是 0 （跟成功的时候一样）但是会在通道 2 里输出信息，
而 attrib 找不到文件错误代码是 0 （跟成功的时候一样）并且信息也是在通道 1 里面的。

因此只能针对具体的命令来看了。

@echo off
set file=不存在的文件.txt
del %file% 2>temptext.tmp
set /p errmsg=<temptext.tmp
if "%errmsg%" NEQ "" (
  echo.>>error.log
  copy /b error.log + temptext.tmp error.log 1>nul
  echo 错误信息是： “%errmsg%”
) else (
  echo 删除成功。
)
del temptext.tmp
pause
复制代码

作者: ming_fox 时间: 2010-5-20 14:27

原帖由 hanyeguxing 于 2010-5-20 13:59 发表
@echo off
del 12.txt 2>$&&set/p err=

非常感谢回复！

现在增加一个要求，就是还要同时向文件输出信息。这个能做到么。。

P.S.

我是一个初学bat的人，您的代码有点没看太明白，能麻烦您稍微讲解一下么，谢谢~

作者: ming_fox 时间: 2010-5-20 14:32

原帖由 Spring 于 2010-5-20 14:18 发表
我给出的三个例子的意思是这样的：
type命令（以及大多数）找不到文件错误代码不是 0 并且在通道 2 里面输出信息，
del 找不到文件错误代码是 0 （跟成功的时候一样）但是会在通道 2 里输出信息，
而 attrib ...

谢谢回复，您的这段代码我看明白了，给了我不少启发，非常感谢！

作者: hanyeguxing 时间: 2010-5-20 15:25

原帖由 ming_fox 于 2010-5-20 14:27 发表

非常感谢回复！

现在增加一个要求，就是还要同时向文件输出信息。这个能做到么。。

P.S.

我是一个初学bat的人，您的代码有点没看太明白，能麻烦您稍微讲解一下么，谢谢~

del 12.txt 2>$就是把错误输出到文件$。

作者: ming_fox 时间: 2010-5-20 18:24

谢谢大家，这部分大概明白怎么用了。谢谢~

作者: ming_fox 时间: 2010-5-20 18:31

补充一下，请问怎么把这个帖子变成【已解决】？

作者: sgaizxt001 时间: 2010-5-21 00:57

编辑顶楼帖子，在标题前面加上就可以

欢迎光临批处理之家 (http://www.bathome.net/)