@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d "*_track*_[chi].srt"') do (
	set "str=%%i"
	setlocal enabledelayedexpansion
	for /f "delims=|" %%a in ("!str:_track=|!") do (
		endlocal
		ren "%%i" "%%a%%~xi"
	)
)
pause
复制代码

@echo off&pause
for %%a in (*.srt) do (
set file=%%a
for /f "delims=" %%b in ('echo^,"%%file:~-17%%"^|findstr /x \"_*track[0-9][0-9]*_\[chi\]\.srt\"') do set _=1
if defined _ (
setlocal enabledelayedexpansion
set _@rp=!file:~-17!
if "!_@rp:~0,1!" == "t" set _@rp=_!_@rp!
for %%c in ("!_@rp!") do rename "!file!" "!file:%%~c=.srt!"
endlocal
set _=
)
)
pause
复制代码

@echo off
for /f "tokens=1* delims=_" %%a in ('dir /b/a-d *_track*.srt') do (ren "%%~a_%%~b" "%%~a.srt")
pause&exit/b
复制代码

楼主须给出重名后的命名规则，如文件名后缀序号... 但如此又被打回原形，说明源文件命名规则的必要性

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d "*_track*_[chi].srt"') do (
	set "str=%%i"
	setlocal enabledelayedexpansion
	set "str=!str:_[chi]=|!"
	for /f "tokens=1-2 delims=|" %%a in ("!str:_track=|!") do (
		endlocal
		set /a n=%%b+1000000
		call set "#%%n%%=%%i|%%a%%~xi|%%b"
	)
)
for /f "tokens=1-3 delims=|" %%a in ('set #') do (
	call :1
)
pause & exit

	:1
	for %%x in (简体 繁体 其它) do (
		if not defined _%%x (
			if "%%x" neq "其它" (
				set _%%x=1
				set f=%%x
			) else (
				set f=%%c
			)
			call md "%%f%%"
			for /f "tokens=1* delims=#=" %%i in ("%%a") do (
				call move "%%j" "%%f%%\%%b"
			)
			exit /b
		)
	)
复制代码

第3-4行之间增加两行

:loop
setlocal

第16-17行之间增加3行

endlocal
if exist "*_track*_[chi].srt" (
	goto :loop
)
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%i in ('dir /b /a-d "*_track??_[chi].srt"') do (
    set a=%%j
    set a=!a:track=!
    if not exist !a! md !a!
    move "%%i_%%j_[chi].srt" "!a!\%%i.srt"
)
pause
复制代码