批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理如何批量将子文件夹下同名不同类型的文件新建文件夹并放入其中？ [打印本页]

作者: 脑袋大 时间: 2023-11-28 11:03 标题: [已解决]批处理如何批量将子文件夹下同名不同类型的文件新建文件夹并放入其中？

如何实现批量将子文件夹下同名不同类型的文件新建文件夹并放入其中；例如子文件夹内容如下（除名称不一致，文件类型均为这7种）：1828.cpg、1828.dbf、1828.prj、1828.sbx、1828.shp、1828.shx、不动产权籍调查表.pdf（pdf文件均叫此名称）；想要实现：1828.cpg、1828.dbf、1828.prj、1828.sbx、1828.shp、1828.shx→新建文件夹名称为：“shp成果”并放入进去；pdf文件不进行处理。求大佬!!

作者: Batcher 时间: 2023-11-28 11:11

回复 1# 脑袋大

@echo off
set "NewFolder=shp成果"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    echo,%%i
    pushd "%%i"
    md "%NewFolder%" 2>nul
    for /f "delims=" %%j in ('dir /b /a-d ^| findstr /v /i /e ".pdf"') do (
        move "%%j" "%NewFolder%\"
    )
    popd
)
复制代码

作者: ShowCode 时间: 2023-11-28 11:13

回复 1# 脑袋大

@echo off
set "NewFolder=shp成果"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    md "%%i\%NewFolder%" 2>nul
    for /f "delims=" %%j in ('dir /b /a-d "%%i" ^| findstr /v /i /e ".pdf"') do (
        move "%%i\%%j" "%%i\%NewFolder%\"
    )
)
复制代码

作者: 脑袋大 时间: 2023-11-28 11:31

回复 3# ShowCode

感谢！

作者: 脑袋大 时间: 2023-11-28 11:31

回复 2# Batcher

感谢~

欢迎光临批处理之家 (http://www.bathome.net/)