Board logo

标题: DOS系统中获取并分解系统日期时间的批处理 [打印本页]
作者: HAT    时间: 2010-1-12 15:24     标题: DOS系统中获取并分解系统日期时间的批处理

【方案一】

To All:

      今天，根据网上的一段代码[1]修改出一个可以在MSDOS下获取并分解系统时钟信息（日期、时间）的批处理。在MSDOS6.22/MSDOS7.10下运行通过。显然易见的是，程序的冗余度过高，存在大量的重复代码，所以它需要简化，也必然可以简化。本来是要自己修改的，只是最近还在忙其他的题目，无法分心；同时又感觉论坛讨论纯DOS批处理的主题日趋萎缩，所以将它贴上来，大家讨论一下，看有什么好的简化和改进方案，并对其中涉及到的DOS下的词法分析算法进行讨论和优化。当然，网上的此类代码应该还有许多，大家也可以提供更多的资源链接或者自己的想法。

[1] %time%...DOS vs. Win98
http://groups.google.com/group/a ... 04/7c979271a52e36e7
  1. @echo off

  2. if "%1"=="[(" goto parse

  3. echo.|date|find "Current" > _getdate.bat

  4. echo set _dw=%%3> current.bat

  5. echo set _date=%%4>> current.bat

  6. call _getdate.bat

  7. 

  8. echo.|date|find "Enter" > _getdfmt.bat

  9. echo set _dfmt=%%3> enter.bat

  10. call _getdfmt.bat

  11. 

  12. echo.|time|find "Current" > _gettime.bat

  13. echo set _time=%%3> current.bat

  14. call _gettime.bat

  15. 

  16. echo _|choice /c%_dfmt%%_date%_%_time%_ @%0 > _parse.bat

  17. %comspec% /e:2048 /c _parse.bat

  18. goto end

  19. 

  20. :parse

  21. set _dt1=_%2%3

  22. set _dt2=_%5%6

  23. set _dt3=_%8%9

  24. for %%t in ([,Y,Y,-,M,M,-,D,D,]) do shift

  25. 

  26. set _vdt=

  27. :loop1

  28. shift

  29. set _tmp=%_vdt%

  30. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  31. if not "%_vdt%"=="%_tmp%" goto loop1

  32. set %_dt1%=%_vdt%

  33. 

  34. set _vdt=

  35. :loop2

  36. shift

  37. set _tmp=%_vdt%

  38. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  39. if not "%_vdt%"=="%_tmp%" goto loop2

  40. set %_dt2%=%_vdt%

  41. 

  42. set _vdt=

  43. :loop3

  44. shift

  45. set _tmp=%_vdt%

  46. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  47. if not "%_vdt%"=="%_tmp%" goto loop3

  48. set %_dt3%=%_vdt%

  49. 

  50. set _vdt=

  51. :loop4

  52. shift

  53. set _tmp=%_vdt%

  54. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  55. if not "%_vdt%"=="%_tmp%" goto loop4

  56. set _HH=%_vdt%

  57. 

  58. set _vdt=

  59. :loop5

  60. shift

  61. set _tmp=%_vdt%

  62. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  63. if not "%_vdt%"=="%_tmp%" goto loop5

  64. set _MN=%_vdt%

  65. 

  66. set _vdt=

  67. :loop6

  68. shift

  69. set _tmp=%_vdt%

  70. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  71. if not "%_vdt%"=="%_tmp%" goto loop6

  72. set _SS=%_vdt%

  73. 

  74. set _vdt=

  75. :loop7

  76. shift

  77. set _tmp=%_vdt%

  78. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  79. if not "%_vdt%"=="%_tmp%" goto loop7

  80. set _CS=%_vdt%

  81. 

  82. echo DTN:%_YY% %_MM% %_DD% %_HH% %_MN% %_SS% %_CS%

  83. :end
复制代码
【方案二】

我来贴一个,效率没有提高.减少了一些代码
  1. @echo off

  2. if "%1"=="[(" goto parse

  3. echo.|date|find "Current" > _getdate.bat

  4. echo set _dw=%%3> current.bat

  5. echo set _date=%%4>> current.bat

  6. call _getdate.bat

  7. 

  8. echo.|date|find "Enter" > _getdfmt.bat

  9. echo set _dfmt=%%3> enter.bat

  10. call _getdfmt.bat

  11. 

  12. echo.|time|find "Current" > _gettime.bat

  13. echo set _time=%%3> current.bat

  14. call _gettime.bat

  15. 

  16. echo _|choice /c%_dfmt%%_date%_%_time%_ @%0 > _parse.bat

  17. %comspec% /e:2048 /c _parse.bat

  18. goto end

  19. 

  20. :loop

  21. set _vdt=

  22. 

  23. :loop1

  24. shift

  25. set _tmp=%_vdt%

  26. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  27. if not "%_vdt%"=="%_tmp%" goto loop1

  28. set %_set%=%_vdt%

  29. goto %next%

  30. 

  31. 

  32. :parse

  33. set _dt1=_%2%3

  34. set _dt2=_%5%6

  35. set _dt3=_%8%9

  36. set fgf=%4

  37. for %%t in ([,Y,Y,-,M,M,-,D,D,]) do shift

  38. 

  39. :dt1

  40. set _set=%_dt1%

  41. set next=dt2

  42. goto loop

  43. 

  44. :dt2

  45. set _set=%_dt2%

  46. set next=dt3

  47. goto loop

  48. 

  49. :dt3

  50. set _set=%_dt3%

  51. set next=hh

  52. goto loop

  53. 

  54. :hh

  55. set _set=_hh

  56. set next=MN

  57. goto loop

  58. 

  59. :mn

  60. set _set=_mn

  61. set next=ss

  62. goto loop

  63. 

  64. :ss

  65. set _set=_ss

  66. set next=cs

  67. goto loop

  68. 

  69. :cs

  70. set _set=_cs

  71. set next=echo1

  72. goto loop

  73. 

  74. :echo1

  75. echo DTN:%_YY% %_MM% %_DD% %_HH% %_MN% %_SS% %_CS%

  76. :end
复制代码
【方案三】

      今天有闲可以回顾修改这个程序了，解决这个代码的冗余性问题，其实最主要的就是如何实现一系列变量连续性的取值和赋值。本来打算使用for对变量进行循环探测，遇到未赋值的变量即跳出赋值，但是此算法实现起来较为复杂，而且对最初变量的重复探测问题也是代码冗余性的一种表现。现在，看到兄的代码，联想起可以使用数据结构中的链表结构，而它正可通过命令行参数来实现，所以写下了这个修改版本。

      这个版本，同时解决了变量没有被“传出”的问题，也增加了退出前清扫现场的语句。但是这个程序还存在许多缺陷，最致命的是，程序中的词法分析核心 choice 无法正确分析以/作为分隔符的字符串，而诸如国家代码为001(United States)的日期信息恰是以/作为分隔符，而代码中的所有语句都是以不依赖于“国家或区域代码”的通用性为设计目标，而这个缺陷完全架空了其他语句所作的努力。

      另外，它还无法处理时间信息中的12小时制时间。
  1. @echo off

  2. if "%1"==":" goto %2

  3. echo.|date|find "Current" > _getdate.bat

  4. echo set _dw=%%3> current.bat

  5. echo set _date=%%4>> current.bat

  6. call _getdate.bat

  7. 

  8. echo.|date|find "Enter" > _getdfmt.bat

  9. echo set _dfmt=%%3> enter.bat

  10. call _getdfmt.bat

  11. 

  12. echo.|time|find "Current" > _gettime.bat

  13. echo set _time=%%3> current.bat

  14. call _gettime.bat

  15. 

  16. echo _|choice /c"%_dfmt%%_date%_%_time%" @%0 : parse > _parse.bat

  17. %comspec% /e:2048 /c _parse.bat

  18. call _setdt.bat

  19. for %%e in (_date _dfmt _time) do set %%e=

  20. for %%f in (_*.bat enter.bat* current.bat*) do del %%f

  21. echo DTN:%_YY%-%_MM%-%_DD% %_HH%:%_MN%:%_SS%.%_CS%

  22. goto end

  23. 

  24. :parse

  25. set _me=%0

  26. shift

  27. shift

  28. set _tok=%2%3 %5%6 %8%9 HH MN SS CS

  29. for %%t in ([,Y,Y,-,M,M,-,D,D,]) do shift

  30. 

  31. :NextToken

  32. set _vdt=

  33. :GetToken

  34. shift

  35. set _tmp=%_vdt%

  36. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1

  37. if not "%_vdt%"=="%_tmp%" goto GetToken

  38. if "%1"=="" goto end

  39. call %_me% : SetToken %_tok%

  40. goto NextToken

  41. 

  42. :SetToken

  43. set _tok=%4 %5 %6 %7 %8 %9

  44. echo set _%3=%_vdt%>> _setdt.bat

  45. goto end

  46. 

  47. :end
复制代码
【方案四】

      在[1]找到了解决choice对/的兼容性问题，可以支持001的时钟信息了；而prompt的选择不仅简化了代码，同时还使时间保持为24小时制。对帖中代码进行了简单的修改得到以下代码，未进行日期变量名的匹配。

[1] alt.msdos.batch > Documentation of CHOICE streaming parser
http://groups.google.com/group/a ... sg/5e1d0f360f172118
  1. @echo off

  2. if "%1"==":" goto %2 (subroutine handler at %2)

  3. 

  4. echo.exit|%comspec%/e:4096/k prompt set v=$d $t$_:>_tm.bat

  5. call _tm.bat

  6. echo.%v%&|%comspec%/e:4096/c %0 : Parse>_tm.bat

  7. for %%p in (_tm.bat* _tmset.bat*) do call %%p

  8. 

  9. echo.Note that d1 d2 and d3 are in your system date order

  10. echo.DTN:d1=%d1% d2=%d2% d3=%d3% hh=%hh% mm=%mm% ss=%ss% cs=%cs%.

  11. 

  12. for %%e in (v d1 d2 d3 hh mm ss cs) do set %%e=

  13. for %%f in (_tm.bat* _tm.tmp* _tmset.bat*) do del %%f

  14. goto end

  15. 

  16. :Parse (usage: call %0 : Parse +input redirect date/time)

  17. set me=%0

  18. set tok=d1 d2 d3 hh mm ss cs

  19. set d1=

  20. :NextToken

  21. for %%v in (v1 v) do set %%v=

  22. choice /c&0123456789 /n>_tm.tmp

  23. for %%n in (0 1 2 3 4 5 6 7 8 9) do if errorlevel 77%%n set v=%%n

  24. if not errorlevel 2 %me% : SetToken %tok%

  25. find ""<_tm.tmp>nul

  26. if not errorlevel 1 if not "%d1%"=="" call %me% : SetToken %tok%

  27. set d1=%d1%%v%

  28. goto NextToken

  29. 

  30. :SetToken

  31. set tok=%4 %5 %6 %7 %8 %9

  32. echo set %3=%d1%>> _tmset.bat

  33. set d1=

  34. goto end

  35. 

  36. :end (end-of-file)
复制代码
转自：http://www.cn-dos.net/forum/viewthread.php?tid=19756
作者: lxzzr    时间: 2010-1-12 16:48

这个倒是不错，最近在研究启动盘，这个有点用处。HAT辛苦了，^_^



欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2