批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理echo 有特殊符号，该如何表达？ [打印本页]

作者: thp2008 时间: 2023-7-27 10:06 标题: [已解决]批处理echo 有特殊符号，该如何表达？

本帖最后由 thp2008 于 2023-7-27 10:31 编辑

下面echo后面，应该如何表达,请帮你修改一下，谢谢！
总是提示，此处不该有<之类

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type "URL.txt"') do (
	echo <li><a href="%%a" class="link-3" target="_blank" rel="nofollow">%%a</a></li>  >>html.txt
	)
endlocal
复制代码

作者: qixiaobin0715 时间: 2023-7-27 10:22

本帖最后由 qixiaobin0715 于 2023-7-27 10:25 编辑

输出“^ > >> & && | || < <<”
echo ^^
echo ^>
echo ^>^>
echo ^&
echo ^&^&
echo ^|
echo ^|^|
echo ^<
echo ^<^<
复制代码

作者: qixiaobin0715 时间: 2023-7-27 10:29

echo ^<li^>^<a href="%%a" class="link-3" target="_blank" rel="nofollow"^>%%a^</a^>^</li^>
复制代码

作者: Batcher 时间: 2023-7-27 10:32

回复 1# thp2008

@echo off
(for /f "delims=" %%a in ('type "URL.txt"') do (
	echo ^<li^>^<a href="%%a" class="link-3" target="_blank" rel="nofollow"^>%%a^</a^>^</li^>
))>>html.txt
复制代码

参考：
https://mp.weixin.qq.com/s/McvY4CiR-SYGaCha7lmjIw
https://mp.weixin.qq.com/s/VZk0TmYUpFdCoWK9ZpgL0Q

作者: 77七 时间: 2023-7-27 10:52

@echo off
set "str1=<li><a href="str2" class="link-3" target="_blank" rel="nofollow">str2</a></li>"
setlocal enabledelayedexpansion
(for /f "delims=" %%a in ('type "URL.txt"') do (
	echo=!str1:str2=%%a!
))>html.txt
endlocal
pause
复制代码

作者: aloha20200628 时间: 2023-7-27 12:04

用 set/p="..."<nul 特殊功能》输出字符串可用双引号包裹但仅输出其内数据，如此可保全双引号之内的特殊字符不被转义。

@echo off
(for /f "delims=" %%a in (URL.txt) do (
   set/p="<li><a href="%%a" class="link-3" target="_blank" rel="nofollow">%%a</a></li>"<nul
   echo,
))>html.txt
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)