批处理之家 - Powered by Discuz! Board

@echo off
(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(powershell -Command "Start-Process '%~fdpnx0' -Verb RunAs"&&EXIT)
title 在Win11下给图片右键添加"用画图编辑"
for /f "tokens=4 delims=. " %%a in ('ver') do set num=%%a
if %num% LSS 10 echo 你的系统无需此操作按任意键退出&pause&exit
reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj">nul 2>nul
if %errorlevel% == 1 echo 未安装新版画图按任意键退出&pause&exit
set /a menu=0
echo 在Win11下给图片右键添加"用画图编辑"&echo=&echo 1、添加或修复右键菜单 (由于微软频繁的自动更新程序所以需要经常修复)&echo=&echo 2、删除右键菜单&echo=
set /p menu=请选择功能 (默认 %menu% 不做更改直接退出):
if %menu%==0 exit
if %menu%==1 goto 1
if %menu%==2 goto 2
:1
cls
echo 正在添加或修复右键菜单请稍候...
for /f "tokens=1* delims= " %%a in ('reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj"') do set mspaint=%ProgramFiles%\WindowsApps\%%a\PaintApp\mspaint.exe
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑 /f /reg:64>nul 2>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑" /v "icon" /t REG_SZ /d "%mspaint%" /f /reg:64>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑\Command" /v "" /t REG_SZ /d "\"%mspaint%\" \"%%1\"" /f /reg:64>nul
)
cls
echo 操作完成请按任意键退出&pause&exit
:2
cls
echo 正在删除右键菜单请稍候...
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑 /f /reg:64>nul 2>nul )
cls
echo 删除完成请按任意键退出&pause&exit