批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求修改随机重命名文件的批处理感谢！！！ [打印本页]

作者: maoanqi110 时间: 2022-3-16 14:05 标题: 求修改随机重命名文件的批处理感谢！！！

大哥们这是一个让文件夹内所有文件全随机变成4位英数的BAT
我想加入
保留原文件名前6位
要怎么改！求教谢谢！！！！

@echo off
setlocal enabledelayedexpansion
set "s=0123456789abcdefghijklmnopqrstuvwxyz"
for %%b in (*.*) do (
	if not "%%b"=="%~nx0" (
		call :loop
		ren "%%b" "!name!%%~xb"
		set loop=
		set name=
	)
)
pause
goto :eof
:loop
set /a loop+=1
set /a r=%random%%%36
set name=%name%!s:~%r%,1!
if "%loop%"=="4" goto :eof
goto :loop
复制代码

作者: qixiaobin0715 时间: 2022-3-16 15:39

未测试：

@echo off
set var=0123456789abcdefghijklmnopqrstuvwxyz
for /f "delims=" %%a in ('dir /b /a-d') do (
    setlocal enabledelayedexpansion
    set filename=%%~na
    set filename=!filename:~,6!
    if not "%%a"=="%~nx0" (
        for /l %%i in (1,1,4) do (
            set /a num=!random!%%36
            for %%j in (!num!) do set str=!str!!var:~%%j,1!
        )
        ren "%%a" "!str!!filename!%%~xa"
    )
    endlocal
)
pause
复制代码

作者: Fit 时间: 2022-3-18 20:24

将ren "%%b" "!name!%%~xb"
换成
set "str=%%b"
ren "%%b" "!str:~0,6!!name!%%~xb"

看看能行不

欢迎光临批处理之家 (http://www.bathome.net/)