批处理之家 - Powered by Discuz! Board

标题: [数值计算] [已解决]批处理统计文件数量并生成日志 [打印本页]

作者: a6236130 时间: 2024-5-14 13:16 标题: [已解决]批处理统计文件数量并生成日志

@echo off
set num=0
for /R %%i in (*-*.jpg) do set /A num+=1
echo %num%
pause
复制代码

代码出处 http://www.bathome.net/viewthrea ... 3%BC%C6%CE%C4%BC%FE
以上代码已经实现统计功能（部分），想扩展一下。
1、需要将结果导出保存成list.txt；
2、结果保存格式为AAA文件夹：3个
BBB文件夹：5个以此类推（AAA、BBB文件夹为最底层的文件夹，即文件所在的文件夹）

作者: ShowCode 时间: 2024-5-14 14:31

回复 1# a6236130

扩展1.bat

@echo off
set num=0
for /r %%i in (*-*.jpg) do set /a num+=1
>"list.txt" echo %num%
复制代码

作者: 77七 时间: 2024-5-14 14:34

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
(for /r /d %%d in (*) do (
	for %%i in ("%%d\*-*.jpg") do (
		set /a n+=1,m+=1
	)
	if defined n (
		call echo %%~nxd：%%n%%个
		set n=
	)
))>"list.txt"
echo %m%
pause
复制代码

作者: aloha20200628 时间: 2024-5-14 15:23

本帖最后由 aloha20200628 于 2024-5-14 15:39 编辑

回复 1# a6236130

在当前目录及其各子目录中统计 ‘直属目标文件’ 的数量，如果非零则按行记入结果文件 list.txt 中。

@echo off
(for /f %%n in (' dir /b/a-d "*-*.jpg"^|find /v /c "" ') do if %%n neq 0 (echo,%cd% 文件夹：%%n 个)
 for /d /r %%d in (*) do for /f %%n in (' dir /b/a-d "%%d\*-*.jpg"^|find /v /c "" ') do if %%n neq 0 (echo,%%d 文件夹：%%n 个)
)>"list.txt" 2>nul
pause&exit/b
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)