批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理映射网络驱动器的求助 [打印本页]

作者: op20040 时间: 2022-11-21 15:06 标题: 批处理映射网络驱动器的求助

echo off
net use z: \\192.168.60.2\测试  "123456" /user:"666" /persistent:no
复制代码

如果电脑已有Z盘，怎么写判断到Y盘？？？？

作者: Batcher 时间: 2022-11-21 15:17

回复 1# op20040

@echo off
for %%i in (Z Y X W V U T S R Q P O N M L K J I H G F E D C) do (
    if not exist %%i:\ (
        set "DriveLetter=%%i"
        goto :Next
    )
)
goto :eof

:Next
net use %DriveLetter%: \\192.168.60.2\测试 "123456" /user:"666" /persistent:no
复制代码

作者: op20040 时间: 2022-11-21 16:13

回复 2# Batcher

感谢回复！又学习到了

作者: Batcher 时间: 2022-11-21 17:54

回复 3# op20040

挂载多个

@echo off
for %%a in ("\\192.168.60.2\测试" "\\192.168.60.2\Test2" "\\192.168.60.2\测试3") do (
    call :MountDisk %%a
)
goto :eof

:MountDisk
for %%i in (Z Y X W V U T S R Q P O N M L K J I H G F E D C) do (
    if not exist %%i:\ (
        set "DriveLetter=%%i"
        goto :Next
    )
)
goto :eof

:Next
net use %DriveLetter%: %1 "123456" /user:"666" /persistent:no
复制代码

作者: op20040 时间: 2022-11-23 12:38

回复 4# Batcher

重启后，再次登录打工提示输入凭据，怎么保存凭据？

欢迎光临批处理之家 (http://www.bathome.net/)