批处理之家 - Powered by Discuz! Board

标题: [游戏娱乐] 批处理版游动的幽灵 [打印本页]

作者: 523066680 时间: 2010-1-26 21:20 标题: 批处理版游动的幽灵

依然很害怕这样的东东会被排斥啊，我是冒着风险来的
我也不想搞这些的，但是看到有人发了一个"搞笑"代码：
if exist 美女 (a) else (强X) 之后，(很气愤if exist 跟强X 放在一起了……)
另外感觉今年末没做啥东西，该做点了，先写了一个。

不是搞笑的，是恶搞的：

 
@echo off
setlocal enabledelayedexpansion
title  幽灵:我在批处理之家待很久了，你没发现吗？
rem Author: if_exist / 523066680
for /l %%a in (1,1,80) do (set spc= !spc!)
set /a x=1,tmpy=-10
set /a xadd=1,yadd=1,xaddadd=1
:a
  cls
  for /l %%a in (1,1,%y%) do (echo,)
  echo,!spc:~0,%x%!*
  set /a i=0,x+=xadd,tmpy+=yadd,y=tmpy+10,xadd+=xaddadd
  if %xadd:-=% gtr 7 (set /a xaddadd=-xaddadd)
  if %tmpy:-=% gtr 10 (set /a yadd=-yadd)
  ping -n 1 127.0.0.1>nul
goto :a
复制代码

作者: 523066680 时间: 2010-1-26 22:31 标题: 被我做成傲翔的“虫虫”了

@echo off
setlocal enabledelayedexpansion
title  幽灵:我在批处理之家待很久了，你没发现吗？
rem Author: if_exist / 523066680
for /l %%a in (1,1,79) do (set spc= !spc!)
for /l %%a in (1,1,21) do (set line%%a=%spc%)
set /a x=1,tmpy=-10,xb=x+1,a=1
set /a xadd=1,yadd=1,xaddadd=1

:a
 if defined do[%a%] (!do[%a%]!)
 if defined do[%a%] (
    set line%cuty%=!line%cuty%:~0,%cutx%! !line%cuty%:~%cutxb%!
 )
 set line%y%=!line%y%:~0,%x%!*!line%y%:~%xb%!
 cls
 for /l %%a in (1,1,21) do (echo,!line%%a!)
 set /a i=0,x+=xadd,tmpy+=yadd,y=tmpy+10,xadd+=xaddadd,xb=x+1
 set "do[%a%]=set /a cutx=%x%,cuty=%y%,cutxb=%xb%"
 if %a% leq 9 (set /a a+=1) else (set /a a=1)
 if %xadd:-=% gtr 7 (set /a xaddadd=-xaddadd)
 if %tmpy:-=% gtr 10 (set /a yadd=-yadd)
 ping -n 1 127.0.0.1>nul
goto :a
pause
复制代码

作者: PakTC 时间: 2010-1-27 09:47

没人鸟，自己鸟 --paktc

作者: netbenton 时间: 2010-1-27 18:37

有点意思，我顶你！
明年我要做个“雷电”，看看到时雷不雷死一些人

作者: sxw 时间: 2010-3-7 21:33

很好！的帖子！顶起！！！

作者: divilis 时间: 2010-5-9 21:14

太有才了...天才的构思...学习了..

作者: hackerlong 时间: 2010-6-15 13:12

这个构思不错！来个全屏把那个点换成幽灵的图像就更漂亮了貌似难度很大就是！

作者: pgfj18 时间: 2010-7-27 17:51

赞一个，真的很不错~！！~

作者: raymai97 时间: 2011-8-18 09:42

回复 2# 523066680

加料了~ 呵呵~

@echo off
setlocal enabledelayedexpansion
title  幽灵:我在批处理之家待很久了，你没发现吗？
rem Author: if_exist / 523066680
for /l %%a in (1,1,79) do (set spc= !spc!)
for /l %%a in (1,1,21) do (set line%%a=%spc%)
set /a x=1,tmpy=-10,xb=x+1,a=1
set /a xadd=1,yadd=1,xaddadd=1
set /a num=0

:a
if defined do[%a%] (!do[%a%]!)
if defined do[%a%] (
    set line%cuty%=!line%cuty%:~0,%cutx%! !line%cuty%:~%cutxb%!
)
set line%y%=!line%y%:~0,%x%!*!line%y%:~%xb%!
cls
for /l %%a in (1,1,21) do (echo,!line%%a!)
set /a i=0,x+=xadd,tmpy+=yadd,y=tmpy+10,xadd+=xaddadd,xb=x+1
set "do[%a%]=set /a cutx=%x%,cuty=%y%,cutxb=%xb%"
if %a% leq 9 (set /a a+=1) else (set /a a=1)
if %xadd:-=% gtr 7 (set /a xaddadd=-xaddadd)
if %tmpy:-=% gtr 10 (set /a yadd=-yadd)
sleep 50
set /a num+=1
if "%num%"=="1" color 07
if "%num%"=="2" color 09
if "%num%"=="3" color 0a
if "%num%"=="4" color 0b
if "%num%"=="5" color 0c
if "%num%"=="6" color 0d
if "%num%"=="7" color 0e
if "%num%"=="8" color 0f&set num=0
goto a
复制代码

作者: garyng 时间: 2011-8-29 13:25

本帖最后由 garyng 于 2011-8-29 13:28 编辑

第二楼帅！
楼上的也不赖～

欢迎光临批处理之家 (http://www.bathome.net/)