批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】批处理如何将多个文件夹按数量放在不同的文件夹里？ [打印本页]

作者: 先起个名 时间: 2023-8-8 17:09 标题: 【已解决】批处理如何将多个文件夹按数量放在不同的文件夹里？

本帖最后由先起个名于 2023-8-9 15:12 编辑

求助大佬

比如我有105个文件夹，按照每20个一组，放在名字为1,2,3,4,5的文件夹里，剩下的5个就剩在原文件夹里即可

作者: qixiaobin0715 时间: 2023-8-8 20:16

本帖最后由 qixiaobin0715 于 2023-8-8 20:22 编辑

请不要预先创建文件夹1/2/3...，代码会在适当时候自动创建，否则会出现问题。

@echo off
set k=20
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /ad') do (
    set /a n+=1
    set _!n!=%%i
    if !n! equ %k% (
        set /a m+=1
        md !m!
        for /l %%j in (1,1,%k%) do move "!_%%j!" "!m!\"
        set n=
    )
)
复制代码

作者: 先起个名 时间: 2023-8-9 15:09

跪谢，跪谢，跪谢

作者: Batcher 时间: 2023-8-9 15:48

回复 1# 先起个名

@echo off
set "MaxNum=20"
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "FolderCount=0"
set "NewFolder=1"
for /f "delims=" %%i in ('dir /b /ad') do (
    if not exist "!NewFolder!" (
        md "!NewFolder!"
    )
    set /a FolderCount+=1
    move /y "%%i" "!NewFolder!"
    if !FolderCount! equ !MaxNum! (
        set /a NewFolder+=1
        set "FolderCount=0"
    )
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)