批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理如何批量删除文件夹名称中的括号及括号之间的内容？ [打印本页]

作者: 935956720 时间: 2021-12-1 17:58 标题: 批处理如何批量删除文件夹名称中的括号及括号之间的内容？

如：文件夹名称为：
XXX（XXX）XXX
（XXX）XXXXX
（XX）XXX

作者: Batcher 时间: 2021-12-1 19:04

回复 1# 935956720

每个文件夹名称里面都有且只有一对括号是吗？
括号是英文输入法的()还是中文输入法的（）呢？

作者: qixiaobin0715 时间: 2021-12-3 15:09

假定为英文括号：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /ad^|sort /r') do (
    set "str=%%~nxi"
    set "str1=!str:(= (!"
    set "str1=!str1:)=) !"
    for %%j in (!str1!) do (
        set "str2=%%j"
        if "!str2:~,1!"=="(" set "str=!str:%%j=!"
    )
    ren "%%i" "!str!"
)
pause
复制代码

如果是中文括号可修改代码中第5、6、9行中对应的左右英文括号即可。

作者: Batcher 时间: 2021-12-11 17:28

回复 1# 935956720

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
for /f "tokens=1* delims=(" %%i in ('dir /b /ad') do (
	if "%%j"=="" (
        set "FileRight=%%i"
        set "FileLeft="
    ) else (
        set "FileRight=%%j"
        set "FileLeft=%%i"
    )
    set "OldName=!FileLeft!(!FileRight!"
    set "FileRight=!FileRight:*)=!"
    set "NewName=!FileLeft!!FileRight!"
    ren "!OldName!" "!NewName!"
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)