// FunCall 汇编函数
#ifdef  _WIN64
	/*
		;64位汇编 仅在单独的asm文件中方可编译, 不能内联
		;intptr_t  FunCall64( void* hProc, intptr_t* DLLParam, int DLLParamNum, int needINT )
		;CALL 64 APL, MADE BY SLIMAY 2021.09.24

		.CODE 
		FunCall64 PROC
			;  函数地址     传参数组     传参数目     传参模式
			;intptr_t* hProc, void* DLLParam, int DLLParamNum, int needINT

			;先备份传入的参数值
			mov	qword ptr [rsp +20h],  r9 
			mov	qword ptr [rsp +18h],  r8  
			mov	qword ptr [rsp +10h],  rdx 
			mov	qword ptr [rsp + 8h],  rcx 

			;寄存器原始值入栈
			push		rdi
			push		rbx
			;栈指针备份
			mov	rdi, rsp

			;设定快速传参栈空间(下移5个int64空间, 16字节对齐)
			sub	rsp, 28h

			;计算参数个数是否超过4个, (没超过 4个, 则直接跳转FUN2快速传参)
			mov	eax, r8d
			cmp	eax, 5
			;小于5个参数直接跳转 FUN2快速传参
			jb	FUN2

			;如果是超过4个参数的情况(计算出 传参数组的 尾指针的 后一指针)
			lea	rbx, [rdx + r8 *8h]

			;将超过4个参数的 剩余参数 入栈
			LOOP1:
				;arr 前移
				sub	rbx, 8h

				;参数倒序入栈
				mov	rax, qword ptr [rbx]  
				push	rax		

				;不相等则继续压参
				cmp	rbx, rdx 
				jnz	LOOP1               

			;复制参数数目, 以便之后比较
			mov	eax, r8d

		FUN2:
			;复制传参数组指针
			mov rbx, qword ptr [rdi + 20h]

			;如果是无参数函数
			cmp	eax, 0
			je	FUN1

			;如果是1个参数
			mov	rcx,qword ptr [rbx + 0h]  
			cmp	eax, 1
			je FUN1

			;如果是2个参数
			mov	rdx,qword ptr [rbx + 8h]
			cmp	eax, 2
			je FUN1

			;如果是3个参数
			mov	r8, qword ptr [rbx + 10h] 
			cmp	eax, 3
			je FUN1

			;如果是4个参数
			mov	r9, qword ptr [rbx + 18h]

		FUN1:
			;调用dll中的函数
			mov     rbx, qword ptr [rdi + 18h]
			call    rbx

			;获取返回模式参数
			mov     rbx, qword ptr [rdi + 30h]
			;如果返回模式为真, 输出整型指针
			cmp     rbx, 1
			je      FUNINT

			;复制浮点数的运算结果
			movsd       mmword ptr [rsp+20h], xmm0 
			jmp      FUN0

		FUNINT:
			;复制整数的运算结果
			mov         qword ptr  [rsp+20h], rax


		FUN0:
			;返回运算结果的指针 
			mov         rax,  qword ptr [rsp+20h]  
			;恢复栈指针
			mov	rsp, rdi
			;寄存器原始值出栈
			pop	rbx
			pop	rdi  


			ret  

		FunCall64 ENDP
		END
	*/
#else
_int64  FunCall32( void* hProc, intptr_t* DLLParam, int DLLParamNum, int needINT )
{
	union
	{
		_int64  retInt64;
		int     retInt[2];
	} RetInt;
	// 返回值容器清零
	RetInt.retInt64 = 0;

	// ESP备份容器, 实现兼容调用stdcall 和 cdecl
	int bakESP = 0;

	// 使用内联汇编, 低效稳定
    __asm
    {
		;备份栈帧
		mov bakESP,	esp

		;获取输入的参数
        mov		ebx, dword ptr [DLLParam]
        mov		ecx, dword ptr [DLLParamNum]
        dec		ecx 
		;计算出 传参数组 末尾指针
		lea		ebx, [ebx + ecx *4h]


	CYC: 
		;倒序 取出参数
		mov		eax, dword ptr [ebx]
		;参数 指针前移
		sub		ebx, 4
		;压栈
		push	eax 
		dec		ecx
		; 不为负值，则参数循环压栈
		jns		CYC                

		;调用函数, 执行call过程
        call dword ptr [hProc]

		;如果返回模式为真, 输出整型指针
		mov		ecx, dword ptr [needINT]
		cmp     ecx, 1
		je      FUNINT
		;返回浮点值
        fstp	RetInt.retInt64;
		jmp		FUNEND

	FUNINT:
        mov		RetInt.retInt[0], eax

	FUNEND:
		;针对 _cdecl 类型函数的call,由上级调用函数也就是FunCall32 负责 清理堆栈
		;恢复栈帧
		mov		esp,	bakESP
    }

	// 返回结果
	return (RetInt.retInt64);
}
#endif
复制代码

@REM 先设置工作目录，添加路径icmd_home
@set "PATH=%PATH%;%~DP0\icmd_home"

@REM 启用icmd64仅用于64位WIN系统, 且能调用64位DLL
@icmd64

@REM 一次载入全部的扩展DLL文件， 省的每次呼叫
@set *= iload  L"calc.dll" ^
               L"user32.dll"    ^
               L"kernel32.dll"  ^
               L"gdi32.dll"     ^
               L"gdiplus.dll"   ^
               L"msvcrt.dll"


@echo off
set ~a= calc A"sin(torad(30)+cos(tan(3)))/7*6+exp(5)"
echo %a%
pause
复制代码