@echo off
setlocal enabledelayedexpansion

:: 设置要搜索的目录
set "rootdir=C:\MyFile\Test"

:: 遍历目录下的所有.rar和.zip文件
for /r "%rootdir%" %%i in (*.rar, *.zip) do (
    :: 获取压缩包的完整路径
    set "fullpath=%%i"
    :: 获取压缩包所在的目录
    set "dir=%%~dpi"
    :: 获取压缩包的文件名（不含扩展名）
    set "filename=%%~ni"
    
    :: 使用7-Zip解压压缩包到原位置
    7z x "!fullpath!" -o"!dir!" -y
    
    :: 创建一个临时目录用于存放解压出来的文件
    md "!dir!!filename!"
    
    :: 遍历解压出来的文件并重命名
    for /r "!dir!" %%f in (*) do (
        if "%%~dpf"=="!dir!!filename!\" (
            set "newname=!filename!@%%~nxf"
            move "%%f" "!dir!!filename!\!newname!"
        )
    )
    
    :: 删除原压缩包
    del "!fullpath!"
)

echo 处理完成。
pause
复制代码

 @echo off
setlocal enabledelayedexpansion

rem 设置工作目录
set "work=%temp%\%random%%random%%random%%random%"
mkdir "%work%" || goto :eof

rem 递归查找所有压缩包并解压
for /r %%A in (*.zip *.rar) do (
    "%ProgramFiles%\7-Zip\7z.exe" x -o"%%~dpA" "%%A"
    rem 获取压缩包文件名（不带扩展名）
    set "zipname=%%~nA"
    rem 处理解压出的文件
    for %%F in ("%%~dpA*") do (
        rem 重命名解压出的文件
        set "newname=%%~nF"
        ren "%%F" "!zipname!@!newname!"
    )
)

rem 删除临时工作目录
rmdir "%work%" /s /q
复制代码

@echo off

set "_folder_=D:\xyz\"

pushd "%_folder_%"

for /f "usebackq tokens=* delims=" %%a in (` dir /s /b /a-d *.zip *.rar `) do (
    "C:\Program Files\WinRAR\Rar.exe" x "%%a" "%%~dpa\%%~na\"
    rem del "%%a"
    for %%b in ("%%~dpa\%%~na\*") do (
        ren "%%~fb" "%%~na@%%~nxb"
    )
)

popd
复制代码

$folder = "D:\xyz\"

Push-Location -Path $folder

Get-ChildItem -Path "*.rar","*.zip" -Recurse | ForEach-Object {
    Write-Host "--$_.FullName--"
    Push-Location -Path $_.DirectoryName
    Start-Process -Wait -FilePath "C:\Program Files\WinRAR\Rar.exe" -ArgumentList " x `"$($_.FullName)`" `"$($_.BaseName)\`""
    Remove-Item -Path $_.FullName
    $ff = $_.BaseName
    Get-ChildItem -Path $ff | ForEach-Object {
        Rename-Item -Path $_.Fullname -NewName ( $ff + "@" + $_.BaseName + $_.Extension )
    }
    Pop-Location
}
复制代码

@echo off
set "_rar=C:\Program Files\WinRAR\Rar.exe"

cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /a-d *.rar *.zip') do (
	md "%%~dpni"
	"%_rar%" e "%%i" "%%~dpni" && del "%%i"
	for /f "delims=" %%j in ('dir /b "%%~dpni\*"') do (
		ren "%%~dpni\%%j" "%%~ni@%%j"
	)
)
pause
复制代码

@echo off
for /f "delims=" %%F in ('dir /b/s/a-d *.zip *.rar *.7z') do (
	7z.exe x "%%F" -o"%%~dpnF" -y
	for /f "delims=" %%a in (' dir /b/s/a-d "%%~dpnF" ') do ren "%%a" "%%~nF@%%~na%%~xa"
	REM del /q "%%F"
)
pause&exit/b
复制代码

@Echo off
Set rar="C:\Program Files\WinRAR\WinRAR.exe"
For /r %%i in (*.rar) do Echo "%rar%" rn "%%~i" *.*" %%~ni@*.*
For /r %%i in (.) do Echo "%rar%" e "%%~dpi*.rar" "%%~dpi*.*"&&Echo del "%%~dpi*.rar"
pause
复制代码