Board logo

标题: [其他] [已解决]批处理如何给视频批量截图结尾最后3秒处？ [打印本页]
作者: a574045075    时间: 2022-9-27 19:16     标题: [已解决]批处理如何给视频批量截图结尾最后3秒处？

本帖最后由 a574045075 于 2022-9-28 17:44 编辑

我有1000多个视频mp4格式，每个视频的时长不一样，有什么方法或软件可以批量截取位于视频结尾最后3秒处的截图，并截图的图片文件名和视频名相同？
作者: waitfortea    时间: 2022-9-27 20:00

本帖最后由 waitfortea 于 2022-9-27 20:01 编辑

这个你得调用视频软件的命令行吧，bat只能帮你循环，如果目标是bat脚本的话
作者: waitfortea    时间: 2022-9-27 20:00

如果视频软件有这个命令行的话，你得把这执行截图 跳转时间的命令行分享出来别人才好帮你
作者: Batcher    时间: 2022-9-28 11:30

回复 1# a574045075 
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. REM 视频结尾最后3秒处

  4. set "SecBack=3"

  5. REM 根据自己电脑实际情况设置ffmpeg的路径

  6. set "path=C:\Program Files\ffmpeg\ffmpeg-n5.1-latest-win64-gpl-5.1\bin\;%path%"

  7. for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (

  8.     echo Current file: %%i

  9.     for /f "tokens=2-5 delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (

  10.         echo Duration %%a:%%b:%%c:%%d

  11.         set /a "TotalCS=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*100+1%%d%%100"

  12.         set /a "SeekCS=TotalCS-SecBack*100"

  13.         set /a "SeekSS=SeekCS/100"

  14.         set /a "HH=SeekSS/3600+100"

  15.         set /a "MM=SeekSS%%3600/60+100"

  16.         set /a "SS=SeekSS%%60+100"

  17.         set /a "CS=SeekCS%%100+100"

  18.         set "SeekPosition=!HH:~1!:!MM:~1!:!SS:~1!.!CS:~1!"

  19.         echo Position !SeekPosition!

  20.     )

  21.     ffmpeg -v quiet -i "%%i" -ss !SeekPosition! -frames:v 1 "%%~ni.png"

  22. )
复制代码
作者: xp3000    时间: 2022-9-28 13:36

本帖最后由 xp3000 于 2022-9-28 23:17 编辑

ffmpeg截图命令我改了一下确实快了很多
  1. @echo off & setlocal enabledelayedexpansion

  2. title ffmpeg视频尾部X秒批量截图

  3. :a

  4. set /p "str=输入1-9秒:"

  5.    echo %str%|findstr /x "[1-9]" >nul||(echo 输入有误,按任意键返回&goto :a ) 

  6. 

  7. for /f "delims=" %%i in ('dir /b /a-d *.avi *.mkv *.mp4 *.flv') do (

  8.     for /f "tokens=2-5delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (

  9.         set /a "t=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*1000+1%%d0%%1000,t-=%str%*1000,ms=t%%1000,t/=1000"

  10.         set /a h=t/3600,m=t%%3600/60,s=t%%60,h+=100,m+=100,s+=100,ms+=1000

  11.         set "t=!h:~1!:!m:~1!:!s:~1!.!ms:~1!"

  12.         echo 文件：%%i 将在!t!处截图，请耐心等待……

  13.         ffmpeg -v quiet -ss !t! -i "%%i" -frames:v 1 "%%~ni.png"

  14.     )

  15. )

  16. pause
复制代码
有时候自己也要用到截图尾部几十秒的
  1. @if(0)==(0) echo off& setlocal EnableDelayedExpansion&cd %~dp0

  2. title ffmpeg视频尾部XX秒批量截图

  3. :ss

  4. set /p ss=请输入秒数（例：5或21）: 

  5. @for /f "delims=" %%i in ('echo %ss%^|cscript -nologo -e:jscript "%~f0"') do (

  6. if not "%%i"=="正确" echo. & echo 时间格式不对，请重新输入1-59内数字 & goto ss

  7. )

  8. for /f "delims=" %%i in ('dir /b /a-d *.avi *.mkv *.mp4 *.flv') do (

  9.     for /f "tokens=2-5delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (

  10.         set /a "t=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*1000+1%%d0%%1000,t-=%ss%*1000,ms=t%%1000,t/=1000"

  11.         set /a h=t/3600,m=t%%3600/60,s=t%%60,h+=100,m+=100,s+=100,ms+=1000

  12.         set "t=!h:~1!:!m:~1!:!s:~1!.!ms:~1!"

  13.         echo 文件：%%i	将在!t!处截图，请耐心等待……

  14.     )

  15.     ffmpeg -v quiet -ss !t! -i "%%i" -frames:v 1 "%%~ni.jpg"

  16. )

  17. 

  18. pause & exit /b

  19. @end

  20. WSH.echo(WSH.StdIn.ReadAll().replace(/^[1-5]\d|^[1-9]/, '正确').match(/^[^\r\n]+/).join('\r\n'));
复制代码
作者: a574045075    时间: 2022-9-28 16:47

本帖最后由 a574045075 于 2022-9-28 17:02 编辑
回复  a574045075
Batcher 发表于 2022-9-28 11:30



    谢谢了
作者: a574045075    时间: 2022-9-28 17:36

回复 4# Batcher


    截图太慢了，几十秒截个图，我把命令行改为ffmpeg -v quiet -ss !SeekPosition! -i "%%i" -frames:v 1 "%%~ni.png"速度飞快.
作者: Batcher    时间: 2022-9-28 17:45

回复 7# a574045075


    就是把  -ss !SeekPosition! 和 -i "%%i" 调换了一下位置是吧？
作者: a574045075    时间: 2022-9-28 18:10

回复 8# Batcher


    是的



欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2