for /f ... ('dir /b') do (
这里用if进行判断
...
)
pause
复制代码

@echo off
for /f "delims=" %%a in ('dir /b /ad ^|findstr /vb "111 222"') do rd %%a
for /f "delims=" %%b in ('dir /b /a-d ^|findstr /ev ".ini .exe .bat"^|findstr /bv "333 444"') do del %%b
pause
复制代码

@cd /d  d:\1\

@echo off & setlocal EnableDelayedExpansion
for /f "tokens=*" %%i in ('dir /a:d /b *') do (echo 搜索目录"%%i"&echo.
    for /f "delims=" %%j in ('echo %%i^| findstr /i /v "^111 ^222"') do echo 删除非匹配目录"%%j"&echo.&rd "%%j" /s /q
        for /f "delims=" %%k in ('echo %%i^| findstr /i /r /x "^111.* ^222.*"') do (echo 符合要求,即将切换.......
    pushd %%k&echo 切换目录"%%k"
        for /f "delims=" %%l in ('dir /b/a-d/on *.*^| findstr /i /v "^333 ^444"^| findstr /i /v "exe$ ini$"') do (
            echo 搜索到非匹配文件，删除"%%l" & del /f /s /q "%%l"
            )
    popd&echo.退出目录"%%k"&echo.
    rd "%%k" 2>nul&echo 如果"%%k"为空文件夹将删除
        )
    )
)
pause
复制代码

for /f "delims=" %%a in ('dir /b /ad ^|findstr /r /v "<111 <222"') do (
    rd /s %%a
)
for /f "delims=" %%a in ('dir /b /a-d ^|findstr /r /v "<333 <444 .ini> .exe>"') do (
     del %%a
)
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b') do (
    set "str=%%a"
    set "str1=!str:~,3!"
    set "str2=!str:~-3!"
    if "%%~xa"=="" (
        if not !str1!==111 (
            if not !str1!==222 rd "%%a"
        )
    )

    if not "%%~xa"=="" (
        if not !str2!==ini (
            if not !str2!==exe (
                if not !str2!==bat (
                    if not !str1!==333 (
                        if not !str1!==444 del %%a
                    )
                )
            )
        )
    )

)
pause
复制代码

@echo off
@rem 只保留以 111 和 222 为开头的文件夹，以 333 和 444 为开头的文件，以及所有.ini 和.exe 文件。
@setlocal enableDelayedExpansion

for /f "delims==" %%a in ('set _retain_ 2^>nul') do set "%%a="
set "_retain_Folder_111=True"
set "_retain_Folder_222=True"
set "_retain_File_333=True"
set "_retain_File_444=True"
set "_retain_File_.ini=True"
set "_retain_File_.exe=True"

for /r %%a in (.,*) do (
	set "Dir_a=%%~aa"
	set "Dir_x=%%~xa"
	set "Dir_n=%%~na"
	set "Dir_n=!Dir_n:~0,3!"
	if /i not "[%cd%]"=="[%%~fa]" if /i not "[%~f0]"=="[%%~fa]" if defined Dir_a if "[!Dir_a:~0,1!]"=="[d]" (
		if not defined _retain_Folder_!Dir_n! rd /q/s "%%~fa"
	) else (
		set "_retain_File_T="
		if defined _retain_File_!Dir_n! set "_retain_File_T=True"
		if defined _retain_File_!Dir_x! set "_retain_File_T=True"
		if not defined _retain_File_T del/f/s/q "%%~fa"
	)
)

endlocal
echo;&pause
exit /b
复制代码

@echo off
setlocal enabledelayed
for %%i in (333 444 .ini .exe .bat) do set _%%i=true
for %%i in (111 222) do set #%%i=true
for /f "delims=" %%i in ('dir /b /ad') do (
    set str=%%i
    if not defined #!str:~,3! rd /q /s "%%i"
)
for /f "delims=" %%i in ('dir /b /a-d') do (
    set str=%%i
    if not defined _%%~xi (
        if not defined _!str:~,3! del "%%i"
    )
)
pause
复制代码

@echo off
setlocal enabledelayed
for %%i in (333 444 .ini .exe .bat) do set _%%i=true
for %%i in (111 222) do set #%%i=true
for /d %%i in (*) do (
    set str=%%i
    if not defined #!str:~,3! rd /q /s "%%i"
)
for %%i in (*) do (
    set str=%%i
    if not defined _%%~xi (
        if not defined _!str:~,3! del "%%i"
    )
)
pause
复制代码

for /f "delims=" %%a in ('dir /b /s') do ...
复制代码