@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.nc') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        echo,%%j
        set "str=%%j"
        if "!str:~,1!"=="T" (
            set "str=!str:~1!"
            set /a "n=str"
            if !n! equ !str! (
                echo,G43H!n!
                echo,M03 S18000
                echo,M141
            )
        )
    ))>temp
    move "temp" "%%i"
)
pause
复制代码

@echo off
for /f "useback delims=" %%i in (`dir /b /a-d *.nc`) do (
	setlocal
	for /f "useback tokens=1* delims=:" %%a in (`findstr /rnic:"^T[0-9][0-9]*$" "%%i"`) do (
		set str=%%b
		call set _"%%b"=%%str:~1%%
	)
	(for /f "useback tokens=1* delims=:" %%a in (`findstr /n .* "%%i"`) do (
		echo=%%b
		if defined _"%%b" (
			call echo G43H%%_"%%b"%%
			echo M03 S18000
			echo M141
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion

for /f "tokens=*" %%i in ('dir /b /a-d *.nc') do call :addline "%%i"
exit

:addline
set F=%1
FOR /f "tokens=1* delims=:" %%A IN ('FINDstr /N "T.*" %F%') DO echo %%A>>Tlist.txt
set lineFlag=0
for /f "tokens=*" %%i in ('type %F%') do (
	set line=%%i
	set "n=!line:~1!"
	set /a lineFlag+=1
	for /f "delims=" %%a in (Tlist.txt) do (
		set T=%%a
		if !lineFlag! equ !T! (
			echo;!line!
			echo;G43H!n!
			echo;M03 S18000
			echo;M141
		)>>temp.txt
	)
	echo;!line!>>temp.txt
)
 
ren %F% %F%.%date:/=-%.bak
ren temp.txt %F%
del /q Tlist.txt
goto :eof
复制代码