批处理之家 - Powered by Discuz! Board

标题: [系统相关] 求助批处理获取硬盘id [打印本页]

作者: whhlcj 时间: 2023-5-18 09:32 标题: 求助批处理获取硬盘id

网上可以找到类似如下的代码来获取硬盘id：

echo select disk 0 >a.txt
echo detail disk >>a.txt
diskpart /s a.txt|findstr "ID:">D:\b.txt
del /q a.txt
复制代码

但这个只能获取一个磁盘的id，如何使用bat实现获取所有磁盘id？
感谢大神

作者: buyiyang 时间: 2023-5-18 11:06

本帖最后由 buyiyang 于 2023-5-19 16:11 编辑

@echo off
fltmc >nul||mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~f0","%*",,"runas",1)(window.close)&&exit
(for /f "tokens=2 delims==" %%i in ('wmic diskdrive get Index /value') do (
echo,select disk %%i
echo,detail disk
)) | diskpart | findstr "ID:"
pause
复制代码

作者: whhlcj 时间: 2023-5-18 14:09

回复 2# buyiyang

收到！
感谢大佬！！！

作者: terse 时间: 2023-5-18 23:12

这样试试diskpart

@echo off
for /f "tokens=2" %%a in ('echo list disk^|diskpart^|find /I "GB"') do (
     for /f "tokens=1*" %%b in ('"(echo sel disk %%a & echo detail disk & echo list part)|diskpart|find /i "ID:""') do (
          echo %%b %%a %%c
    )
)
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)