批处理之家 - Powered by Discuz! Board

@echo off
set nums=0
for /f %%i in ('dir /b /s 1357.txt') do (
for /f "skip=5 tokens=1-4" %%j in (%%i) do (
set num=%%m
call set num=%%num:,=%%
call set num=%%num:.=%%
call set /a nums+=%%num%%
)
)
echo 总交易金额是:%nums:~0,-2%.%nums:~-2%
pause

复制代码

@echo off&setlocal enabledelayedexpansion
set lx=6210,6221,6222
set "6210=认购" && set "6221=申购" && set "6222=赎回"
for %%a in (%lx%) do (
set nums=0
for /f %%i in ('dir /b /s %%a') do (
for /f "skip=5 tokens=1-4" %%j in (%%i) do (
if not "%%j"=="*" (
set num=%%m
set num=!num:,=!
set num=!num:.=!
set /a nums+=!num!>nul 2>nul
)
)
)
echo !%%a!类型总交易金额是:!nums:~0,-2!.!nums:~-2!
)
echo.&echo ---统计完成,键任意键退出.&pause>nul

复制代码

@echo off&setlocal enabledelayedexpansion
set batpath=%~d0%~p0
echo 统计中...
for /f %%i in ('dir /b /ad RPT2007*') do (
cd /d %%i
for /f "delims=" %%j in ('dir /b /s 62*') do (
for /f "skip=5 tokens=4" %%k in ('type "%%j"') do (
set t=%%k
echo !t:,=! >>"%batpath%result.txt"
)
)
cd ..
)
echo dim fso,data,n,sum,h >>cal.vbs
echo set fso=createobject("scripting.filesystemobject") >>cal.vbs
echo set data=fso.opentextfile("result.txt") >>cal.vbs
echo do >>cal.vbs
echo n=data.readline >>cal.vbs
echo if isnumeric(n) then >>cal.vbs
echo n=cdbl(n) >>cal.vbs
echo sum=sum+n >>cal.vbs
echo end if >>cal.vbs
echo loop until data.atendofstream >>cal.vbs
echo data.close >>cal.vbs
echo fso.deletefile("result.txt") >>cal.vbs
echo fso.deletefile "cal.vbs" >>cal.vbs
echo msgbox "总额为：" ^& sum ^& "元。" >>cal.vbs
start cal.vbs

复制代码

@echo off
:: 凌晨时发的代码有错误，请用本次代码测试[2008-1-29 17:59]
cd.>test.txt
set /a total=0,times=1
for /f "delims=" %%i in ('dir /a-d /b /s 1357.txt') do (
>>test.txt more +5 "%%i"
)
setlocal enabledelayedexpansion
for /f "tokens=1,4,5 delims=,. " %%i in ('sort test.txt') do (
if defined ID (
if "!ID!"=="%%i" (
set /a times+=1
) else (
echo !ID! 出现的次数是 !times!
set times=1
)
)
set /a total+=%%j%%k
set ID=%%i
)
echo %ID% 出现的次数是 %times%
echo 总金额是 %total%.00
pause

复制代码

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s 1357.txt') do (
for /f "usebackq skip=5 tokens=4,5 delims=,. " %%j in ("%%i") do (
set /a total+=%%j%%k
)
)
echo 总金额是 %total%.00
pause

复制代码

@echo off
:: 1、搜索所有的数据文件
:: 2、提取所有数据文件中第5行后所有的第一列数据，
:: 3、重组为 "第一列数据纯数字型文件夹名纯数字型文件名"的格式(关键)
:: 4、把重组后的数据按照月份写入"根目录\tmp\××\tmp1.txt"文件中
:: 5、把tmp1.txt中的所有帐号内容提取到tmp2.txt中
:: 6、对tmp2.txt中的数据进行统计，按照
:: "帐户号月份总数" 或者
:: "帐户号月份数类型号小计数" 的格式导入"根目录\tmp\tmp_月份号.txt"中
:: 7、按格式提取统计信息
:: 关键处有两点：1、重新组合相关数据并分类写入相关文件；2、各种相似数据的累加
rem ==========初始化各种设置=============
set begin=%time%
set root=%cd:~0,2%
set FileNum=0
:: 统计脚本所在目录存在的文件数量，为后面的 skip=%FileNum% 提供数据
for /f %%i in ('dir /a-d') do set /a FileNum+=1
echo.&echo 　　　　本程序将创建临时文件夹 %root%\tmp ，里面存放的是程序运行期间产
echo 　　生的各种临时数据。为便于跟踪测试，本程序保留所有的临时文件，这
echo 　　些文件可在程序运行完毕后全部删除。无论删除与否，都不会影响程序
echo 　　下一次运行的结果。
echo.&echo 　　　　正在处理数据。视待处理数据量的大小，这个过程将持续数分钟到
echo 　　数十分钟不等，请耐心等待...
rem ==========生成各种临时文件=============
:: 提取原始文件中的相关信息，重新组合，写入临时文件，以备最后的统计
rd /q /s %root%\tmp 2>nul
setlocal enabledelayedexpansion
:: 把每个月的相关的临时数据写入以月份命名的临时文件夹下
:: 要做的一些事情：过滤每个文件的头5行（skip=5）、重新组合相关数据（关键处之一）
:: 生成每个月的第一个临时文件
for /f "skip=%FileNum% tokens=1-6 delims=\" %%i in ('dir /a-d /b /s') do (
title 正在提取 %%i\%%j\%%k\%%l\%%m\%%n 中数据
set month=%%l
set month=!month:~7,2!
md %root%\tmp\!month! 2>nul
if not exist %root%\tmp\!month!\tmp1.txt (
echo ;本文件为临时中转文件，在 %%i\%%j\%%k 下!month!月份数据的基础上产生
echo ;处理结果请看 %root%\tmp\%%i\tmp2.txt
echo ;以下数据的含义为：交易帐号纯数字文件夹名纯数字文件名
echo ;因为原文件数据格式不尽一致的原因，某些行的数据含义与上述描述不尽相符
echo ;
)>%root%\tmp\!month!\tmp1.txt
for /f "skip=5" %%x in (%%i\%%j\%%k\%%l\%%m\%%n) do (
echo %%x %%m %%n>>%root%\tmp\!month!\tmp1.txt
)
)
cd.>result.txt
:: 生成每个月的第二个临时文件
for /f %%i in ('dir /ad /b %root%\tmp') do (
if not exist %root%\tmp\%%i\tmp2.txt (
echo ;本文件为临时中转文件，在 %root%\tmp\%%i\tmp1.txt 的基础上产生
echo ;为后续处理做准备，处理结果请看 %root%\tmp\tmp_%%i.txt
echo ;以下数据的含义为：交易帐号纯数字文件夹名纯数字文件名
echo ;
)>%root%\tmp\%%i\tmp2.txt
findstr /b "[0-9]" %root%\tmp\%%i\tmp1.txt>>%root%\tmp\%%i\tmp2.txt
for /f "delims==" %%j in ('set num_ 2^>nul') do set %%j=
for /f "tokens=1-3" %%j in (%root%\tmp\%%i\tmp2.txt) do (
title 正在统计%%i月份数据
set /a num_%%k+=1&set /a num_%%k_%%l+=1
)
(
echo ;本文件为临时中转文件，在所有子目录下的tmp2.txt基础上产生
echo ;处理结果请看 %cd%\result.txt
echo ;以下数据的含义为：纯数字文件夹名月份总数或者纯数字文件夹名月份纯数字文件名小计
echo ;
)>%root%\tmp\tmp_%%i.txt
for /f "tokens=2,3,4 delims=_=" %%j in ('set num_') do (
if "%%l"=="" (
>>%root%\tmp\tmp_%%i.txt echo %%j %%i %%k
) else (
>>%root%\tmp\tmp_%%i.txt echo %%j %%i %%k %%l
)
)
for /f "tokens=1-4" %%j in ('sort %root%\tmp\tmp_%%i.txt') do (
if "%%m"=="" (
(echo.&echo %%j %%k月份新开户数 %%l，其中：)>>result.txt
) else (
>>result.txt echo %%l 为 %%m
)
)
)
(echo.&echo 程序开始运行时间 %begin%，结束运行时间 %time%)>>result.txt
start result.txt

复制代码