批处理之家 - Powered by Discuz! Board

标题: [其他] 萌新，求大神帮忙写个执行adb命令的批处理感谢！感谢！ [打印本页]

作者: wyydg75 时间: 2022-6-12 22:58 标题: 萌新，求大神帮忙写个执行adb命令的批处理感谢！感谢！

萌新求助，想写个一键禁用手机系统app的批处理，奈何一窍不通网上查了好多资料也没弄好，只好来求那位大神有空帮忙给写个，感谢！感谢！
abd执行命令如下（都是一样的，列出了几个示例）：
adb shell pm uninstall --user 0 com.samsung.hongbaoassistant
adb shell pm uninstall --user 0 com.samsung.android.softsim
adb shell pm uninstall --user 0 com.samsung.android.spay
adb shell pm uninstall --user 0 com.samsung.android.spayfw
adb shell pm disable-user com.samsung.android.game.gametools
adb shell pm disable-user com.samsung.android.rubin.app
adb shell pm disable-user com.sec.android.app.sbrowser
adb shell pm disable-user com.sec.spp.push

adb目录设为F:\adb
每个命令都要有返回结果，全部处理完后不要关闭，以便查看校对。

作者: went 时间: 2022-6-13 11:13

禁用指定的包名

@echo off & cd /d "%~dp0"
REM 设置adb工具包
set "PATH=%PATH%;F:\adb"
REM 设置要禁用的包名
set "pkg_list=%pkg_list% com.samsung.android.game.gametools"
set "pkg_list=%pkg_list% com.samsung.android.rubin.app"
set "pkg_list=%pkg_list% com.sec.android.app.sbrowser"
set "pkg_list=%pkg_list% com.sec.spp.push"
set "pkg_list=%pkg_list% com.tencent.mobileqq"
REM 执行禁用
for %%i in (%pkg_list%) do adb shell pm disable-user %%i
pause&exit
复制代码

作者: went 时间: 2022-6-13 11:18

禁用所有系统app

@echo off & cd /d "%~dp0"
REM 设置adb工具包
set "PATH=%PATH%;F:\adb"
REM 执行禁用所用系统app
for /f "tokens=1* delims=:" %%i in ('adb shell pm list package -s') do (
	adb shell pm disable-user %%j
)
pause&exit
复制代码

若要禁用所有用户app,将-s 改为-3
若要执行启用,将disable-user改为enable

作者: wyydg75 时间: 2022-6-13 12:06

回复 2# went

感谢！感谢大神的帮忙！另，还有几个是需要卸载的，是否可以一块加上？

作者: went 时间: 2022-6-13 12:33

卸载我没有测试,第11行修改

REM 执行禁用
for %%i in (%pkg_list%) do (
    adb shell pm disable-user %%i
    adb shell pm uninstall --user 0 %%i
)
复制代码

作者: wyydg75 时间: 2022-6-13 13:27

回复 5# went

感谢！
修改disable-user是可行的。
但如果要将卸载和禁用放入同一个批处理执行呢，只将disable-user更改为uninstall --user 0 则全部被卸载，无法区分那些是卸载那些是禁用。

作者: went 时间: 2022-6-13 14:06

@echo off & cd /d "%~dp0"
REM 设置adb工具包
set "PATH=%PATH%;F:\adb"
REM 设置要卸载的包名
set "pkg_uninst_list=%pkg_uninst_list% com.samsung.hongbaoassistant"
set "pkg_uninst_list=%pkg_uninst_list% com.samsung.android.softsim"
set "pkg_uninst_list=%pkg_uninst_list% com.samsung.android.spay"
set "pkg_uninst_list=%pkg_uninst_list% com.samsung.android.spayfw"
REM 设置要禁用的包名
set "pkg_disable_list=%pkg_disable_list% com.samsung.android.game.gametools"
set "pkg_disable_list=%pkg_disable_list% com.samsung.android.rubin.app"
set "pkg_disable_list=%pkg_disable_list% com.sec.android.app.sbrowser"
set "pkg_disable_list=%pkg_disable_list% com.sec.spp.push"
REM 执行卸载
for %%i in (%pkg_uninst_list%) do adb shell pm uninstall --user 0 %%i
REM 执行禁用
for %%i in (%pkg_disable_list%) do adb shell pm disable-user %%i
pause&exit
复制代码

回复 6# wyydg75

作者: wyydg75 时间: 2022-6-13 15:19

回复 7# went

完美！感谢！

欢迎光临批处理之家 (http://www.bathome.net/)