批处理之家 - Powered by Discuz! Board

标题: [系统相关] 批处理怎么获取电脑显卡型号？ [打印本页]

作者: jshuanya 时间: 2024-1-24 20:13 标题: 批处理怎么获取电脑显卡型号？

批处理怎么获取电脑显卡型号？用变量输出到文本文件

作者: Batcher 时间: 2024-1-24 20:46

回复 1# jshuanya

试试这几个脚本在你电脑上能否成功
http://bbs.bathome.net/thread-12538-1-1.html

作者: jshuanya 时间: 2024-1-25 13:53

回复 jshuanya

试试这几个脚本在你电脑上能否成功
Batcher 发表于 2024-1-24 20:46

@echo off
for /f "tokens=1,2 delims==" %%a in ('wmic path Win32_VideoController get AdapterRAM^,Name /value^|findstr "AdapterRAM Name"') do echo %%a:%%b
pause>nul

这个代码执行的最快，能否把显卡名称和显存大小都显示在同一行呢？
第二种代码获得的显卡是想要的。第三种比较全，虚拟的都有了，最好是只显示主显卡。

作者: ShowCode 时间: 2024-1-25 14:28

回复 3# jshuanya

@echo off
for /f "tokens=2 delims==" %%a in ('wmic path Win32_VideoController where "AdapterRAM > 1" get AdapterRAM^,Name /value ^| findstr "="') do (
    for /f "delims=" %%i in ("%%a") do (
        set /p =%%~i <nul
    )
)
echo,
pause
复制代码

作者: jshuanya 时间: 2024-1-25 16:40

回复 jshuanya
ShowCode 发表于 2024-1-25 14:28

adapterram单位能否调整成GB?

作者: ShowCode 时间: 2024-1-25 17:00

回复 5# jshuanya

@echo off
for /f "tokens=2 delims==" %%a in ('wmic path Win32_VideoController where "AdapterRAM > 1" get AdapterRAM^,Name /value ^| findstr "="') do (
    for /f "delims=" %%i in ("%%a") do (
        if not defined StrRam (
            set "StrRam=%%~i"
        ) else (
            set "StrName=%%~i"
        )
    )
)
set /a StrRam=%StrRam:~0,-6%/1000
echo %StrRam%GB %StrName%
pause
复制代码

作者: jshuanya 时间: 2024-1-25 19:09

回复 6# ShowCode

很好用，我把where后面改成"CurrentBitsPerPixel>1"，好像这样是正在用的主显卡，不知道是不是这个意思了。

作者: ShowCode 时间: 2024-1-26 09:05

回复 7# jshuanya

是的，条件随便换，多找几个电脑试试，能成功就好。

作者: aloha20200628 时间: 2024-1-26 18:07

本帖最后由 aloha20200628 于 2024-1-26 18:15 编辑

在帖子 http://www.bathome.net/thread-68291-1-1.html 中曾用bat+jscrpit混编版请后者给前者援助浮点运算功能，vbs/jscript裸码不能直接在命令行运行，虽可经过mshta载入，但单行句式较长，且因mshta窗口瞬间开闭会导致屏闪，因而采用了bat+jscript混编方案。用本帖可以练一把powershell/python/awk给批处理脚本援助浮点运算功能的一行流句式，GB精度设为小数点后一位。
powershell版本

@echo off
for /f "skip=1 tokens=1*" %%1 in (' "wmic path win32_videocontroller get adapterram,name" ') do if "%%2" neq "" (
	for /f "delims=" %%v in (' powershell -c "[math]::round((%%1/1gb),1)" ') do (echo,%%vGB %%2)
)
复制代码

python版本

@echo off
for /f "skip=1 tokens=1*" %%1 in (' "wmic path win32_videocontroller get adapterram,name" ') do if "%%2" neq "" (
	for /f "delims=" %%v in (' python -c "print(round(%%1/1073741824,1))" ') do (echo,%%vGB %%2)
)
复制代码

gawk版本

@echo off
for /f "skip=1 tokens=1*" %%1 in (' "wmic path win32_videocontroller get adapterram,name" ') do if "%%2" neq "" (
	for /f "delims=" %%v in (' gawk "BEGIN{printf(""%%.1f"",%%1/1073741824)}" ') do (echo,%%vGB %%2)
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)