批处理之家 - Powered by Discuz! Board

标题: [文本处理] [分享]批处理删除第一个位置参数获取其余参数 [打印本页]

作者: Batcher 时间: 2023-7-24 20:28 标题: [分享]批处理删除第一个位置参数获取其余参数

【问题描述】

已知使用以下方式调用 test.bat 脚本：
test.bat "C:\Program Files\WinRAR" "File 1.txt" "File 2.txt" "File 3.txt"
这个时候，%*的值是：
"C:\Program Files\WinRAR" "File 1.txt" "File 2.txt" "File 3.txt"

怎样去掉第一个位置参数，并赋值给变量，得到：
FileList="File 1.txt" "File 2.txt" "File 3.txt"

作者: Batcher 时间: 2023-7-24 20:29

【解决方案】

test-1.bat

@echo off
setlocal enabledelayedexpansion
set "SkipFlag="
set "FileList="
for %%i in (%*) do (
    if not defined SkipFlag (
        set "SkipFlag=true"
    ) else if not defined FileList (
        set "FileList=%%i"
    ) else (
        set "FileList=!FileList! %%i"
    )
)
echo,%FileList%
复制代码

作者: Batcher 时间: 2023-7-24 20:29

test-2.bat

@echo off
set "ArgsAll=%*"
call set "FileList=%%ArgsAll:*%1 =%%"
echo,%FileList%
复制代码

作者: Batcher 时间: 2023-7-24 20:39

test-3.bat

@echo off
set "FileList="
:Loop
shift
if not defined FileList (
    set "FileList=%1"
) else (
    set "FileList=%FileList% %1"
)
if "%~2" neq "" (
    goto :Loop
)
echo,%FileList%
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)