Board logo

标题: [网络工具] 命令行发送邮件(群发、多附件、匿名)p-mailsend_4.0 [打印本页]
作者: HAT    时间: 2009-9-20 11:46     标题: 命令行发送邮件(群发、多附件、匿名)p-mailsend_4.0

  1. ::p-mailsend.cmd

  2. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  3. :: p-mailsend_v4.0                                                       ::

  4. ::                                                                       ::

  5. ::           Code by  : vkill                                            ::

  6. ::           Thanks   : bjsh,est,lxmxm...                                ::

  7. ::           出    处 : http://www.vkill.net http://bbs.cn-dos.net       ::

  8. ::           功    能 : 命令行邮件发送程序(群发\多附件\匿名)             ::

  9. ::           原    理 : telnet收发邮件的原理                             ::

  10. ::           最后更新 : 2007-11-12                                       ::

  11. ::           程序依赖文件:nc.exe;rar.exe;base64.exe                      ::

  12. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  13. 

  14. @echo off&endlocal&setlocal ENABLEDELAYEDEXPANSION

  15. set "t_=test.conf"

  16. ::这里是匿名发信的详细设置

  17. set "匿名="QQ邮箱管理员匿名测试" ^<10000@qq.com^>" 

  18. 

  19. call :del_

  20. set "oneself=%~f0"

  21. if "%1"=="" (

  22. echo 请在命令行下执行 %oneself% /? 查看详细命令行帮助

  23. ping -n 5 127.1 >nul 2>nul  

  24. goto :eof

  25.          )

  26. if "%1"=="/?" goto help

  27. if "%1"=="-?" goto help

  28. for %%? in (/h,-h,--h) do (if "%~1"=="%%?" goto help)

  29. echo.

  30. echo p-mailsend_v4.0  by:vkill

  31. echo _________________________________________________

  32. 

  33. set/p=依赖文件完整性检查...<nul

  34. set "tools_name=nc.exe;rar.exe;base64.exe"

  35. for %%? in (%tools_name%) do (

  36. if *%%~$PATH:?==* if not exist %%? (

  37. echo no,缺失文件%%? &goto :sleep_

  38.                                   )

  39.                            )

  40. set/p=ok<nul&echo.

  41. 

  42. set/p=分析参数是否正确...<nul

  43. set n=0

  44. if not "%1"=="" (

  45. :loop_ap

  46. set/a n+=1

  47. if "%1"=="/hu" (set "hu=on" &shift)

  48. if "%1"=="/ht" (set "ht=on" &shift)

  49. if "%1"=="/ch" (set "ch=on" &shift)

  50. if "%1"=="/u" ((for /f "tokens=1-2 delims=@" %%a in ('echo %~2') do (set "user=%%a"& set "server=%%b")) &shift&shift)

  51. if "%1"=="/p" (set "pass=%~2" &shift&shift)

  52. if "%1"=="/t" (set "to=%~2" &shift&shift)

  53. if "%1"=="/s" (set "subject=%~2" &shift&shift)

  54. if "%1"=="/c" (set "content=%~2" &shift&shift)

  55. if "%1"=="/a" (set "accessories=%~2" &shift&shift)

  56. if not "%1"=="" (echo %~1|findstr "^/" >nul 2>nul ||(echo no,参数"%~1"错误&goto :sleep_))

  57. if !n!==10 (echo no,参数"%~1"错误&goto :sleep_)

  58. if not "%1"=="" (goto loop_ap) 

  59.              )

  60. set/p=ok<nul&echo.

  61. 

  62. set/p=分析必须参数是否缺失...<nul

  63. for %%? in (user server to subject) do (if not defined %%? (echo no&goto :sleep_))

  64. set/p=ok<nul&echo.

  65. if not defined pass (

  66. :inputpass

  67. for /f "tokens=1 delims=:" %%? in ('findstr /N "=Hiddenpass.cmd_s=" "%oneself%"') do (more +%%? %oneself%>"%temp%\a")

  68. for /f "tokens=1 delims=:" %%? in ('findstr /N "=Hiddenpass.cmd_e=" "%oneself%"') do (set/a "a=%%?-1" & more +!a! %oneself%>"%temp%\b")

  69. findstr /V /B /E /G:"%temp%\b" "%temp%\a">"%temp%\pass.cmd"

  70. start /wait cmd /k ""%temp%\pass.cmd" "!user!@!server!""

  71. set/p password=<%temp%\pass

  72. set "pass=!password:~9!"

  73. if not defined pass goto inputpass

  74. del /f/q "%temp%\pass" >nul 2>nul

  75. del /f/q "%temp%\pass.cmd" >nul 2>nul

  76. del /f/q "%temp%\a" >nul 2>nul

  77. del /f/q "%temp%\b" >nul 2>nul

  78.                  )

  79. 

  80. set/p=验证支持这个地址的邮箱发信否...<nul

  81. for /f "tokens=3-6 delims=," %%a in ('findstr "^::,%server%," "%oneself%"') do (

  82. set "smtp=%%a"&set "port=%%b"&set "认证方式=%%c"&set "max_z=%%d"

  83.                                                                              )

  84. if not defined smtp (echo no&goto :sleep_)

  85. set/p=ok<nul&echo.

  86. 

  87. set/p=验证网络通否...<nul

  88. for /f "tokens=2 delims=[]" %%? in ('ping -n 1 %smtp% ^|findstr /i "^ping.*[.*]"') do (set "ip=%%?")

  89. if not defined ip (echo no&goto :sleep_)

  90. set/p=ok<nul&echo.

  91. 

  92. set/p=验证telnet %smtp% %port%通否...<nul

  93. >"%temp%\l%t_%" echo quit

  94. nc -d -nvv %ip% %port% < "%temp%\l%t_%" >"%temp%\p-mailsend.log"

  95. findstr . "%temp%\p-mailsend.log">nul 2>nul||(echo no&goto :sleep_)

  96. set/p=ok<nul&echo.

  97. 

  98. set/p=验证登陆成功否...<nul

  99. if "%认证方式%"=="1" call :认证方式1

  100. copy "%temp%\%t_%" "%temp%\l%t_%">nul 2>nul

  101. >>"%temp%\l%t_%" echo quit

  102. nc -d -nvv %ip% %port% < "%temp%\l%t_%" >"%temp%\p-mailsend.log"

  103. set n=0

  104. for /f "tokens=1,2* delims=:" %%a in ('findstr /N . "%temp%\p-mailsend.log"') do (set "n=%%a"&set "x%%a=%%b")

  105. set/a n-=1

  106. echo "!x%n%!"|findstr "235 " >nul 2>nul ||(echo no,错误"!x%n%!"&goto :sleep_)

  107. set/p=ok<nul&echo.

  108. 

  109. ::继续写nc配置文件

  110. >>"%temp%\%t_%" echo mail from: ^<%user%@%server%^>

  111. if exist "%to%" (

  112. for /f "tokens=*" %%? in ('findstr "^[0-9a-zA-Z-_.]@" "!to!"') do (set "lto=%%?,!lto!")

  113.              )

  114. if defined lto (set "to=!lto!")

  115. for %%? in (!to!) do (>>"%temp%\%t_%" echo rcpt to: ^<%%?^>)

  116. >>"%temp%\%t_%" echo data

  117. if not defined hu (>>"%temp%\%t_%" echo From: %user%@%server%) else (>>"%temp%\%t_%" echo From: %匿名%)

  118. if not defined ht (>>"%temp%\%t_%" echo To: %to%)

  119. >>"%temp%\%t_%" echo Subject: %subject%

  120. >>"%temp%\%t_%" echo X-mailer: p-mailsend_v4.0 [cn]

  121. >>"%temp%\%t_%" echo Mime-Version: 1.0

  122. >>"%temp%\%t_%" echo Content-Type: multipart/mixed;

  123. >>"%temp%\%t_%" echo         boundary="=====vkill====="

  124. >>"%temp%\%t_%" echo.

  125. >>"%temp%\%t_%" echo --=====vkill=====

  126. if defined content call :htmlortxt !content!

  127. >>"%temp%\%t_%" echo         charset="gb2312"

  128. >>"%temp%\%t_%" echo Content-Transfer-Encoding: 7bit

  129. >>"%temp%\%t_%" echo.

  130. if defined content (dir !content! >nul 2>nul &&(type "!content!">>"%temp%\%t_%" &>>"%temp%\%t_%" echo.) ||(>>"%temp%\%t_%" echo !content!)) else (>>"%temp%\%t_%" echo :^))

  131. 

  132. set z=0

  133. if defined accessories set/p=压缩编码附件中...<nul

  134. echo "%accessories%" |findstr ")" >nul 2>nul && (echo no,附件路径或文件名中不能包含^)&goto :sleep_)

  135. if defined accessories (

  136. for /f "tokens=1,2,3,4,5,6 delims=→" %%a in ('echo %accessories%') do (

  137.    call :压缩编码附件 "%%~a"

  138.    call :压缩编码附件 "%%~b"

  139.    call :压缩编码附件 "%%~c"

  140.    call :压缩编码附件 "%%~d"      

  141.    call :压缩编码附件 "%%~e" 

  142.    call :压缩编码附件 "%%~f"                                 )

  143.                      )

  144. if defined xx (echo no,压缩或编码附件错误&goto :sleep_)

  145. if not !z! lss %max_z% (echo 附件过大,%server%邮箱最大支持附件大小为%max_z%K&goto :sleep_)

  146. if defined accessories (set/p=ok<nul&echo.)

  147. >>"%temp%\%t_%" echo --=====vkill=====--

  148. >>"%temp%\%t_%" echo .

  149. >>"%temp%\%t_%" echo quit

  150. 

  151. ::发信

  152. set/p=发信中...<nul

  153. nc -d -nvv %ip% %port% < ""%temp%\%t_%"" >"%temp%\p-mailsend.log"

  154. for /f "tokens=*" %%? in ("%temp%\p-mailsend.log") do (

  155. if defined vk1 if not defined vk2 (set vk2=0&set "发信错误=%%?"&echo "%%?"|findstr "250 " >nul 2>nul ||(set vk3=0))

  156. echo "%%?"|findstr "354 " >nul 2>nul &&(set vk1=0)

  157.                                           )

  158. if defined vk3 (echo no,错误"!发信错误!"&goto :sleep_)

  159. set/p=ok<nul&echo.

  160. 

  161. call :del_

  162. echo _________________________________________________

  163. echo 信件发送完成,2秒后退出

  164. ping -n 2 127.1 >nul 2>nul

  165. goto :eof

  166. 

  167. ::all call::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  168. 

  169. :help

  170. echo.

  171. echo p-mailsend_v4.0  2007.11  by:vkill  Thanks to bjsh,est,lxmxm...

  172. echo Copyright (C) 2006-2008 http://www.vkill.net http://bbs.cn-dos.net

  173. echo 当前支持的邮箱有:21cn.com,sina.com,163.com,126.com,sohu.com,yahoo.com.cn,qq.com

  174. echo 程序依赖文件:nc.exe;rar.exe;base64.exe

  175. echo 如依赖文件不全请手动到http://www.vkill.net/tools.html上下载到windows目录

  176. echo.

  177. echo Usage: 

  178. echo p-mailsend [/hu] [/ht] /u 用户@地址 [/p 密码] /t 收件人 /s 主题 [/c 内容] [/ch] [/a 附件]

  179. echo.

  180. echo /hu   匿名发信

  181. echo /ht   隐藏多方发送时别的收件人

  182. echo /u *  用户名@地址 例:/u 122755990@qq.com

  183. echo /p    密码

  184. echo /t *  收件人:(收件人/写好收件人列表的文本文件路径)

  185. echo              (多收件人用,隔开;用""引住) 例:/t "abc@163.com,123@56.com"

  186. echo              (收件人列表的文本文件格式如下:)

  187. echo               a@163.com    

  188. echo               b@163.com  

  189. echo               c@163.com           

  190. echo /s *  主题

  191. echo /c    内容:(文字/写好内容的文本文件路径)

  192. echo /ch   信件内容html格式开关,表示发送的内容为html格式   

  193. echo /a    附件:(绝对/相对路径,多附件用→隔开用""引住) 例:/a "c:\a b.cmd→1234.txt"

  194. goto :eof

  195. 

  196. :认证方式1

  197. >>"%temp%\%t_%" echo helo vkill

  198. >>"%temp%\%t_%" echo auth login

  199. for %%? in (%user%;%pass%) do (

  200. set/p=%%?^<nul|base64>"l!t_!"

  201. set/p v=<"l!t_!"

  202. >>"%temp%\%t_%" echo !v!

  203. del /f/q "l!t_!"

  204.                            )

  205. goto :eof

  206. 

  207. :del_

  208. del /f/q "%temp%\%t_%">nul 2>nul

  209. del /f/q "%temp%\l%t_%">nul 2>nul

  210. del /f/q "%temp%\p-mailsend.log">nul 2>nul

  211. goto :eof

  212. 

  213. :htmlortxt

  214. if "%ch%"=="on" (>>"%temp%\%t_%" echo Content-Type: text/html;) else (>>"%temp%\%t_%" echo Content-Type: text/plain;)

  215. goto :eof

  216. 

  217. :压缩编码附件

  218. if "%~1"=="" exit/b

  219. if "%~x1"==".rar" (copy "%~1" "%temp%\%~n1_.rar" >nul 2>nul) else (

  220. dir %~1 >nul 2>nul &&(rar.exe -r a "%temp%\%~n1_.rar" "%~1" >nul 2>nul)||(rar.exe a "%temp%\%~n1_.rar" "%~1" >nul 2>nul)

  221.                                                         )

  222. if not exist "%temp%\%~n1_.rar" (set xx=vkill&exit/b)

  223. for %%? in ("%temp%\%~n1_.rar") do (set/a z=z+%%~z?)

  224. >>"%temp%\%t_%" echo --=====vkill=====

  225. >>"%temp%\%t_%" echo Content-Type: application/octet-stream;

  226. >>"%temp%\%t_%" echo         name="%~n1_.rar"

  227. >>"%temp%\%t_%" echo Content-Transfer-Encoding: base64

  228. >>"%temp%\%t_%" echo Content-Disposition: attachment;

  229. >>"%temp%\%t_%" echo         filename="%~n1_.rar"

  230. >>"%temp%\%t_%" echo.

  231. base64.exe -i "%temp%\%~n1_.rar">>"%temp%\%t_%"

  232. >>"%temp%\%t_%" echo.

  233. del /f/q "%temp%\%~n1_.rar" >nul 2>nul

  234. goto :eof

  235. 

  236. :sleep_

  237. call :del_

  238. ping -n 2 127.1 >nul 2>nul

  239. goto :eof

  240. 

  241. ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  242. 

  243. =Hiddenpass.cmd_s=

  244. @echo off 

  245. chcp 437>nul&graftabl 936>nul

  246. echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com

  247. echo (注:输入密码时不明文显示)

  248. set  /p password=请输入mail:%~1的密码:<nul

  249. for /f "tokens=*" %%i in ('in.com') do set password=%%i

  250. del in.com

  251. echo.

  252. >%temp%\pass set password

  253. exit

  254. =Hiddenpass.cmd_e=

  255. 

  256. :::::::::::::::::::::当前支持的地址::::::::::::::::::::::

  257. ::,邮箱地址,smtp地址,telnet smtp端口,认证方式,最大附件大小(k)

  258. ::,21cn.com,smtp.21cn.com,25,1,15000000

  259. ::,sina.com,smtp.sina.com.cn,25,1,15000000

  260. ::,163.com,smtp.163.com,25,1,20000000

  261. ::,126.com,smtp.126.com,25,1,20000000

  262. ::,sohu.com,smtp.sohu.com,25,1,10000000

  263. ::,yahoo.com.cn,smtp.mail.yahoo.com,25,1,15000000

  264. ::,yahoo.com,smtp.mail.yahoo.com,25,1,15000000

  265. ::,qq.com,smtp.qq.com,25,1,5000000

  266. ::
复制代码


群发方法：
p-mailsend /u *@* /p * /t a.txt /s test /c * /a *

a.txt格式如下：
a@163.com
b@qq.com
c@56.com
d@yahoo.com.cn
....

本地下载：
http://pan.baidu.com/share/link?shareid=3811808911&uk=1124163200

转自：http://www.cn-dos.net/forum/viewthread.php?tid=29873
作者: HAT    时间: 2009-9-20 11:52     标题: 简单注释

  1. @echo off&setlocal ENABLEDELAYEDEXPANSION

  2. set "t_=test.conf"

  3. set "server=163.com"

  4. set "port=25"

  5. set "最大附件大小=15000000"

  6. set "tools_url=http://www.vkill.net/netbar/网吧所需exe/"

  7. set "tools_name=nc.exe;rar.exe;base64.exe"

  8. rem ================检查文件完整性=====================

  9. :down_tools

  10. set "down_ok=y"

  11. if not "%tools_name%*"=="*" (

  12. for %%? in (%tools_name%) do (

  13. if *%%~$PATH:?==* if not exist %%? (

  14. set "down_ok=n"

  15. echo 程序所依赖文件%%?缺失,已自动开始下载

  16. if not exist iget.vbs call :iget.vbs_

  17. iget.vbs "%tools_url%%%?" "%%?"

  18. ::move "%%?" %windir%>nul 2>nul

  19. echo 文件%%?下载完毕

  20.                                    )

  21.                              )

  22.                             )

  23. del /f/q iget.vbs>nul 2>nul

  24. if [%down_ok%]==[n] goto down_tools

  25. rem ==================结束==============================

  26. rem ===============分析参数=============================

  27. for %%? in (/? -? /h -h --h) do (if "%1"=="%%?" goto help)

  28. if "%1"=="" goto help

  29. :loop_ap

  30. set/a n+=1

  31. if not "%1"=="" (

  32.   if "%1"=="/x" goto 交互模式

  33.   if "%1"=="/u" set "user=%~2"

  34.   if "%1"=="/p" set "pass=%~2"

  35.   if "%1"=="/t" set "to=%~2"

  36.   if "%1"=="/s" set "subject=%~2"

  37.   if "%1"=="/c" set "content=%~2"

  38.   if "%1"=="/a" set "accessories=%~2"

  39.   shift&shift

  40.   goto loop_ap

  41.                 )

  42. for %%? in (user pass to subject) do (if not defined %%? goto 参数错误)

  43. goto start

  44. rem ===================结束===============================

  45. :交互模式

  46. call :help vkill

  47. if not defined user (set/p "user=用户名: ")

  48. if not defined pass (set/p "pass=密码: ")

  49. if not defined to (set/p "to=收件人: ")

  50. if not defined subject (set/p "subject=主题<hello>: ")

  51. if not defined content (set/p "content=内容: ")

  52. if not defined accessories (set/p "accessories=附件: ")

  53. rem                               :::::开始写配置文件:::::

  54. :start

  55. ::写单个发送配置文件

  56. for /l %%? in (1,1,7) do (>%%? cd.)

  57. >>1 echo helo vkill

  58. >>1 echo AUTH LOGIN

  59. rem ===================1文件的内容==========================

  60. rem                    helo vkill

  61. rem                    AUTH LOGIN

  62. rem ====================结束================================

  63. for %%? in (%user%;%pass%) do (

  64.   set/p=%%?^<nul|base64>"!t_!"

  65.   set/p v=<"!t_!"

  66.   >>2 echo !v!

  67.   del /f/q !t_!

  68.                               )

  69. rem [*第一次改写 test.conf 做为一个中介用来把用户名密码的base64编码写入文件2*]

  70. rem =================2文件的内容=============================

  71. rem               用户名和密码的base64编码

  72. rem =====================结束================================

  73. rem          [*改写test.conf利用nc 灌入服务器25端口的回显判断是否能够成功登陆*]

  74. >8 echo quit

  75. rem =================8文件的内容============================

  76. rem                     quit

  77. rem ====================结束================================

  78. copy 1+2+8 "!t_!" >nul 2>nul

  79. rem                                     ::判断能否登陆::

  80. rem 第二次改写test.conf 以用来 验证能否登陆服务器 nc -nvv IP Port <test.conf

  81. rem =================test.conf文件的内容=====================

  82. rem                helo vkill

  83. rem                AUTH LOGIN

  84. rem                用户名base64编码

  85. rem                密码base64编码

  86. rem                quit

  87. rem ====================结束================================

  88. call :发信程序

  89. cls

  90. call :判断登陆成功否

  91. if errorlevel 1 goto :del_

  92. rem                                     ::判断结束::

  93. >>3 echo mail from: ^<%user%@%server%^>

  94. rem ===================3文件的内容=============================

  95. rem             mail from: <%user%@163.com>

  96. rem =======================结束================================

  97. 

  98. >>5 echo data

  99. >>5 echo From: %user%@%server%

  100. >>5 echo To: %to%

  101. >>5 echo Subject: %subject%

  102. >>5 echo X-mailer: p-163ms 2.0 [cn]

  103. >>5 echo Mime-Version: 1.0

  104. >>5 echo Content-Type: multipart/mixed;

  105. >>5 echo         boundary="=====vkill====="

  106. >>5 echo.

  107. if defined content (

  108. >>5 echo --=====vkill=====

  109. >>5 echo Content-Type: text/plain;

  110. >>5 echo         charset="gb2312"

  111. >>5 echo Content-Transfer-Encoding: 7bit

  112. >>5 echo.

  113. dir !content! >nul 2>nul &&(type "!content!">>5) ||(>>5 echo !content!)

  114.                    )

  115. rem ====================5文件的内容=============================

  116. rem                        data

  117. rem                        From: %user%@163.com

  118. rem                        To: %to%

  119. rem                        Subject: %subject%

  120. rem                        X-mailer: p-163ms 2.0 [cn]

  121. rem                        Mime-Version: 1.0

  122. rem                        Content-Type: multipart/mixed;

  123. rem                                boundary="=====vkill====="

  124. rem         如果有内容的话

  125. rem                        --=====vkill=====

  126. rem                        Content-Type: text/plain;

  127. rem                                charset="gb2312"

  128. rem                        Content-Transfer-Encoding: 7bit

  129. rem

  130. rem                        内容

  131. rem ======================结束================================

  132. echo 压缩编码文件中...

  133. if defined accessories for %%? in (%accessories%) do (call :压缩编码附件 "%%?")

  134. >>7 echo --=====vkill=====--

  135. >>7 echo .

  136. >>7 echo quit

  137. rem ===================7文件的内容============================

  138. rem                 --=====vkill=====--

  139. rem

  140. rem                 quit

  141. rem ======================结束================================

  142. ::发信

  143. for %%? in (%to%) do (

  144.   echo 给%%?发信中...

  145.   ::合并单个发送配置文件

  146.   >4 echo rcpt to: ^<%%?^>

  147.   del /f/q "!t_!"

  148.   copy 1+2+3+4+5+6+7 "!t_!" >nul 2>nul

  149.   call :发信程序

  150.   call :判断发送成功否

  151.                      )

  152. rem ====================4文件的内容=============================

  153. rem                    rcpt to:<%to%>

  154. rem =======================结束================================

  155. rem 第三次改写 test.conf文件.合并1-7个文件;内容如下;也是最关键的东西.

  156. rem ===================test.conf文件的内容==========================

  157. rem                     helo vkill

  158. rem                     AUTH LOGIN

  159. rem                     用户名base64编码

  160. rem                     密码base64编码

  161. rem                     mail from: <%user%@163.com>

  162. rem                     rcpt to: <%to%@163.com>

  163. rem                     data

  164. rem                     From: %user%@163.com

  165. rem                     To: %to%@163.com

  166. rem                     Subject: %subject%

  167. rem                     X-mailer: p-163ms 2.0 [cn]

  168. rem                     Mime-Version: 1.0

  169. rem                     Content-Type: multipart/mixed;

  170. rem                             boundary="=====vkill====="

  171. rem

  172. rem                     --=====vkill=====

  173. rem                     Content-Type: text/plain;

  174. rem                             charset="gb2312"

  175. rem                     Content-Transfer-Encoding: 7bit

  176. rem

  177. rem                     %content%

  178. rem                     --=====vkill=====

  179. rem                     Content-Type: application/octet-stream;

  180. rem                             name="附件名称_.rar"

  181. rem                     Content-Transfer-Encoding: base64

  182. rem                     Content-Disposition: attachment;

  183. rem                             filename="附件名称_.rar"

  184. rem

  185. rem                     附件压缩文件的base64编码

  186. rem

  187. rem                     --=====vkill=====--

  188. rem                     .

  189. rem                     quit

  190. rem ====================结束================================

  191. rem                                                  ::::写配置文件结束::::

  192. cls

  193. if errorlevel 1 echo 发信不成功 & goto del_

  194. call :del_

  195. echo 全部信件发送完毕

  196. ping -n 3 127.1>nul 2>nul

  197. goto :eof

  198. :del_

  199. for /l %%? in (1,1,8) do (del /f/q %%?>nul 2>nul)

  200. del /f/q "%t_%">nul 2>nul

  201. del /f/q p-163ms.log>nul 2>nul

  202. goto :eof

  203. :help

  204. if "%1"=="vkill" goto :eof

  205. echo ____help________________________________________________________________________

  206. echo.

  207. echo p-163ms v2.0  by:vkill

  208. echo Copyright (C) 2006-2008 http://www.vkill.net

  209. echo.

  210. echo Usage: p-163ms.cmd [/x] /u 用户名 /p 密码 /t 收件人 /s 主题 [/c 内容] [/a 附件]

  211. echo.

  212. echo /x 交互模式,当使用此参数时别的参数全部无效

  213. echo /t 收件人:(多收件人中间用,隔开;多附件时用""引住)

  214. echo /c 内容:(文字/写好内容的文本文件路径)

  215. echo /a 附件:(绝对路径/相对路径,多附件中间用,隔开;多附件时用""引住)

  216. echo.

  217. echo 示例:

  218. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello

  219. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello /c 123 /a "d:\00.txt"

  220. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com,yx127@yx127.com" /s hello /c 123 /a "d:\00.txt,c:\00.bat"

  221. echo.

  222. echo ________________________________________________________________________________

  223. goto :eof

  224. :压缩编码附件

  225. dir %~1 >nul 2>nul &&(call :压缩文件 "%~1" "rar.exe -r")||(call :压缩文件 "%~1" rar.exe)

  226. call :判断文件大小 "%~n1_.rar"

  227. >>6 echo --=====vkill=====

  228. >>6 echo Content-Type: application/octet-stream;

  229. >>6 echo         name="%~n1_.rar"

  230. >>6 echo Content-Transfer-Encoding: base64

  231. >>6 echo Content-Disposition: attachment;

  232. >>6 echo         filename="%~n1_.rar"

  233. >>6 echo.

  234. base64.exe -i "%~n1_.rar">>6

  235. >>6 echo.

  236. del /f/q "%~n1_.rar" >nul 2>nul

  237. goto :eof

  238. rem ==================6文件的内容===================================

  239. rem                  --=====vkill=====

  240. rem                  Content-Type: application/octet-stream;

  241. rem                          name="%~n1_.rar"

  242. rem                  Content-Transfer-Encoding: base64

  243. rem                  Content-Disposition: attachment;

  244. rem                          filename="%~n1_.rar"

  245. rem

  246. rem                  附件的base64编码

  247. rem

  248. rem ====================结束======================================

  249. :压缩文件

  250. %~2 a "%~n1_.rar" "%~1" >nul 2>nul||(goto 压缩文件错误)

  251. goto :eof

  252. :判断文件大小

  253. set/a z+=%~z1

  254. ::判断附件大小

  255. if not !z! lss %最大附件大小% (goto 附件大小超出)

  256. goto :eof

  257. :发信程序

  258. for /f "tokens=2 delims=[]" %%? in ('ping -n 1 smtp.163.com ^|findstr /i "^Ping"') do (set "ip=%%?")

  259. nc -nvv !ip! %port%<"!t_!">p-163ms.log

  260. goto :eof

  261. :判断登陆成功否

  262. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")

  263. echo !5!|findstr "^235" >nul 2>nul ||(goto 登陆不成功)

  264. goto :eof

  265. :判断发送成功否

  266. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")

  267. if not defined 10 (call :发信不成功)

  268. echo !9!|findstr "^250" >nul 2>nul ||(goto 发信不成功)

  269. goto :eof

  270. :iget.vbs_

  271. >iget.vbs echo x=LCase(WScript.Arguments(1))

  272. >>iget.vbs echo y=LCase(WScript.Arguments(0))

  273. >>iget.vbs echo Set xPost=CreateObject("Microsoft.XMLHTTP")

  274. >>iget.vbs echo xPost.Open "GET",y,0

  275. >>iget.vbs echo xPost.Send()

  276. >>iget.vbs echo Set sGet=CreateObject("ADODB.Stream")

  277. >>iget.vbs echo sGet.Mode=3

  278. >>iget.vbs echo sGet.Type=1

  279. >>iget.vbs echo sGet.Open()

  280. >>iget.vbs echo sGet.Write(xPost.responseBody)

  281. >>iget.vbs echo sGet.SaveToFile x,2

  282. goto :eof

  283. :::::::::::::::::::::所有错误start::::::::::::::::::::::

  284. :参数错误

  285. echo 参数错误,用户名\密码\收件人\主题中某一项缺少

  286. goto :eof

  287. :压缩文件错误

  288. echo 压缩文件失败

  289. goto :eof

  290. :附件大小超出

  291. echo 附件大小超出

  292. goto :eof

  293. :登陆不成功

  294. echo 登陆不成功

  295. goto :eof

  296. :发信不成功

  297. echo 发信不成功

  298. goto :eof

  299. :::::::::::::::::::::所有错误end::::::::::::::::::::::
复制代码
作者: hxinhu12315    时间: 2009-10-1 09:33

!   C:\Documents and Settings\Administrator\桌面\批处理之家论坛下载_p-mailsend_v4.0.rar: 不可预料的压缩文件末端
作者: Seter    时间: 2009-10-1 14:27

原帖由 hxinhu12315 于 2009-10-1 09:33 发表
!   C:\Documents and Settings\Administrator\桌面\批处理之家论坛下载_p-mailsend_v4.0.rar: 不可预料的压缩文件末端

可以解压就可以了,不要那么讲究
居然用NC发送邮件..真强
作者: linmiaojing    时间: 2010-4-5 11:01

真是有字天书！看不懂
作者: weiluz    时间: 2013-12-19 18:33

nc.exe 很容易给杀毒软件 但病毒查杀了，导致文件丢失无法正常使用了。
作者: xybzm    时间: 2014-2-21 17:17

楼上说得很对。。
作者: Hodson124    时间: 2014-3-7 08:26

解压不了啊！
作者: wuhengsi    时间: 2014-6-20 21:38

凡是可杀的。。。可视为废物一个。。。无用
作者: shh200438    时间: 2014-6-29 07:07

太赞了, 写这么个批处理不容易啊, 辛苦了.
作者: shh200438    时间: 2014-6-29 07:10

太赞了, 写这么个批处理不容易啊, 辛苦了.



欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2