<# :
cls&echo off&cd /d "%~dp0"&set "current=%cd%"
path %SYSTEMROOT%\System32\WindowsPowerShell\v1.0;%path%
powershell -NoProfile -ExecutionPolicy bypass "Get-Content -literal \"%~f0\"|Out-String|Invoke-Expression"
pause
exit
#>
$inifile="D:\Program Files (x86)\xxx.ini";
if(-not (test-path -literal $inifile)){write-host ('"'+$inifile+'" path error or not exist');exit;}

$codes=@'
using System;
using System.Runtime.InteropServices;
public static class EditINI
{
    [DllImport("kernel32")]
    public static extern long WritePrivateProfileString(string section, string key, string val, string filePath);
}
'@;
Add-Type -TypeDefinition $codes;

[EditINI]::WritePrivateProfileString('SERVER_DATA_2', 'SERVER_USER', '112233', $inifile);
[EditINI]::WritePrivateProfileString('SERVER_DATA_2', 'SERVER_PASSWORD', '88888', $inifile);
复制代码

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "FileOld=1.ini"
set "FileNew=2.ini"
set "BeginChange="
(for /f "tokens=1,2 delims==" %%a in ('type "%FileOld%"') do (
    if "%%b" equ "" (
        set "ThisRow=%%a"
    ) else (
        set "ThisRow=%%a=%%b"
    )
    if "%%a" equ "[SERVER_DATA_2]" (
        echo,!ThisRow!
        set "BeginChange=true"
    ) else if "!BeginChange!" equ "true" (
        if "%%a" equ "SERVER_USER" (
            echo,%%a=bbs.bathome.net
            set "ChangeU=true"
        ) else if "%%a" equ "SERVER_PASSWORD" (
            echo,%%a=www.bathome.net
            set "ChangeP=true"
        ) else (
            echo,!ThisRow!
        )
        if "!ChangeU!" equ "true" (
            if "!ChangeP!" equ "true" (
                set "BeginChange=false"
            )
        )
    ) else (
        echo,!ThisRow!
    )
))>"%FileNew%"
复制代码

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "FileOld=1.ini"
set "FileNew=2.ini"
set "BeginChange="
(for /f "tokens=1,2 delims=:" %%i in ('findstr /n .* "%FileOld%"') do (
    if "%%j" equ "" (
        echo,
    ) else (
        for /f "tokens=1,2 delims==" %%a in ("%%j") do (
            if "%%b" equ "" (
                set "ThisRow=%%a"
            ) else (
                set "ThisRow=%%a=%%b"
            )
            if "%%a" equ "[SERVER_DATA_2]" (
                echo,!ThisRow!
                set "BeginChange=true"
            ) else if "!BeginChange!" equ "true" (
                if "%%a" equ "SERVER_USER" (
                    echo,%%a=bbs.bathome.net
                    set "ChangeU=true"
                ) else if "%%a" equ "SERVER_PASSWORD" (
                    echo,%%a=www.bathome.net
                    set "ChangeP=true"
                ) else (
                    echo,!ThisRow!
                )
                if "!ChangeU!" equ "true" (
                    if "!ChangeP!" equ "true" (
                        set "BeginChange=false"
                    )
                )
            ) else (
                echo,!ThisRow!
            )
        )
    )
))>"%FileNew%"
复制代码

move /y "%FileNew%" "%FileOld%"
复制代码

inifile a.ini [SERVER_DATA_2] SERVER_USER=123456
inifile a.ini [SERVER_DATA_2] SERVER_PASSWORD=888888
复制代码

sed -r -i "/^\[SERVER_DATA_2\]$/,/^\[.*$/{s/^SERVER_USER=.*$/SERVER_USER=ABCDEFG/;s/^SERVER_PASSWORD=.*$/SERVER_PASSWORD=abcdefg/}" "D:\Program Files (x86)\1.txt"
复制代码

set "LocalDir=D:\Program Files(x86)\111.ini"
set "NewDir=D:\Program Files(x86)\111.ini.txt"

setlocal enabledelayedexpansion

if exist "%LocalDir%" (

		for /f "delims=" %%i in  ('findstr /N .* %LocalDir%') do (		

			set "str=%%i"
			set "str=!str:*:=!"

			if "!str!" equ "SERVER_USER=456" ( 

				echo SERVER_USER=XXXXXX

			) else if "!str!" equ "SERVER_PASSWORD=456"(

				echo SERVER_PASSWORD=XXXXXX
			
			) else (
			
				echo.!str!
			)
		 )>>%NewDir%
  )

endlocal

echo F|xcopy  /c /r /y  %NewDir%  %LocalDir%

del /q %NewDir%

pause
复制代码

@echo off
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "1.ini"') do (
        if defined m (
                (for /f "tokens=1 delims==" %%c in ("%%b") do (
                        if "%%c" equ "SERVER_USER" (
                                echo %%c=456456456
                        ) else if "%%c" equ "SERVER_PASSWORD" (
                                echo %%c=456456456
                        ) else echo=%%b
                        if defined SERVER_USER if defined SERVER_PASSWORD (
                                set m=
                        )
                )) || echo=%%b
        ) else (
                if "%%b" equ "[SERVER_DATA_2]" (
                        set m=1
                )
                echo=%%b
        )
))>"2.ini"
move /y "2.ini" "1.ini"
pause
复制代码

@echo off
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "1.ini"') do (
	if defined m (
		(for /f "tokens=1 delims==" %%c in ("%%b") do (
			if "%%c" equ "SERVER_USER" (
				echo %%c=456456456
			) else if "%%c" equ "SERVER_PASSWORD" (
				echo %%c=456456456
				set m=
			) else echo=%%b
		)) || echo=%%b
	) else (
		if "%%b" equ "[SERVER_DATA_2]" (
			set m=1
		)
		echo=%%b
	)
))>"2.ini"
move /y "2.ini" "1.ini"
pause
复制代码

      if "%%a" equ "SERVER_USER" (
            echo,%%a=bbs.bathome.net
            set "ChangeU=true"
        ) else if "%%a" equ "SERVER_PASSWORD" (
            echo,%%a=www.bathome.net
            set "ChangeP=true"
        ) else (
            echo,!ThisRow!
        )
复制代码

@echo off
cd /d "D:\Program Files (x86)"
set "newUser=abc" &set "newPw=999"
setlocal enabledelayedexpansion
(for /f "delims=" %%s in (src.ini) do if not defined got (
		(echo,%%s)
		if /i "%%s"=="[SERVER_DATA_2]" (set "got=1")
	) else (
		if !got! equ 1 (set "newV=%newUser%") else (set "newV=%newPw%")
		for /f "tokens=1 delims==" %%1 in ("%%s") do (echo,%%1=!newV!)
		if !got! equ 2 (set "got=") else (set/a got+=1)
	)
)>new.ini
:: move /y new.ini src.ini REM 若保留源文件即注释此行
endlocal &exit/b
复制代码

@echo off
rem cd /d "%~dp0"
setlocal EnableDelayedExpansion

rem set "INPUT_FILE=file.txt"
set "INPUT_FILE=D:\Program Files (x86)\input.ini"
set "OUTPUT_FILE=D:\Program Files (x86)\output.ini"
set "DATE_TIME=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%"
set "BAK_FILE=D:\Program Files (x86)\common_bak%DATE_TIME%.ini"
copy "%INPUT_FILE%" "%BAK_FILE%"

rem 删除上次的输出文件
if exist "%OUTPUT_FILE%" del "%OUTPUT_FILE%"

for /f "usebackq tokens=1,2 delims=:" %%o in (`findstr /n .* "%INPUT_FILE%"`) do (
  rem echo %%p
  if "%%p" equ "" (
    rem 输出空行
    echo. >>"%OUTPUT_FILE%"
  ) else (
      for /f "tokens=1* delims==" %%c in ("%%p") do (
    	if /i "%%c"=="[SERVER_DATA_3]" (
    	  set "Mod_flag=true"
    	  rem echo ----------------!Mod_flag!------------
    	)
    	rem 包含字符串“#""[”则仅输出%%c，否则进行修改
    	echo %%c| findstr "# [" >nul && (
          set line=%%c
        ) || (
		  rem 修改键值对
		  if /i "!Mod_flag!" equ "true" (		  
    	    if /i "%%c" == "SERVER_USER" ( 
    	      rem echo %%d
    	      set line=%%c=cccccc
			  set "ChangeU=true"
    	    ) else if /i "%%c" == "SERVER_PASSWORD" ( 
    	       rem echo %%d
    	      set line=%%c=cccccc
			  set "ChangeP=true"
    	    ) else (
    	      set line=%%c=%%d
    	    )
			rem 全部修改完毕后，重置Mod_flag标识
			if /i "!ChangeU!" equ "true" (
			  if /i "!ChangeP!" equ "true" (
			    set "Mod_flag=false"
			  )
			)			
		  ) else (
    	    set line=%%c=%%d
    	  )
        )
        REM 在此处修改line变量的值
        echo !line!>>"%OUTPUT_FILE%"
      )
    )
)

move /y "%OUTPUT_FILE%" "%INPUT_FILE%"
endlocal
echo  "文件处理完成"
pause
复制代码