@echo off
rem 批处理保存为ansi编码格式。
for /r "C:\指定目录" %%i in (*.pdf *.doc *.xls) do set _"%%i"=1
for %%a in (c d e) do call :1 "%%a:\"
pause
exit

        :1
        for /r "%~1" %%b in (*.pdf *.doc *.xls) do (
                if not defined _"%%b" (
                        rem 效果满意，则删除echo再执行
                        echo del "%%b"
                )
        )
        exit /b
复制代码

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder=C:\Users\Administrator\Desktop\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder%"') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

@echo off
rem 批处理保存为ansi编码格式。请谨慎使用！
set "folder=C:\指定目录"
for %%a in (pdf doc xls) do attrib +H "%folder%\*.%%a" /s
echo 确认待排除文件隐藏成功，则继续执行
pause
for %%a in (c d e) do (
        pushd "%%a:\"
        del /s /q *.pdf;*.doc;*.xls
        popd
)
for %%a in (pdf doc xls) do attrib -H "%folder%\*.%%a" /s
pause
复制代码

@echo off
rem 指定排除目录
set "exfolder=C:\Windows\"

set "exfolder=%exfolder:\=\\%"
wmic datafile where "not name like '%exfolder%%%' and (Extension='pdf' or Extension='doc' or Extension='xls')" get name /value | findstr .
pause
pause>nul&echo,确认删除？
pause>nul&echo,确认删除？
wmic datafile where "not name like '%exfolder%%%' and (Extension='pdf' or Extension='doc' or Extension='xls')" call delete
复制代码

@echo off
rem 批处理保存为ansi编码格式。请谨慎使用！
set "folder1=C:\指定目录1"
set "folder2=C:\指定目录2"
for %%a in (pdf doc xls) do (
	attrib +H "%folder1%\*.%%a" /s
	attrib +H "%folder2%\*.%%a" /s
)
echo 确认待排除文件隐藏成功，则继续执行
pause
for %%a in (c d e) do (
        pushd "%%a:\"
        del /s /q *.pdf;*.doc;*.xls
        popd
)
for %%a in (pdf doc xls) do (
	attrib -H "%folder1%\*.%%a" /s
	attrib -H "%folder2%\*.%%a" /s
)
pause
复制代码

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

@echo off
rem 批处理保存为ansi编码格式。路径末尾以 \ 结束
call :1 "c:\指定目录1\"
call :1 "c:\指定目录2\"
call :1 "c:\指定目录3\"

for %%a in (c d e) do call :2 "%%a:\"
pause & exit

	:1
	set _"%~1"=1
	rem 如果不需要排除子目录删除下一行
	for /r "%~1" /d %%d in (*) do set _"%%d\"=1
	exit /b

	:2
	for /r "%~1" %%i in (*.pdf *.doc *.xls) do (
		if not defined _"%%~dpi" (
			echo del "%%i"
		)
	)
	exit /b
复制代码

@echo off
set "ExFolder1=指定目录1"（完整路径）
set "ExFolder2=指定目录2"（完整路径）
...

ren "%ExFolder1%\*.*" "*.*.1"
ren "%ExFolder1%\*.*" "*.*.1"
...

for %%i in (C D F) do (
if exist %%i:\
for %%j in (pdf doc xls) do (
del /s %%i:\*.%%j
)
)

ren "%ExFolder1%\*.*" "*."
ren "%ExFolder2%\*.*" "*."
...
复制代码

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
REM 导出的文件列表
set "OutFile=%~dp0备份.csv"
REM 设置新的临时后缀名
set "NewExt=ttttt"
>"%OutFile%" echo OldName,NewName
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            echo 正在查找 %%b
            >>"%OutFile%" echo "%%b","%%b.%NewExt%"
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
            echo ren "%%b","%%~nxb.%NewExt%"
        )
        popd
    )
)
pause
复制代码

@echo off
set "InFile=%~dp0备份.csv"
for /f skip^=1^ tokens^=3^ delims^=^" %%a in ('type "%InFile%"') do (
    REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
    echo ren "%%a" "%%~na"
)
pause
复制代码

@echo off
rem 批处理保存为ansi编码格式。路径末尾以 \ 结束
call :1 "c:\指定目录1\"
call :1 "c:\指定目录2\"
call :1 "c:\指定目录3\"

for %%a in (c d e) do call :2 "%%a:\"
pause & exit

	:1
	set _"%~1"=1
	rem 如果不需要排除子目录删除下一行
	for /r "%~1" /d %%d in (*) do set _"%%d\"=1
	exit /b

	:2
	for /r "%~1" %%i in (*.pdf *.doc *.xls) do (
		if not defined _"%%~dpi" (
			>>"重命名.bat" echo ren "%%i" "%%~ni.tttt"
			>>"恢复.bat" echo ren "%%~dpni.tttt" "%%~nxi"
		)
	)
	exit /b
复制代码