@echo off &setlocal enabledelayedexpansion
echo,%time%
(for /f "delims=" %%F in (1.txt) do (
	(call :_insertCharInStr "%%~F" newF)
	echo,!newF!
))>1.new
echo,%time%
endlocal&exit/b

:_insertCharInStr // %1=srcStr %2=newStr //处理1000行文本数据(单行字符量≤128)耗时约29秒
set "srcStr=%~1" &set "sn=" &set "k=0"
:[Loop]
for %%n in (!k!) do (set "cn=!srcStr:~%%n,1!")
if "!cn!"=="" (set "%~2=!sn!" &exit/b)
set "sn=!sn!@!cn!" &set/a "k+=1" &goto:[Loop]
复制代码

@echo off &setlocal enabledelayedexpansion
echo,%time%
(for /f "delims=" %%F in (1.txt) do (
	(call :insertCharInStr "%%~F" newF)
	echo,!newF!
))>1.new
echo,%time%
endlocal&exit/b

:insertCharInStr // %1=srcStr %2=newStr //处理1000行文本数据耗时约5秒
set "srcStr=%~1" &(call :strLen srcStr sL) &set "sn=" &set/a "sL-=1"
for /L %%k in (0,1,!sL!) do (set "sn=!sn!@!srcStr:~%%k,1!")
set "%~2=!sn!" &exit/b

:strLen // %1=被测字符串变量名 %2=返回值变量名
(set "str=a!%~1!"
set "len=0"
for /l %%a in (12,-1,0) do (
	set/a "len|=1<<%%a"
	for %%b in (!len!) do if "!str:~%%b,1!"=="" set/a "len&=~1<<%%a"
	)
)
if "%~2" neq "" set/a "%~2=!len!"
exit /b
复制代码

@set @v=1 /*
@echo off &setlocal enabledelayedexpansion
echo,%time%
::处理1000行数据耗时约30秒
(for /f "delims=" %%F in (1.txt) do (
	for /f "delims=" %%v in ('cscript /e:jscript "%~f0" "%%~F" ') do set "newF=%%v"
	echo,!newF!
))>1.new
echo,%time%
endlocal&exit/b
*/
var v=WSH.Arguments; //获取命令行参数
WSH.Echo(v(0).replace(/(.)/g,'@$1')); //在字符串中逐列插入字符
复制代码

@set @v=1 /*
@echo off
echo,%time%
::处理1000行文本数据(单行字符量≤128)耗时约0.05秒
cscript /e:jscript "%~f0" "1.txt"
echo,%time%
exit/b
*/
var v=WSH.Arguments; //获取命令行参数
var fso=new ActiveXObject('scripting.filesystemobject');
var alltext=fso.opentextfile(v(0)).readall();
alltext=alltext.replace(/([^\r\n])/g,'@$1'); //在字符串中逐列(排除换行符)插入字符
fso.opentextfile("1.new", 2, true).write(alltext);
复制代码