@echo off &setlocal enabledelayedexpansion
:[Loop] // 测试代码》中文数字转为阿拉伯数字(0-2147483647)
set "cn="
set/p cn="输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】："
if not defined cn endlocal&exit/b
(call :ChangeCnToAn !cn! an)
echo,n=!an!
goto [Loop]

:: 分段求和函数》最大输出范围={ 0~2147483647 }
:ChangeCnToAn // %1=中文数字符串(实值) %2=返回值变量名
if "%~1"=="零" (set "%~2=0")&exit/b
set "#cn#=%~1" &set "Yn=100000000"
if "!#cn#:~-1!"=="亿" (
    (call :ChangeCnToAn9999 !#cn#:~,-1! #n)
    (set/a "%~2=!#n!*!Yn!")&exit/b
)
set "#cn#=!#cn#:*亿=!" &set "#cn=!#cn#:零=!"
if "!#cn:万=!" neq "!#cn!" (for /f "tokens=1-2 delims=万" %%a in ("!#cn!") do (
    (call :ChangeCnToAn9999 %%a nL)
    set/a "#n=!nL!*10000"
    if "%%b" neq "" (
        (call :ChangeCnToAn9999 %%b nR)
        set/a "#n+=!nR!"
    )
)) else (call :ChangeCnToAn9999 !#cn! #n)
if "!#cn#!" neq "%~1" for /f "tokens=1-2 delims=亿" %%a in ("%~1") do (
    (call :ChangeCnToAn9999 %%a nY)
    (set/a "#n+=!nY!*!Yn!")
)
set "%~2=!#n!" &exit/b

:: 最小段位转换函数》输出范围={ 0~9999 }
:ChangeCnToAn9999 // %1=中文数字符串(实值) %2=返回值变量名
if "%~1"=="零" set "%~2=0"&exit/b
set "cn#=%~1"&set "cn#=!cn#:零=!"&set "uList=十,百,千"
set/a "n#=0,一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9,十=10,百=100,千=1000"
for /L %%k in (0, 2, 6) do if "!cn#:~%%k,1!" neq "" (
    set "n2c=!cn#:~%%k,2!" &set "nc1=!n2c:~0,1!" &set "nc2=!n2c:~1,1!"
    if "!nc2!"=="" (set/a n#+=!nc1!) else for %%c in (!nc2!) do (
        if "!uList:%%c=!" neq "!uList!" (set/a n#+=!nc1!*!nc2!) else (set/a n#+=!nc1!+!nc2!)
    )
)
set "%~2=!n#!" &exit/b
复制代码

输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】：一万九千七百
n=19700
输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】：一百零一
n=101
输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】：一亿零二十万零伍佰零一
n=100200001
输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】：
复制代码

@echo off
setlocal enabledelayedexpansion
set str=九千九百九十九亿九千九百九十九万九千九百九十九
set str=!str:零=!
set str=!str:亿=亿 !
set str=!str:万=万 !
set _十=10
for %%i in (一 二 三 四 五 六 七 八 九) do (
    set /a x+=1
    set /a _%%i=!x!
    set y=1
    for %%j in (十 百 千) do (
        set /a y*=10
        set /a _%%i%%j=!x!*!y!
    )
)
for %%i in (!str!) do (
    set Part=%%i
    if !Part:~-1!==亿 (
        set Part1=!Part:~,-1!
    ) else if !Part:~-1!==万 (
        set Part2=!Part:~,-1!
    ) else (
        set Part3=%%i
    )
)
for /l %%i in (1,1,3) do (
    if defined Part%%i (
        set Part%%i=!Part%%i:千=千 !
        set Part%%i=!Part%%i:百=百 !
        set Part%%i=!Part%%i:十=十 !
        for %%j in (!Part%%i!) do set /a m%%i+=_%%j
    )
    set /a m%%i+=10000
    set m%%i=!m%%i:~1!
)
for /f "tokens=* delims=0" %%i in ("!m1!!m2!!m3!") do echo,%%i
pause
复制代码

输入一个中文数字【零 - 二十一亿四千七百四十八万三千六百四十七】：一亿零二十万零伍佰零一
n=100200001
复制代码

中文数字的输入格式应为中文小写格式》亿万千百十...而佰须改为百

for %%v in ("壹=一", "贰=二", "叁=三", "肆=四", "伍=五", "陆=六", "柒=七", "捌=八", "玖=九", "拾=十", "佰=百", "仟=千") do (set "cn=!cn:%%~v!")
复制代码

:: 最小段位转换函数》输出范围={ 0~9999 }
:ChangeCnToAn9999 // %1=中文数字符串(实值) %2=返回值变量名
if "%~1"=="零" set "%~2=0"&exit/b
set "cn#=%~1" &set "cn#=!cn#:零=!"&set "uList=十,拾,百,佰,千,仟"
set/a "n#=0,一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9,十=10,百=100,千=1000"
set/a "n#=0,壹=1,贰=2,叁=3,肆=4,伍=5,陆=6,柒=7,捌=8,玖=9,拾=10,佰=100,仟=1000"
for /L %%k in (0,2,6,8,10,12) do if "!cn#:~%%k,1!" neq "" (
    set "n2c=!cn#:~%%k,2!" &set "nc1=!n2c:~0,1!" &set "nc2=!n2c:~1,1!"
    if "!nc2!"=="" (set/a n#+=!nc1!) else for %%c in (!nc2!) do (
        if "!uList:%%c=!" neq "!uList!" (set/a n#+=!nc1!*!nc2!) else (set/a n#+=!nc1!+!nc2!)
    )
)
set "%~2=!n#!" &exit/b
复制代码

只要能经受各种测试就好...

@echo off&setlocal enabledelayedexpansion
set/a "零=0,一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9,十=10,百=100,千=1000,万=10000,亿=100000"
set "str=八十二亿零十"
set "s=!str!
if "!s:~16!" neq "" (set len=16&set "s=!s:~16!") else set len=0
set "s=!s!fedcba9876543210"
set /a "len+=0x!s:~16,1!,result=content=num=0"
set "stry="
for /l %%i in (0,1,!len!) do for /f %%j in ("!str:~%%i,1!") do (
     if !%%j! geq 10 (
        if !%%j! gtr 1000 (
            if !%%j! gtr 10000 (
              set /a stry=result+content+num,result=content=0"
              set stry=!stry!00000000
          )else set /a "content=(content+num)*%%j,result+=content,content=0"
        ) else set /a "num+=^!num,content+=num*%%j"
        set "num=0"
     ) else if !%%j! neq 0 set num=!%%j!
)
set /a "result+=content+num
if defined stry (
   set "s1=!stry!fedcba9876543210"
   set "s2=!result!fedcba9876543210"
   set /a "len=0x!s1:~16,1!-0x!s2:~16,1!"
   for /f %%i in ("!len!") do echo !str! "!stry:~,%%i!!result!"
) else echo;!str! !result!
pause
复制代码