批处理之家 - Powered by Discuz! Board

标题: [系统相关] 【已解决】求bat代码读取指定硬盘分区的卷标，并通过echo输出 [打印本页]

作者: kokoxx 时间: 2024-1-27 17:02 标题: 【已解决】求bat代码读取指定硬盘分区的卷标，并通过echo输出

rt，文心一言给出的代码是

for /f "tokens=2 delims==" %%a in ('wmic logicaldisk where deviceid='R:' get name,volumename /value') do (  
    if not "%%a"==" " (  
        echo %%a  
    )  
) 
复制代码

结果运行时反复报错 R: - 别名谓词无效。

我的需求是将wmic logicaldisk where deviceid='r:' get volumename输出的卷标名（单独敲这条命令能正常输出）设置为变量x1，接着echo输出显示

希望大佬能出手指点

作者: hfxiang 时间: 2024-1-27 17:21

回复 1# kokoxx

试一下

wmic logicaldisk where deviceid='c:' get name,volumename /value|findstr =
复制代码

作者: kokoxx 时间: 2024-1-27 17:22

回复 2# hfxiang

怎么将输出结果中的VolumeName设为可调用的变量？

作者: newswan 时间: 2024-1-27 17:23

修改一处

deviceid^=
复制代码

作者: kokoxx 时间: 2024-1-27 17:26

本帖最后由 kokoxx 于 2024-1-27 17:38 编辑

回复 4# newswan

大佬，我改成

@echo off
for /f "tokens=2 delims==" %%a in ('wmic logicaldisk where deviceid^='c:' get volumename /value') do (
if not "%%a"==" " (
      echo %%a
)
)
PAUSE

后可以输出卷标，但是只显示后半部分，比如c盘卷标是ssd1，输出的卷标是  d1

就像这样

R:\>for /F "tokens=2 delims==" %a in ('wmic logicaldisk where deviceid='c:' get volumename /value') do (if not "%a" == " " (echo %a ) )

) ) " (echo SDD1
  D1

R:\>PAUSE
请按任意键继续. . .

---
补充，我发现输出的卷标名前两个字是空白，但是后面的卷标都是正常的

作者: newswan 时间: 2024-1-27 17:47

回复 5# kokoxx

for /f "usebackq tokens=1,2 delims==" %%a in (` wmic logicaldisk where deviceid^='E:' get volumename /value `) do (
	echo --%%a__%%b--
	if not "%%b" == "" (set label=%%b)
)
echo  %label%
复制代码

作者: hfxiang 时间: 2024-1-27 19:13

回复 3# kokoxx

@echo off   
for /f "tokens=*" %%a in ('"wmic logicaldisk where deviceid=^'c:^' get name,volumename /value"^|findstr ^=') do set "%%a"
echo;“%Name%盘”卷标为：%VolumeName%
echo;
PAUSE
复制代码

作者: aloha20200628 时间: 2024-1-27 19:16

本帖最后由 aloha20200628 于 2024-1-27 19:17 编辑

代码及说明如下。
一。用双引号包裹命令表达式 "wmic ..." 以免用转义字符的麻烦
二。用call子过程以便能从循环体尽早退出，不再打理 wmic 输出的多余行

@echo off
(call :getVn x1)
echo,%x1%
exit/b
:getVn
	for /f "skip=1" %%v in (' "wmic logicaldisk where deviceid="r:" get volumename" ') do (set "%1=%%v"&exit/b)
exit/b
复制代码

作者: buyiyang 时间: 2024-1-27 19:29

回复 5# kokoxx

你的"echo %%a"后面多打了两个空格，因为%%a末尾多了一个回车符，所以后面两个空格回到行首，覆盖了%%a前面两个字符。
参见http://www.bathome.net/thread-65737-1-1.html

作者: kokoxx 时间: 2024-1-27 20:37

回复 9# buyiyang

这就是专业！

欢迎光临批处理之家 (http://www.bathome.net/)