批处理之家 - Powered by Discuz! Board

标题: [系统相关] [已解决]批处理怎样动态显示日期时间？ [打印本页]

作者: fenglin124 时间: 2010-4-7 12:21 标题: [已解决]批处理怎样动态显示日期时间？

本帖最后由 pcl_test 于 2016-9-8 17:49 编辑

我用如下代码获取动态时间显示：

for /l %%i in (001 1 255) do (
ping 192.168.0.%%i
echo 现在时间是：%date% %time%
)
复制代码

程序一直循环，但是为什么显示出来的时间都不变呢？%time%每次获取的都是系统时间，应该每次都变的啊。请问这是为什么？

作者: hanyeguxing 时间: 2010-4-7 12:26

开启变量延迟，使用!date! !time!

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 255) do (
ping 192.168.0.%%i
echo 现在时间是：!date! !time!
)
pause
复制代码

或者

@echo off
for /l %%i in (1 1 255) do (
ping 192.168.0.%%i
echo|echo 现在时间是：%%date%% %%time%%
)
pause
复制代码

等等。。。。。。

顺便说一下，不要在for /l 中使用0开头的数字，很容易出错滴，而且for /l直接迭代出来的数列是不会以0开头的。
例如下面的代码就出错了：

for /l %%i in (098 1 100) do echo %%i
复制代码

for /l %%i in (98 09 200) do echo %%i
复制代码

for /l %%i in (98 1 0100) do echo %%i
复制代码

如果确实需要001，002，003......200这样的数列，则：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 200) do (
set i=00%%i
echo 数列!i:~-3!
)
pause
复制代码

[ 本帖最后由 hanyeguxing 于 2010-4-7 12:52 编辑 ]

作者: fenglin124 时间: 2010-4-7 22:02

真是太感谢了，你说的真是太精彩了。

欢迎光临批处理之家 (http://www.bathome.net/)