部门 A项完成 B项完成 C项完成 D项完成 E项完成 F项完成 当天排名 当月累计排名
一分局 2 7 0 1 7 7 2  1
二分局 0 0 0 1 0 0 6  2
三分局 2 8 1 1 1 9 1  3
四分局 0 0 0 1 1 0 5  5
五分局 0 0 0 1 2 1 3  7
六分局 0 0 0 1 0 0 4  6
七分局 0 5 0 1 0 6 6  3
复制代码

A项完成4,完成为0的局:二分局,四分局,五分局,六分局,七分局
B项完成20,完成为0的局:二分局,四分局,五分局,六分局
C项完成1,完成为0的局:一分局,二分局,四分局,五分局,六分局,七分局
D项完成7,完成为0的局:无
E项完成11,完成为0的局:二分局,六分局,七分局
F项完成23,完成为0的局:二分局,四分局,六分局
当日排名:三分局1,一分局2,五分局3,六分局4,四分局5,二分局6,七分局6
当月累计排名:一分局1,二分局2,三分局3,七分局3,四分局5,六分局6,五分局7
复制代码

@echo off
%1 %2

setlocal enableDelayedExpansion
set n=0
for /f "tokens=1* delims==" %%a in ('"set /p head=<1.txt& set head"') do ^
for %%i in (%%b) do set _!n!=%%i& set /a n+=1
set /a items=n-3, day_ranking=n-1, month_ranking=n
for /f "skip=1 delims=" %%a in (1.txt) do set m=0&for %%i in (%%a) do (
    if "!m!"=="0" set department=%%i
    for %%x in (_!m!) do (
        if "%%i"=="0" set %%x_0=!%%x_0! !department!
        set /a !%%x! += %%i
    )
    set /a m+=1
    set serial=0000%%i& set serial=!serial:~-4!
    if !m!==!day_ranking! set _day_ranking=!_day_ranking! !serial!.!department!
    if !m!==!month_ranking! set _month_ranking=!_month_ranking! !serial!.!department!
)
for /l %%a in (1 1 %items%) do (
    if "!_%%a_0!"=="" set _%%a_0= 无
    set #%%a=!_%%a! ^^!!_%%a!^^!, 完成为0的局:!_%%a_0!
)
for /f "tokens=1* delims==" %%a in ('set #') do echo %%b

for /f "tokens=* delims=0" %%a in ('%~s0 goto sort_ "!_day_ranking!"^|sort') do set #day_ranking=!#day_ranking!,%%~xa%%~na
for /f "tokens=* delims=0" %%a in ('%~s0 goto sort_ "!_month_ranking!"^|sort') do set #month_ranking=!#month_ranking!,%%~xa%%~na
set #day_ranking=!#day_ranking:~1!
set #month_ranking=!#month_ranking:~1!
echo 当日排名: !#day_ranking:.=!
echo 当月累计排名: !#month_ranking:.=!

pause&exit/b

:sort_
for /f "delims=" %%a in ("%~3") do for %%i in (%%~a) do echo %%i
goto :eof
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
    set /a hang+=1,lie=0
    for %%b in (%%a) do (
        set /a lie+=1&set "str=%%b"
        if not defined fj if "!str:~,1!" equ "当" set /a fj=lie
        if !hang! equ 1 (
           if !lie! neq 1 set "_!lie!=%%b#:"
           ) else (
           if !lie! equ 1 (
              set "ju=%%b"
              ) else (
              for %%c in (!lie!) do (
                  if %%c lss !fj! (
                     set /a num_%%c+=%%b 
                     if !str! equ 0 set "_%%c=!_%%c!!ju!,"
                     ) else (
                     if not defined %%c_%%b (
                        set "%%c_%%b=!ju!%%b,"
                        ) else (
                        set "%%c_%%b=!%%c_%%b!!ju!%%b,"
                     )
                  )
               )
            )
         )
    )
)
cd.>b.txt
for /l %%a in (2,1,%lie%) do (
    set "str=!_%%a!"
    if %%a lss %fj% (
       for %%b in (!num_%%a!) do (
           if "!str:~-1!" neq ":" (
              set "str=!str:~,-1!"&echo !str:#=%%b,完成为0的局!>>b.txt
              ) else (
              echo !str:#=%%b,完成为0的局!无>>b.txt
           )
       )
       ) else (
       for /l %%b in (1,1,%hang%) do if defined %%a_%%b set "str=!str! !%%a_%%b!"
       set "str=!str:#=!"&echo !str:~,-1!>>b.txt
    )
)
start b.txt
复制代码

@echo off
setlocal enabledelayedexpansion
set /a a=-1
for /f "tokens=*" %%a in (a.x) do (
   set /a a+=1,b=-1
   for %%b in (%%a) do (
      set /a b+=1
      set str[!a!][!b!]=%%b
   )
)
for /l %%b in (1,1,6) do (
  for /l %%a in (1,1,%a%) do (
    set /a !str[0][%%b]!+=str[%%a][%%b]
    if "!str[%%a][%%b]!"=="0" (set zero%%b=!zero%%b!!str[%%a][0]!;)
  )
  if "!zero%%b!"=="" (set "zero%%b=无;")
  for %%x in (!str[0][%%b]!) do (set now=!%%x!)
  echo,!str[0][%%b]!!now! , 本次完成0的分局: !zero%%b:~0,-1!
)

pause
exit
复制代码

@echo off
setlocal enabledelayedexpansion
::第一部分是赋值二维数组模型
set /a a=-1
for /f "tokens=*" %%a in (a.x) do (
   set /a a+=1,b=-1
   for %%b in (%%a) do (
      set /a b+=1 
      set str[!a!][!b!]=%%b
   )
)
set /a 项目数=b-2
::给出某项任务完成的个数，并找出0的局
for /l %%b in (1,1,%项目数%) do (
  for /l %%a in (1,1,%a%) do (
    set /a !str[0][%%b]!+=str[%%a][%%b]
    if "!str[%%a][%%b]!"=="0" (set zero%%b=!zero%%b!!str[%%a][0]!;)
  )
  if "!zero%%b!"=="" (set "zero%%b=无;")
  for %%x in (!str[0][%%b]!) do (set now=!%%x!)
  echo,!str[0][%%b]!!now! , 本次完成0的分局: !zero%%b:~0,-1!
)
::最后两列，和对应的项目名按顺序，匹配好并列出
set /a last=b-1
:result
set result=!str[0][%last%]!:
for /l %%b in (1,1,%a%) do (
   for /l %%a in (1,1,%a%) do (
     if "!str[%%a][%last%]!"=="%%b" (
       set result=!result! !str[%%a][0]!!str[%%a][%last%]!
     )
   )
)
echo,%result%
if %last% lss %b% (set /a last+=1 &goto :result)
pause
exit
复制代码

 
@echo off
setlocal enabledelayedexpansion
set/pt=<in.txt
set t=!t:  = !
set max1=0
set max2=0
for %%i in (%t:~2,-11%) do (
   set/an+=1
   set n!n!=%%i
)
for /f "skip=1 tokens=1* delims= " %%i in (in.txt) do (
   set i=0
   for %%z in (%%j) do (
      set/ai+=1
      if !i! leq %n% (
         for %%y in (!i!) do (
            if %%z==0 (
               for %%x in (w!n%%y!) do (
                  set %%x=!%%x!,%%i
               )
            ) else (
               set/as!n%%y!+=%%z
            )
         )
      ) else (
         if defined p (
            set p=
            set y%%z=!y%%z!,%%i%%z
            if !max2! lss %%z (
               set max2=%%z
            )
         ) else (
            set p=1
            set r%%z=!r%%z!,%%i%%z
            if !max1! lss %%z (
               set max1=%%z
            )
         )
      )
   )
)
for /l %%i in (1,1,%n%) do (
   set o=!n%%i!
   for %%x in (s!n%%i!) do (
      set o=!o!!%%x!,完成为0的局:
      if defined w!n%%i! (
         for %%x in (w!n%%i!) do (
            echo !o!!%%x:~1!
         )
      ) else (
         echo !o!无
      )
   )
)
set o=
for /l %%i in (1,1,%max1%) do (
   set o=!o!!r%%i!
)
echo 当日排名:!o:~1!
set o=
for /l %%i in (1,1,%max2%) do (
   set o=!o!!y%%i!
)
echo 当月累计排名:!o:~1!
pause>nul
复制代码

Option Explicit

Sub JustDoIt()
  Dim AllColumns As Integer, AllRows As Integer, i As Integer, j As Integer, ADuty As Integer, Info As String, _
    Info2 As String
  AllColumns = Range("iv1").End(xlToLeft).Column       '获取数据区列数
  AllRows = Range("a65536").End(xlUp).Row              '获取数据区行数
  For i = 2 To AllColumns - 2
    Info = ""
    ADuty = 0
    For j = 2 To AllRows
      If Cells(j, i) > 0 Then
        ADuty = ADuty + Cells(j, i)
      Else
        Info = Info & Cells(j, 1) & ","
      End If
    Next
    If Info = "" Then Info = "无"
    Cells(i, AllColumns + 1) = Cells(1, i) & ADuty & ", 完成为 0 的局: " & Info
  Next
  Info = "当日排名: "
  Info2 = "当月累计排名: "
  For i = 1 To AllRows
    For j = 2 To AllRows
      If Cells(j, AllColumns - 1) = i Then Info = Info & Cells(j, 1) & i & ","
      If Cells(j, AllColumns) = i Then Info2 = Info2 & Cells(j, 1) & i & ","
    Next
  Next
  Cells(AllColumns, AllColumns + 1) = Info & vbCrLf & Info2
  Columns(AllColumns + 1).AutoFit
  Cells(AllColumns, AllColumns + 1).Select
End Sub
复制代码