批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]自动解压缩的批处理中特殊字符的处理问题 [打印本页]

作者: thp2008 时间: 2023-6-22 11:23 标题: [已解决]自动解压缩的批处理中特殊字符的处理问题

我有个自动解压的批处理。正常情况使用没有问题。
但是现在很多设置压缩密码的时候，喜欢加入一些特殊字符，这个时候，批处理就会出错。
像这种情况，有没有什么高手可以解决这个问题。

@echo off
echo.
set /p pass=请输入当前目录下压缩文件的解压密码：
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p%pass% -o- "%%i" "%%~dpi"
复制代码

比如密码中存在：^ ! & 类似这种，批处理，就识别密码不正确了。

感谢！

作者: 77七 时间: 2023-6-22 11:30

参考下这个帖子
http://www.bathome.net/redirect. ... 3453&pid=258303

作者: thp2008 时间: 2023-6-22 12:27

回复 2# 77七

谢谢提供消息，我看后，研究了一下。自已写的好像还是不对，应该是怎么个写法。

@echo off
echo.
set /p pass=请输入当前目录下压缩文件的解压密码：
echo %pass%>PtempS.txt
winclip.exe -u -c PtempS.txt
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
winclip.exe -p | for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p -o- "%%i" "%%~dpi"
del PtempS.txt
pause
复制代码

我一输入含有特殊字符的密码，就自动退出了。

我已下载了第三方工具winclip.exe在放同一目录。

作者: 77七 时间: 2023-6-22 12:54

回复 3# thp2008

不知道你怎么实际使用，使用set /p 输入密码吗？去掉-p 这样直接在弹框中输入密码可以吗？

@echo off
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -o- "%%i" "%%~dpi"
pause
复制代码

作者: thp2008 时间: 2023-6-22 13:10

回复 4# 77七

哦，可以这样，让他直接弹出密码输入框，我发现输入一个错误的密码或者不输，也会弹出。这样，什么密码就都可以输了。这也是个办法。

解压文件少，是没多大影响。

但是，就是文件解压文件较多的话，就比较麻烦一点，每一个文件，都要输。不能一个密码，应用到所有解压文件，还有对多重解压也是，要多次输入密码

如果用批处理解决的话，又要解决特殊字符，又要解决空格，全角，的问题。的确是比较麻烦。

不知道，还有没有，什么，完美的解决办法，或借助Powershell,VBS,第三方工具也行。

作者: 77七 时间: 2023-6-22 13:25

回复 5# thp2008

如果你需要解压的文件的密码都是相同的，可以用那个帖子的方法
我使用那个作者提供的密码

1"@>::”#<$%"*%@“=?(*::"=*}{3"5*!！?%&|=6$”"4……-^_a=*a`~*()-_=+aa
复制代码

这个密码echo 后密码中含有的变量会变成空值
所以不妨直接复制密码，然后点击脚本，解压期间不要操作剪贴板

@echo off
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') (
        winclip -p|"C:\Program Files\7-Zip\7z.exe" x "%%i" -o"%%~dpi" 1>nul
)
pause
复制代码

作者: thp2008 时间: 2023-6-22 13:37

本帖最后由 thp2008 于 2023-6-22 13:58 编辑

我找到去年，我问过的一个类似的问题，用了flashercs帮我提供的一种方法，我改了一下，发现可以使用。
就是先把密码保存在一个文本文件中。

对于较多的解压文件，就可以用这种方法，因为不需要第三方工具，更方便。如果文件较少，就直接在弹出的对话框中粘贴就好了。

提示：本方法可以处理含有特殊字符的字符串，在批处理中作为变量，前提是把密码存放在tsPass.txt中。密码如果有中文或全角，就要保存了ANSI格式。

@echo off
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
echo.
for /f "delims=" %%a in (tsPass.txt) do (
    set pass=%%a
    setlocal EnableDelayedExpansion
    set pass=!pass:"=""!
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
    endlocal
)
exit
复制代码

如果可以不手工创建文件就完美了。

作者: thp2008 时间: 2023-6-22 13:44

回复 thp2008

如果你需要解压的文件的密码都是相同的，可以用那个帖子的方法
我使用那个作者提供 ...
77七发表于 2023-6-22 13:25

我试了一下，这种办法，好像对WINRAR无效，不知道是不是我写错了。

我先把密码，复制到剪贴板，再运行下面的批处理。不能自动粘贴，还是弹出对话框。

@echo off
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do (winclip -p |  "%rar%" x -y -o- "%%i" "%%~dpi")
pause
复制代码

作者: 77七 时间: 2023-6-22 14:06

回复 8# thp2008

7楼的方法挺好的。winrar可能不支持吧。

作者: buyiyang 时间: 2023-6-22 14:26

本帖最后由 buyiyang 于 2023-6-22 15:31 编辑

就是预处理的问题，直接给%pass%加上双引号就行了。或者开变量延迟setlocal enabledelayedexpansion，把%pass%改成!pass!

setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
复制代码

作者: thp2008 时间: 2023-6-22 14:49

本帖最后由 thp2008 于 2023-6-22 14:51 编辑

能不能在7楼的基础上，加上一个粘贴密码后，自动创建tsPass.txt的文件呀，我试着用批处理创建，不行，只要有全角符号，或者^等特殊字符就不行了。不知道，用VBS或者其它什么方式，可不可以，做个输入框，加在批处理前面，这样就自动创建tsPass.txt。比较方便一点。学习使用脚本，本身就是为了方便。

作者: 77七 时间: 2023-6-22 15:37

本帖最后由 77七于 2023-6-22 16:44 编辑

回复 11# thp2008

@echo off
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%a in ('winclip -p') do (
        set "pass=%%a"
        setlocal EnableDelayedExpansion
        set "pass=!pass:"=""!"
        for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
        endlocal
)
exit
复制代码

特殊字符使用set /p ，我试了直接闪退，在7楼的代码上修改，复制后直接点脚本就行了，不用粘贴
“特殊字符使用set /p ，我试了直接闪退”，说法有误！

作者: thp2008 时间: 2023-6-22 15:39

回复 thp2008

特殊字符使用set /p ，我试了直接闪退，在7楼的代码上修改，复制后直接点脚本就行 ...
77七发表于 2023-6-22 15:37

这个方法不错，我测试了，可以。

作者: buyiyang 时间: 2023-6-22 16:15

回复 12# 77七

哪个特殊字符会让set /p闪退？

作者: 77七 时间: 2023-6-22 16:24

本帖最后由 77七于 2023-6-22 17:27 编辑

回复 14# buyiyang

大佬，您试试这个

1"@>::”#<$%"*%@“=?(*::"=*}{3"5*!！?%&|=6$”"4……-^_a=*a`~*()-_=+aa
复制代码

这个就是2楼那个帖子作者试验的密码
我又试了一下，开启延迟变量后，再使用set /p 就不会闪退了
多次测试，只有开启延迟变量后，使用叹号才能正确echo 这个字符串，

@echo off
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%a in ('winclip -p') do (
        set "pass=%%a"
        setlocal EnableDelayedExpansion
        set "pass=!pass:"=""!"
        for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
        endlocal
)
pause

for /f "delims=" %%a in ("1") do (
        set /p pass=
        setlocal EnableDelayedExpansion
        set "pass=!pass:"=""!"
        for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
        endlocal
)
pause
复制代码

使用上面的密码压缩的文件，再同一个批处理文件中，使用上面的代码第一段winclip -p 获取密码解压成功，使用第二段 set /p 输入密码，提示密码错误。

作者: thp2008 时间: 2023-6-22 19:40

本帖最后由 thp2008 于 2023-6-22 20:06 编辑

使用了几个小时，感觉12楼winclip -p的这种方式，不稳定，刚开始用的时候，用的都可以，后面再用来解压的时候，就不行了。后来，我又把winclip -p改成tsPass.txt，就可以了。问题还是这个winclip -p不稳定，是不是系统对这种剪贴板的访问次数，还是什么多了，就会自动干预什么，搞不清楚原因，重启电脑也不行，同一个批处理，又没有变动过。即使是解压之前解压过的，也会报错，但更奇怪的是，我手工粘贴密码到弹出的对话框中也报错，总是说密码错误，批处理就退出了，但是后台却把文件解压出来了，我解压的文件都很大，没有看到任何解压过程，也报密码错误，却把文件都解压了。而且要是我停一段时间不用，过会再用，有时，又可以用了。非常奇怪。但是用文本文件的方式，就很稳定，就是每个文件夹，都要创建一个tsPass.txt,麻烦点。

后来，我想了变通的办法，
这样创建出来的文本文件就是ANSI编码的了。直接复制进去，替换掉第一行，保存，关掉，就可以了。

@echo off
echo 将密码复制到这里替换这行字>tsPass.txt
notepad tsPass.txt

set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
for /f "delims=" %%a in (tsPass.txt) do (
        set "pass=%%a"
        setlocal EnableDelayedExpansion
        set "pass=!pass:"=""!"
        for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
        endlocal
)
del tsPass.txt
exit
复制代码

作者: idwma 时间: 2023-6-22 21:14

试试这个

#@&cls&powershell "type '%~0'|out-string|iex"&pause&exit
$rar=$env:ProgramFiles+'\WinRAR\RAR.exe'
$OutputEncoding=[System.Text.Encoding]::GetEncoding(936)
$a=read-host '请输入当前目录下压缩文件的解压密码：'
dir -Recurse *.rar,*.001,*.7z,*.zip|%{$a|&$rar x -y -o- $_.FullName $_.Directory}
复制代码

作者: buyiyang 时间: 2023-6-22 22:03

回复 15# 77七

我试了一下第二段代码错误是由于控制台粘贴问题，cmd控制台属性》粘贴时筛选剪贴板内容的功能会把中文弯角引号自动变成英文引号，从而引发错误，把这个功能关闭就正常了。

作者: 77七 时间: 2023-6-22 22:18

回复 18# buyiyang

谢谢大佬指点！果然是这样！

欢迎光临批处理之家 (http://www.bathome.net/)