批处理之家 - Powered by Discuz! Board

标题: [文本处理] Bat如何判断txt文本中第8行是否只有"符号，有则删除整行 [打印本页]

作者: 739483260 时间: 2021-12-1 23:56 标题: Bat如何判断txt文本中第8行是否只有"符号，有则删除整行

本帖最后由 739483260 于 2021-12-2 09:22 编辑

用某程序对几千个txt文本修改后导致第八行会莫名出现单独的一个"符号几千个txt文本一个一个打开删除太累求大佬帮助写一个bat判断并处理一下注意需要判断的是第八行文本是否只有"符号只有"符号则删除整行内容
举例：
xxxxxxx
cxxx
  31312
  32132
  321321
  31245
6785
"
213
希望bat判断并修改后的内容：
xxxxxxx
cxxx
  31312
  32132
  321321
  31245
6785
213

作者: qixiaobin0715 时间: 2021-12-2 10:20

本帖最后由 qixiaobin0715 于 2021-12-13 11:12 编辑

@echo off
md NewFolder
setlocal enabledelayedexpansion
for %%i in (*.txt) do (
    set n=0
    (for /f "delims=" %%a in (%%i) do (
        set /a n+=1
        if !n! equ 8 (
            set str=%%a
            set "str=!str:"=!"
            if "!str!"=="%%a" echo,%%a
        ) else echo,%%a
    ))>NewFolder\%%i
)
pause
复制代码

作者: 739483260 时间: 2021-12-2 17:04

本帖最后由 739483260 于 2021-12-2 17:16 编辑

回复 2# qixiaobin0715

大佬这个第8行除了有"符号还有很多空格刚才试了一下如果第八行的"符号不在行首就不能删除麻烦您再改一下

作者: 739483260 时间: 2021-12-11 11:13

该问题仍然没有解决求大佬帮助

作者: WHY 时间: 2021-12-11 22:18

回复 3# 739483260

既然第8行只有"字符，空格又是咋回事呢？空格不是字符啊？

作者: WHY 时间: 2021-12-11 22:21

sed下载

sed -i -r "8{/^\s*\x22\s*$/d}" *.txt
复制代码

作者: 739483260 时间: 2021-12-12 09:59

回复 6# WHY

大佬牛逼会有一个不影响使用的小问题就是会生成sed的临时文件

作者: qixiaobin0715 时间: 2021-12-13 11:33

改变一下判断方法，2楼代码应当能用，已修改：如果第8行存在双引号，即删除。

作者: 739483260 时间: 2021-12-13 21:07

回复 8# qixiaobin0715

需要判断第8行是否只有1个"符号和 N个空格或者只有一个"符号如果有则删除
有的文件第8行是正常的比如"4213" 这样第8行也存在"符号但是最新的代码也会将这一行删除掉

作者: WHY 时间: 2021-12-13 23:54

纯批的话，这样如何？

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set /a n+=1
    if !n!==8 (
        set "s=%%i"
        set "s=!s:"=""!"
        set "s=!s: =!"
        if not "!s!" == """" echo;%%i
    ) else (
        echo;%%i
    )
)
pause
复制代码

作者: 739483260 时间: 2021-12-14 18:45

回复 10# WHY

但是这样不能将所有txt一键修改

作者: 739483260 时间: 2021-12-14 23:37

回复 10# WHY

麻烦大佬再修改能一键修复所有txt的同个文件夹下有几千个txt 谢谢大佬了

作者: 739483260 时间: 2021-12-15 08:44

回复 10# WHY

并且只能在bat中正常显示，但是不能将bat中正常显示的内容写入原txt文本里

作者: Batcher 时间: 2021-12-15 09:49

回复 13# 739483260

测试代码之前请注意做好备份

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
    set n=0
    (for /f "delims=" %%i in ('type "%%a"') do (
        set /a n+=1
        if !n! == 8 (
            set "s=%%i"
            set "s=!s:"=""!"
            set "s=!s: =!"
            if not "!s!" == """" (
                echo,%%i
            )
        ) else (
            echo,%%i
        )
    ))>"%%a.BatHome"
    move /y "%%a.BatHome" "%%a"
)
复制代码

作者: 739483260 时间: 2021-12-15 20:26

回复 14# Batcher

管理大佬有没有处理效率更快的写法呢？

作者: Batcher 时间: 2021-12-15 21:02

回复 15# 739483260

6楼的sed命令速度应该比较快

欢迎光临批处理之家 (http://www.bathome.net/)