批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求助批处理对比符合条件的文件的修改时间，复制文件到指定目录 [打印本页]

作者: qd2024 时间: 2023-11-17 06:57 标题: 求助批处理对比符合条件的文件的修改时间，复制文件到指定目录

链接：https://pan.baidu.com/s/1NBihbsCUyVsjWHiSyqNU7Q?pwd=vh7e
提取码：vh7e
--来自百度网盘超级会员V9的分享

当前目录【通知条】下有一些以“记录表”开头的文件，文件类型不限，

如，
通知条\记录表01小楷.xlsm
通知条\记录表02笔记.xlsm
通知条\记录表03作文.xlsm
通知条\记录表04生字.xlsm
通知条\记录表05口算.pdf
……（文件数量不限，只有文件名以“记录表”开头，就在考虑范围之中）

\通知条\更新的表格\提取文件.bat

在【通知条】目录下有【更新的表格】文件夹，这里需要的BAT文件放在这里，有命名为【提取文件.bat】

【提取文件.bat】在实现，

① 首次运行【提取文件.bat】时，记录 \通知条\记录表*.* 文件的修改时间；
② 之后每次运行【提取文件.bat】时，先删除 \通知条\更新的表格\记录表*.* ;再将文本中记录的内容和\通知条\记录表*.* 同名文件进行对比，如果有文件系统修改时间有改变，则将相关文件复制到 \通知条\更新的表格\ 文件夹下。
③ 如通知条\记录表06速算.pdf 有新增加的符合规则的文件时，则将文件文件名、修改时间追加记录到【提取文件.bat】中，同时复制文件到\通知条\更新的表格\中，下次运行【提取文件.bat】时，此文件同其他文件一并规则处理。

感谢。

链接：https://pan.baidu.com/s/1NBihbsCUyVsjWHiSyqNU7Q?pwd=vh7e
提取码：vh7e
--来自百度网盘超级会员V9的分享

作者: 77七 时间: 2023-11-17 13:10

@echo off
cd /d "%~dp0"
cd ..
if not exist "%~dp0list.txt" (
	call :1
) else (
	del /q "%~dp0记录表*" 2>nul
	for /f "useback delims=" %%a in ("%~dp0list.txt") do (
		set %%a
	)
	for %%a in (记录表*.*) do (
		if not defined _"%%a%%~ta" (
			copy "%%a" "%~dp0"
		)
	)
	call :1
)
pause & exit

	:1
	(for %%a in (记录表*.*) do (
		echo _"%%a%%~ta"=1
	))>"%~dp0list.txt"
	exit /b
复制代码

作者: ShowCode 时间: 2023-11-17 13:20

回复 1# qd2024

通知条\更新的表格\提取文件.bat

@echo off
cd /d "%~dp0"
xcopy /y /d ..\记录表*.* .
复制代码

有可能你想复杂了，xcopy命令的/d选项可以自己判断文件是否需要复制（是否有更新），不需要像你这样手工记录时间再对比时间。

作者: qd2024 时间: 2023-11-17 13:35

回复 2# 77七

谢谢

作者: qd2024 时间: 2023-11-17 13:36

回复 3# ShowCode

有生成方案吗

作者: ShowCode 时间: 2023-11-17 13:38

回复 5# qd2024

请举例说明“生成方案”是什么？

作者: qd2024 时间: 2023-11-17 15:19

回复 6# ShowCode

用 77七的方法已经得到想要的结果感谢

欢迎光临批处理之家 (http://www.bathome.net/)