批处理之家 - Powered by Discuz! Board

标题: [数值计算] 批处理命令for /f 里面不能使用 set /a吗？ [打印本页]

作者: tiandyoin 时间: 2023-4-15 17:35 标题: 批处理命令for /f 里面不能使用 set /a吗？

@echo off
set regPath="HKLM\SYSTEM\CurrentControlSet\Control\FileSystem"
set v=0
for /f "tokens=3" %%a in ('Reg query %regPath% /v LongPathsEnabled') do (
	echo a=%%a
	set "v=%%a"
	set /a "v+=0"
	echo vv=%v%
	set v
	set "s=%%a"
)
	set /a "s+=0"
	echo ss=%s%
	set s
goto :eof
复制代码

如上面的代码当 LongPathsEnabled 值为 0x1 时，%v% 还是 0.

a=0x1
vv=0
v=1
ss=1
s=1
SystemDrive=C:
SystemRoot=C:\Windows
复制代码

但把
set /a "v+=0"
之后的代码移到 do() 之后，就正常，难道 for /f 里面不能使用 set /a 吗？
似乎找遍网上也没这个说法。

作者: buyiyang 时间: 2023-4-15 17:44

你可以在论坛搜索预处理、变量延迟学习一下。
简单来说，开头加上setlocal enabledelayedexpansion，语句内，%v%改成!v!

作者: Batcher 时间: 2023-4-16 17:19

回复 1# tiandyoin

@echo off
setlocal enabledelayedexpansion
set "RegPath=HKLM\SYSTEM\CurrentControlSet\Control\FileSystem"
set "v=0"
for /f "tokens=3" %%a in ('reg query "%RegPath%" /v LongPathsEnabled') do (
    echo a=%%a
    set "v=%%a"
    set /a "v+=0"
    echo vv=!v!
    set v
    set "s=%%a"
)
set /a "s+=0"
echo ss=%s%
set s
pause
复制代码

作者: tiandyoin 时间: 2024-10-2 21:20

回复 3# Batcher

要求不开延迟的，如果路径含有感叹号 !
如真实目录为:
"C:\快捷方式\Start Menu 开始菜单\test!APPDATA!%APPDATA%\叶子目录"
运行命令:
"搜索无效快捷方式.bat" "C:\快捷方式\Start Menu 开始菜单\test!APPDATA!"%"APPDATA"%"\叶子目录"

rem "搜索无效快捷方式.bat" 
:main
@echo off
set lnkId=0
for /f "delims=" %%a in ('dir /A-D /S/B "%~dp1.\%~nx1\*.lnk"') do (
setlocal enabledelayedexpansion
  set /a lnkId=!lnkId!+1
endlocal & set "lnkId=%lnkId%"
@set lnkId
）
复制代码

并不能增加 lnkId

作者: tiandyoin 时间: 2024-10-2 22:29

本帖最后由 tiandyoin 于 2024-10-3 01:32 编辑

回复 4# tiandyoin

rem "搜索无效快捷方式.bat" 
:main
  @echo off
  set lnkId=0
  for /f "delims=" %%a in ('dir /A-D /S/B "%~dp1.\%~nx1\*.lnk"') do (
    call :get_lnk_target %%~a returnVal
    call :add1 returnVal lnkId
  ）
@goto :EOF
:add1
	@if "%~1" == "" goto :EOF
	@if "%~2" == "" goto :EOF
	setlocal enabledelayedexpansion
		set "returnVal=!%~1!"
		set "lnkId=!%~2!"
		if "!returnVal!" neq "" if not exist "!returnVal!" set /a lnkId+=1
	endlocal & set "%~2=%lnkId%"
@goto :EOF
复制代码

自增量不能放在复合语句里，哪怕外层套一对括号 ()，也算处在复合语句里。
在复合语句里 %lnkId% 就会被预处理为常量
setlocal 不是复合语句， (), for , if 等是复合语句
只能另起函数求自增量了

作者: tiandyoin 时间: 2024-10-3 11:35

回复 5# tiandyoin

rem "搜索无效快捷方式.bat" 
:main
  @echo off
  set lnkId=0
  for /f "delims=" %%a in ('dir /A-D /S/B "%~dp1.\%~nx1\*.lnk"') do (
    call :get_lnk_target %%~a returnVal
    setlocal enabledelayedexpansion
    if "!returnVal!" neq "" if not exist "!returnVal!" (
       rem do somthing
       endlocal & set /a lnkId+=1
    )else endlocal
  ）
@goto :EOF
复制代码

这样写确实挺怪的。但它取到了lnkId的临时值，能自增

作者: tiandyoin 时间: 2024-10-3 11:57

回复 6# tiandyoin
前面的代码还是没处理所有的判断逻辑。重写

rem "搜索无效快捷方式.bat" 
:main
  @echo off
  set lnkId=0
  for /f "delims=" %%a in ('dir /A-D /S/B "%~dp1.\%~nx1\*.lnk"') do (
    call :get_lnk_target %%~a returnVal
    setlocal enabledelayedexpansion
    if "!returnVal!" neq "" （
      if not exist "!returnVal!" (
        rem do somthing
        endlocal & set /a lnkId+=1
      )else endlocal
    )else endlocal
  )
@goto :EOF
复制代码

作者: 77七 时间: 2024-10-3 12:11

回复 4# tiandyoin

参考此代码 http://www.bathome.net/redirect.php?goto=findpost&ptid=69847&pid=284564

作者: aloha20200628 时间: 2024-10-3 17:29

本帖最后由 aloha20200628 于 2024-10-3 17:39 编辑

回复 7# tiandyoin

回答一。for/f 循环体内可以使用 set/a，参见以下示例代码
回答二。for/f 循环体内采用自增量计算是有效的，因其未采用百分号变量%n%的显式，故可躲过预处理先行赋值，参见以下示例代码
回答三。for/f 循环体内采用 endlocal & set "lnkId=%lnkId%" 是无效的，因其百分号变量%lnkId%会被预处理先行赋值（即取自循环体之前的%lnkId%变量值，若未被定义则取空值）

示例代码：

@echo off & setlocal & for /f "delims=" %%a in ('dir /b/a-d *.txt') do set/a n+=1
echo,%n%
endlocal&pause&exit/b
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)