批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求BAT操作文件夹判断是否合格；合格进行压缩处理 [打印本页]

作者: bat小猎手 时间: 2021-11-8 10:05 标题: 求BAT操作文件夹判断是否合格；合格进行压缩处理

判断文件夹文件数量；文件后缀；文件夹名称；三者都合格；进行压缩文件夹处理。求大神援手。。。。

作者: Batcher 时间: 2021-11-8 11:40

回复 1# bat小猎手

请举例说明合格的具体条件是什么？

作者: bat小猎手 时间: 2021-11-9 10:12

回复 2# Batcher

合格就是说，1.在数量上符合要求；至少有1个文件；2，在文件后缀上；必须是指定格式；例如 txt，3.在文件夹名称上；必须是指定名称

作者: Batcher 时间: 2021-11-9 13:07

回复 3# bat小猎手

@echo off
cd /d "%~dp0"
REM 指定文件夹名称
set "FolderName=身份证"
REM 指定文件扩展名
set "FileExt=txt"
REM 根据自己电脑实际情况设置 7-Zip 的路径
set "path=C:\Program Files\7-Zip;%path%"

for /f "delims=" %%i in ('dir /b /s /ad "%FolderName%"') do (
    echo 正在处理文件夹 %%i
    pushd "%%i"
    if exist "*.txt" (
        7z.exe a "%%~nxi.zip" "%%i"
    )
    popd
)
pause
复制代码

作者: bat小猎手 时间: 2021-11-16 09:21

回复 4# Batcher

@echo off
if not exist a echo "缺少A文件夹"
if not exist b echo "缺少b文件夹"
if not exist c echo "缺少c文件夹"

For /r %%i IN (*) DO if not %%~xi == .txt if not %%~xi== .bat echo"存在后缀名不为txt的文件” %%i
pause
复制代码

这段是可以达到检测出文件夹名是否符合要求。文件夹内文件是否符合要求。但是这个应该怎么去中断操作？意思就是说：如果检测出文件夹名不符合要求或文件夹内文件不符合要求该怎么退出操作下面还有其他操作的
比如说 "C:\Program Files\7-Zip\7z.exe" a 30.zip .\a\ 如果没有a文件夹，或者不符合要求的；不对其进行压缩处理

作者: Batcher 时间: 2021-11-16 09:58

回复 5# bat小猎手

@echo off
set "ExecFlag=1"
for %%i in (inCertificate smCertificate smRoot root) do (
    if not exist %%i (
        echo 缺少文件夹 %%i
        set "ExecFlag=0"
    )
)
for /r %%i in (*) do (
    if not %%~xi == .pem (
        if not %%~xi == .bat (
            echo 存在后缀名不为pem的文件 %%i
            set "ExecFlag=0"
        )
    )
)
if %ExecFlag% == 1 (
    echo "C:\Program Files\7-Zip\7z.exe" a  30.zip .\a\
)
pause
复制代码

作者: bat小猎手 时间: 2021-11-16 10:37

回复 6# Batcher

大神；在里面增加一个判断。。。。
root文件夹文件数量不超过20个不少于1个的判断；否则也不进行压缩处理

:kiss:

作者: Batcher 时间: 2021-11-16 11:09

回复 7# bat小猎手

@echo off
set "RootMax=20"
set "FileCount=0"
set "ExecFlag=1"
for %%i in (inCertificate smCertificate smRoot root) do (
    if not exist %%i (
        echo 缺少文件夹 %%i
        set "ExecFlag=0"
    )
)
for /r %%i in (*) do (
    if not %%~xi == .pem (
        if not %%~xi == .bat (
            echo 存在后缀名不为pem的文件 %%i
            set "ExecFlag=0"
        )
    )
)
for /f "delims=" %%i in ('dir /b /a-d root\*.*') do (
    set /a FileCount+=1
)
if %FileCount% gtr %RootMax% (
    echo root文件夹文件[%FileCount%个]超过[%RootMax%个]
    set "ExecFlag=0"
)
echo %ExecFlag%
if %ExecFlag% == 1 (
    echo "C:\Program Files\7-Zip\7z.exe" a  30.zip .\a\
)
pause
复制代码

作者: bat小猎手 时间: 2021-11-30 11:01

回复 8# Batcher

大神，在压缩工具目录里，怎么去判断他的压缩工具是在C盘的Program Files文件夹还是C盘的Program Files（x86）里面呢

作者: Batcher 时间: 2021-11-30 11:10

回复 9# bat小猎手

@echo off
if exist "C:\Program Files\7-Zip\7z.exe" (
    echo "C:\Program Files\7-Zip\7z.exe"
) else if exist "C:\Program Files (x86)\7-Zip\7z.exe" (
    echo "C:\Program Files (x86)\7-Zip\7z.exe"
) else (
    echo No 7z.exe
)
pause
复制代码

作者: bat小猎手 时间: 2022-1-9 16:34

回复 bat小猎手
Batcher 发表于 2021-11-30 11:10

大神；麻烦在里面如何在增加一个判断：文件夹内文件数量不能为0；为零的话不做打包处理；还有一个就是名称。就比如说在A文件夹内必须有“1.txt”，“2.txt”文件。如没有。也跳出程序；给出提示

作者: Batcher 时间: 2022-1-9 16:59

回复 11# bat小猎手

@echo off
set "RootMax=20"
set "FileCount=0"
set "ExecFlag=1"
for %%i in (inCertificate smCertificate smRoot root) do (
    if not exist %%i (
        echo 缺少文件夹 %%i
        set "ExecFlag=0"
    )
)
for /r %%i in (*) do (
    if not %%~xi == .pem (
        if not %%~xi == .bat (
            echo 存在后缀名不为pem的文件 %%i
            set "ExecFlag=0"
        )
    )
)
for /f "delims=" %%i in ('dir /b /a-d root\*.*') do (
    set /a FileCount+=1
)
if %FileCount% gtr %RootMax% (
    echo root文件夹文件[%FileCount%个]超过[%RootMax%个]
    set "ExecFlag=0"
)

REM 文件夹内文件数量不能为0；为零的话不做打包处理
set "FileCount=0"
for /f "delims=" %%i in ('dir /b /a-d inCertificate\*.*') do (
    set /a FileCount+=1
)
if %FileCount% gtr %RootMax% (
    echo inCertificate文件夹文件[%FileCount%个]
    set "ExecFlag=0"
)

REM root文件夹下必须有1.txt和2.txt这两个文件
if not exist "root\1.txt" (
    echo 不存在文件 "root\1.txt"
    set "ExecFlag=0"
) else if not exist "root\2.txt" (
    echo 不存在文件 "root\2.txt"
    set "ExecFlag=0"
)

echo %ExecFlag%
if %ExecFlag% == 1 (
    echo "C:\Program Files\7-Zip\7z.exe" a  30.zip .\a\
)
pause
复制代码

作者: bat小猎手 时间: 2022-1-9 18:08 标题: qq

[i=s] 本帖最后由 bat小猎手于 2022-1-9 19:55 编辑 [/i]

qq q q q q q q

欢迎光临批处理之家 (http://www.bathome.net/)