@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
        pushd "%%i"
        set n=
        for /f "delims=" %%a in ('dir /b /s /ad ^| sort /r') do (
                if not defined n (
                        echo %%~na
                        set n=1
                )
        )
        popd
)>>名称.txt
pause
复制代码

@echo off
rem 保存为ANSI编码格式
setlocal enableDelayedExpansion
cd /d "%~dp0"
set A=%~f0
(
	for /f "delims=" %%a in ('dir /b/s/ad^|sort/r') do (
		if "!A!" NEQ "%%~fa\" echo;%%~na
		set A=%%~dpa
	)
)>dir_name.txt
endlocal
复制代码

@echo off
for /f "delims=" %%a in ('dir /s /b /ad') do (
    dir /b /ad "%%a"|findstr .>nul 2>nul
    if errorlevel 1 echo,%%a
)
pause
复制代码

@echo off
>new_txt.txt (for /f "delims=" %%i in ('dir /b /ad') do (
        call :getfolder "%%~i" "d"
        call echo %%d%%
))
pause&exit
:getfolder
(for /f "delims=" %%a in ('dir /ad/b "%~1\"') do call :getfolder "%~1\%%a" %2)||set "%~2=%~1"&exit /b
复制代码

@echo off
for /d /r "%~dp0" %%i in (*) do (
    set "flag="
    for /d %%j in ("%%~i\*") do set "flag=1"
    if not defined flag echo;%%i
)
pause
复制代码

PowerShell "dir -Literal '%~dp0' -Recurse -Dir | ?{!$_.GetDirectories().Count} | forEach{$_.FullName}"
复制代码

@echo off
(for /f "delims=" %%d in ('dir /b/s/ad') do (
	cd /d "%%~d"
	dir /b/ad|findstr ".*">nul||echo,%%d
))>"末级目录列表.txt"
复制代码